source: branches/0.6-stable/configure.ac @ 1260

Last change on this file since 1260 was 841, checked in by Peter Johansson, 11 years ago

Preparing release 0.6.8

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 7.4 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 841 2009-11-12 00:36:55Z peter $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8
9# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
10# Copyright (C) 2006 Jari Häkkinen
11# Copyright (C) 2007 Jari Häkkinen, Peter Johansson
12# Copyright (C) 2008, 2009 Peter Johansson
13#
14# This file is part of svndigest, http://dev.thep.lu.se/svndigest
15#
16# svndigest is free software; you can redistribute it and/or modify it
17# under the terms of the GNU General Public License as published by
18# the Free Software Foundation; either version 2 of the License, or
19# (at your option) any later version.
20#
21# svndigest is distributed in the hope that it will be useful, but
22# WITHOUT ANY WARRANTY; without even the implied warranty of
23# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
24# General Public License for more details.
25#
26# You should have received a copy of the GNU General Public License
27# along with this program; if not, write to the Free Software
28# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
29# 02111-1307, USA.
30
31AC_PREREQ(2.57)
32AC_INIT([svndigest],[0.6.8],[jari@thep.lu.se])
33AC_CONFIG_SRCDIR([lib/File.h])
34AC_CONFIG_AUX_DIR([autotools])
35AC_PREFIX_DEFAULT([/usr/local])
36test $prefix = NONE && prefix=/usr/local
37
38AM_CONFIG_HEADER([config.h])
39AM_INIT_AUTOMAKE([std-options check-news])
40
41AC_LANG([C++])
42
43# Checks for programs.
44AC_PROG_CXXCPP
45AC_PROG_CXX
46AC_PROG_INSTALL
47AC_PROG_LIBTOOL
48AC_PROG_RANLIB
49AC_CHECK_PROG([GNUPLOT],[gnuplot],[ok])
50
51# -Wno-long-long is needed to suppress compiler diagnostics regarding
52# using extension beyond the C++ standard (usage of non C++ standard
53# 'long long' types).
54CXXFLAGS="-Wall -pedantic -Wno-long-long"
55
56AC_ARG_ENABLE([debug],
57              [AS_HELP_STRING([--enable-debug],
58                              [turn on debug options and code])])
59
60AS_IF([test x$enable_debug = xyes], [CXXFLAGS="$CXXFLAGS -g -O"],
61      [CPPFLAGS="$CPPFLAGS -DNDEBUG" CXXFLAGS="$CXXFLAGS -O3"])
62
63AC_ARG_ENABLE([wctests],
64  [AS_HELP_STRING([--enable-wctests],[turn on all tests, tests
65  requiring a subversion WC are disabled by default])])
66AM_CONDITIONAL(WCTESTS, test x$enable_wctests = xyes)
67
68# optionally prepare for building static libraries.
69AC_ARG_ENABLE(staticbin,
70  [AS_HELP_STRING([--enable-staticbin], [create a static binary,
71  at least as static as the available underlying libraries
72  allows])])
73if test "$enable_staticbin" = "yes"; then
74  case $host in
75  *-apple-darwin*)
76    # At the time of creating this libsvn_subr uses
77    # Keychain on Mac OSX. In consequence the below
78    # frameworks are needed for succesful static builds.
79    LIBS="$LIBS -framework Security"
80    LIBS="$LIBS -framework CoreFoundation"
81    LIBS="$LIBS -framework CoreServices"
82    ;;
83  esac
84  STATICFLAG=-static
85  AC_SUBST(STATICFLAG)
86fi
87
88# Apache Portable Runtime (APR) API checks
89# The next three lines are not needed as long as APR_FIND_APR is used.
90# AC_ARG_WITH(apr,
91#  [  --with-apr=DIR          prefix for installed APR or path to APR build
92#                          tree [[PREFIX]]])
93# Include APR_FIND_APR macro distributed within the APR project. If
94# the usage of the APR macro is to be omitted then the construct for
95# setting the CXXFLAGS (header file location) and LDFLAGS (linking
96# informaion) for APR must be changed. The latter can be achieved with
97# AC_SEARCH_LIBS([apr_allocator_create],[apr-0],,apr_found="no") but
98# apr-0 must be prior knowledge.
99sinclude(./build_support/find_apr.m4)
100APR_FIND_APR(,,1)
101if test "$apr_found" = "yes" ; then
102    LDFLAGS="`$apr_config --link-ld` $LDFLAGS"
103    CPPFLAGS="`$apr_config --includes` $CPPFLAGS"
104    AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
105fi
106
107# Subversion API checks
108svn_found="yes"
109AC_ARG_WITH(svn,
110  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
111  [ LDFLAGS="-L$withval/lib $LDFLAGS" CPPFLAGS="-I$withval/include $CPPFLAGS"])
112AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
113# The library checks below may match shared libs even when
114# --enable-staticbin is given to configure. This should probably not
115# pose any problems since in a properly installed system the shared
116# and static libraries should be the same.
117AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],,svn_found="no")
118AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],,svn_found="no")
119AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],,svn_found="no")
120AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],,svn_found="no")
121AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],,svn_found="no")
122
123AC_CONFIG_FILES([Makefile
124                bin/Makefile
125                lib/Makefile
126                test/Makefile])
127
128# Print failure status information about selected items, and exit if
129# fatal errors were encountered. No output will be created if
130# configure is halted prematurely.
131
132# used to trigger exit before creation of output
133all_reqs_ok="true"
134
135# Non-existing APR is fatal -- sub-sequent compilation will fail.
136if (test "$apr_found" = "no") ; then
137    AC_MSG_WARN([APR not found. The Apache Portable Runtime
138    (APR) library cannot be found. Please make sure APR is installed
139    and supply the appropriate --with-apr option to 'configure'.])
140    all_reqs_ok="false"
141fi
142
143# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
144if (test "$svn_found" = "no") ; then
145    svn_msg="Subversion API not found. Subversion API libraries cannot
146    be found. Make sure the APIs are installed and supply the
147    appropriate --with-svn option to 'configure'."
148if (test "$apr_found" = "no") ; then
149    svn_msg="$svn_msg
150    Note, APR was not found. Failure to locate APR affects the
151    location of the subversion API. Please fix the APR problem before
152    trying to resolve the subversion related issues."
153fi
154    AC_MSG_WARN([$svn_msg])
155    all_reqs_ok="false"
156fi
157
158if (test "$all_reqs_ok" = "false") ; then
159    AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
160    configure. Please consult the 'README' file for more information
161    about what is needed to compile svndigest and refer to above
162    warning messages. Needed files were NOT created.])
163fi
164
165# Create output.
166AC_OUTPUT
167
168# Some more messages.
169AC_MSG_NOTICE([])
170AC_MSG_NOTICE([   Ready to compile the executables of svndiget])
171AC_MSG_NOTICE([   The following flags and libs will be used:])
172AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
173AC_MSG_NOTICE([    Preprocessor flags: CPPFLAGS=\"$CPPFLAGS\"])
174AC_MSG_NOTICE([    C++ flags:          CXXFLAGS=\"$CXXFLAGS\"])
175AC_MSG_NOTICE([    Linker flags:       LDFLAGS=\"$LDFLAGS\"])
176AC_MSG_NOTICE([    LIBS:               LIBS=\"$LIBS\"])
177AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
178AC_MSG_NOTICE([])
179
180if (test x$enable_wctests = xyes) ; then
181    AC_MSG_NOTICE([WC dependent tests are enabled])
182else
183    AC_MSG_NOTICE([WC dependent tests are disabled ... okay for most users])
184    AC_MSG_NOTICE([Developers, use --enable-wctests to enable WC tests])
185fi
186AC_MSG_NOTICE([])
187
188# Failure to locate gnuplot is not considered fatal
189if (test "$GNUPLOT" != "ok") ; then
190    AC_MSG_WARN([Gnuplot was not found. svndigest will compile
191    without gnuplot but will throw an exception at run-time. Please
192    install gnuplot (available for a wide range of operating systems
193    at http://www.gnuplot.info).])
194    AC_MSG_NOTICE([])
195fi
196
197if test "$enable_staticbin" = "yes"; then
198    AC_MSG_NOTICE([A statically linked 'svndigest' binary will be created.])
199else
200    AC_MSG_NOTICE([A dynamically linked 'svndigest' binary will be created.])
201fi
202    AC_MSG_NOTICE([])
203
204AC_MSG_NOTICE([Now type 'make ; make check'.])
Note: See TracBrowser for help on using the repository browser.