source: trunk/configure.ac @ 1057

## Process this file with autoconf to produce a configure script.
##
## $Id: configure.ac 1057 2010-04-23 07:54:01Z peter $
##
## If you grabbed the source from subversion you should, at top-level,
## execute:
##          ./bootstrap
## To push subsequent changes of this file into the build scripts you
## must issue:
##          autoreconf

# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
# Copyright (C) 2006 Jari Häkkinen
# Copyright (C) 2007, 2008, 2009 Jari Häkkinen, Peter Johansson
# Copyright (C) 2010 Peter Johansson
#
# This file is part of svndigest, http://dev.thep.lu.se/svndigest
#
# svndigest is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3 of the License, or
# (at your option) any later version.
#
# svndigest is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
# General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with svndigest. If not, see <http://www.gnu.org/licenses/>.

AC_PREREQ([2.63])

m4_include([m4/version.m4])
AC_INIT([svndigest], m4_defn([SVNDIGEST_VERSION]),[jari@thep.lu.se],,
        [http://dev.thep.lu.se/svndigest])
AC_CONFIG_SRCDIR([lib/File.h])
AC_CONFIG_AUX_DIR([autotools])
dnl arg below should be the same as in Makefile.am
AC_CONFIG_MACRO_DIR([m4])
AC_PREFIX_DEFAULT([/usr/local])

dnl FIXME remove when we assume autoconf 2.64
m4_ifndef([AC_PACKAGE_URL], 
          [AC_DEFINE([PACKAGE_URL], ["http://dev.thep.lu.se/svndigest"],
                     [Define to home page for this package])
           AC_SUBST([PACKAGE_URL], ["http://dev.thep.lu.se/svndigest"])])

# propagate RELEASE_YEAR from file .release_year
RELEASE_YEAR=`cat $srcdir/.release_year`
AC_SUBST([RELEASE_YEAR])
AC_DEFINE_UNQUOTED([RELEASE_YEAR], ["$RELEASE_YEAR"], 
                   [Define year package was last modified])
AC_SUBST([CONFIG_STATUS_DEPENDENCIES], ['$(top_srcdir)/.release_year'])

AC_SUBST([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION])
AC_SUBST([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION])
AC_SUBST([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION])

AC_DEFINE([DEV_BUILD],[SVNDIGEST_DEV_BUILD], 
          [true if dev build (version ends with pre)])
AC_DEFINE([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION], 
                    [Define to the svndigest major version])
AC_DEFINE([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION],
                    [Define to the svndigest minor version])
AC_DEFINE([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION],
                    [Define to the svndigest patch version])

AC_CONFIG_HEADERS([config.h])
AM_INIT_AUTOMAKE([1.11 color-tests std-options parallel-tests])

dnl create bin/svndigest-copy-cache.in at autoconf time and let
dnl config.status create bin/svndigest-copy-cache from
dnl bin/svndigest-copy-cache.in
m4_pushdef([FILE], [svndigest-copy-cache])
m4_pushdef([my_m4sh_options], [-m 0644])
dnl me cd down in bin to have same output as when created from Makefile
m4_syscmd([cd bin && autom4te -l M4sh -o ]FILE[.in ]my_m4sh_options FILE[.as])
AC_CONFIG_FILES([bin/]FILE[], [chmod +x bin/]FILE[ && chmod a-w bin/]FILE[])
dnl export options so we can use the same in Makefile
AC_SUBST([M4SH_OPTIONS], ['my_m4sh_options'])
m4_popdef([my_m4sh_options])
m4_popdef([FILE])
AM_MISSING_PROG([AUTOM4TE], [autom4te])

# Set default programming language
AC_LANG([C++])

# propagate selected configure variables to DISTCHECK_CONFIGURE_FLAGS
for var in CPPFLAGS CXX CXXFLAGS CXXCPP LDFLAGS LIBS; do
  eval isset=\${$var+set}
  if test "$isset" = 'set' ; then
    eval val=$`echo $var`
    DISTCHECK_CONFIGURE_FLAGS="${DISTCHECK_CONFIGURE_FLAGS}'${var}=${val}' "
  fi
done
AC_SUBST(DISTCHECK_CONFIGURE_FLAGS) 

# Let user overide default CXXFLAGS
if test "${CXXFLAGS+set}" != set; then
  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
fi

# Checks for programs.
AC_PROG_CXXCPP
AC_PROG_CXX
AC_PROG_RANLIB
AC_PROG_SED
AC_PATH_PROG([HELP2MAN], [help2man], [no])
# look for pkg-config
PKG_PROG_PKG_CONFIG([0.23])

# Save FLAGS
APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)

# -Wno-long-long is needed to suppress compiler diagnostics regarding
# using extension beyond the C++ standard (usage of non C++ standard
# 'long long' types).
YAT_CXX_ADD_FLAG([CXXFLAGS],[-pedantic -Wno-long-long])
AC_TYPE_LONG_LONG_INT
AS_IF([test x$ac_cv_type_long_long_int = xno],
      [AC_MSG_ERROR([compiler does not support long long int])]
     )

AC_ARG_ENABLE([debug],
  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])])

AS_IF([test x$enable_debug = xyes], 
  [YAT_CXX_ADD_FLAG([CXXFLAGS],[-g -O])],
  [YAT_CPP_ADD_FLAG([CPPFLAGS],[-DNDEBUG])
   YAT_CXX_ADD_FLAG([CXXFLAGS],[-O3])])

# Apache Portable Runtime (APR) API checks
APR_FIND_APR(,,[1],[1 0])
AS_IF([test "${with_apr+set}" = set],
    [DISTCHECK_CONFIGURE_FLAGS="$DISTCHECK_CONFIGURE_FLAGS --with-apr=$with_apr"]
)
if test "$apr_found" = "yes" ; then
    APR_LIBS="`$apr_config --libs`"
    apr_link_ld="`$apr_config --link-ld`"
    for i in $apr_link_ld; do
      AS_IF([test ${i:0:2} = "-l"],[APR_LIBS="$i $APR_LIBS"],
            [YAT_LD_ADD_FLAG([APR_LDFLAGS], [$i])])
    done
    YAT_CPP_ADD_FLAG([APR_CPPFLAGS],[`$apr_config --includes --cppflags`])
    save_CPPFLAGS=$CPPFLAGS
    CPPFLAGS="$APR_CPPFLAGS $CPPFLAGS"
    AC_CHECK_HEADER([apr_allocator.h],,[apr_found="no"])
    CPPFLAGS=$save_CPPFLAGS
fi
AC_SUBST([APR_CPPFLAGS])
AC_SUBST([APR_LDFLAGS])
AC_SUBST([APR_LIBS])

# Subversion API checks
svn_found="yes"
AC_ARG_WITH([svn],
  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
  [ AS_CASE([$withval], [yes|no],
            [AC_MSG_ERROR([--with-svn requires a directory to be provided])])
    AS_IF([test -d $with_svn], [], 
          [AC_MSG_ERROR([$with_svn: no such directory])])
    # transform argument to absolute path
    with_svn=`cd $with_svn && pwd`
    DISTCHECK_CONFIGURE_FLAGS="$DISTCHECK_CONFIGURE_FLAGS --with-svn=$with_svn"
    YAT_LD_ADD_FLAG([SVN_LDFLAGS], [-L$with_svn/lib])
    YAT_CPP_ADD_FLAG([SVN_CPPFLAGS], [-I$with_svn/include])
  ])
# svn needs needs apr headers
save_CPPFLAGS=$CPPFLAGS
CPPFLAGS="$APR_CPPFLAGS $SVN_CPPFLAGS $CPPFLAGS"
AC_CHECK_HEADER([subversion-1/svn_types.h],,[svn_found="no"])
CPPFLAGS=$save_CPPFLAGS

save_LDFLAGS=$LDFLAGS
save_LIBS=$LIBS
tmp_LIBS="$APR_LIBS $save_LIBS"
LIBS=""
LDFLAGS="$SVN_LDFLAGS $APR_LDFLAGS"
AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],
               [], [svn_found="no"], [$tmp_LIBS])
AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1], [], [svn_found="no"],[$tmp_LIBS])
AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1], [], [svn_found="no"], [$tmp_LIBS])
AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],[], 
               [svn_found="no"], [$tmp_LIBS])
AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],,[svn_found="no"], [$tmp_LIBS])
SVN_LIBS=$LIBS
LIBS=$save_LIBS
LDFLAGS=$save_LDFLAGS
AC_SUBST([SVN_CPPFLAGS])
AC_SUBST([SVN_LDFLAGS])
AC_SUBST([SVN_LIBS])


# check if svnversion is installed
AC_PATH_PROG([SVNVERSION], [svnversion], [no])

# PLplot API checks
# plplot_found can get values: skip, noheader, old, or nolib if an
# error is detected.
plplot_found="yes"
plplot_version=5.9
save_PKG_CONFIG_PATH=$PKG_CONFIG_PATH
AC_ARG_WITH([plplot],
  [AS_HELP_STRING([--with-plplot=DIR],[prefix for plplot developer files])],
  [DISTCHECK_CONFIGURE_FLAGS="$DISTCHECK_CONFIGURE_FLAGS --with-plplot=$withval"
   AS_IF([test "x$withval" = "xno"], [ dnl
     plplot_found=skip;
   ], [ dnl
     AS_IF([test -d $with_plplot], [],
           [AC_MSG_ERROR([$with_plplot: no such directory])])
     with_plplot=`cd $with_plplot && pwd` 
     # help pkg-config find .pc file
     PKG_CONFIG_PATH=$with_plplot/lib/pkgconfig$PATH_SEPARATOR$PKG_CONFIG_PATH
     export PKG_CONFIG_PATH 
   ])
  ])

use_plplot_pc="no"
AS_IF([test "x$plplot_found" = "xyes" && test -n "$PKG_CONFIG"], [
  AC_MSG_CHECKING([for plplotd-c++.pc])
  AS_IF([$PKG_CONFIG --exists plplotd-c++], [
    AC_MSG_RESULT([yes])
    use_plplot_pc="yes"
  ],[
    AC_MSG_RESULT([no])
    AC_MSG_WARN([cannot find plplotd-c++; 
      please use --with-plplot with appropriate argument to get more accurate 
      configuration.])
  ])
])

AS_IF([test "x$plplot_found" = "xyes"], [
  # copy flags if we have found pc file
  AS_IF([test "$use_plplot_pc" = "yes"], [
    YAT_LD_ADD_FLAG([PLPLOT_LDFLAGS], [`$PKG_CONFIG plplotd-c++ --libs-only-L`])
    PLPLOT_LIBS="`$PKG_CONFIG plplotd-c++ --libs-only-l --libs-only-other`"
  ],[
    # otherwise guess
    PLPLOT_LIBS="-lplplotcxxd -lplplotd";
    AS_IF([test -n "$with_plplot" && test "x$with_plplot" != "xyes"], [
      YAT_LD_ADD_FLAG([PLPLOT_LDFLAGS], [-L$with_plplot/libs])
    ])
  ])
  # don't use `pkg-config --cflags' because it returns
  # `PREFIX/include/plplot' rather than `PREFIX/include'
  AS_IF([test -n "$with_plplot" && test "x$with_plplot" != "xyes"], [
    YAT_CPP_ADD_FLAG([PLPLOT_CPPFLAGS], [-I$with_plplot/include])
  ])
])
                  
AS_IF([test "x$plplot_found" = "xyes"], [
  save_CPPFLAGS=$CPPFLAGS
  CPPFLAGS="$PLPLOT_CPPFLAGS $CPPFLAGS"
  AC_CHECK_HEADER([plplot/plstream.h], [], [plplot_found="noheader"])
  CPPFLAGS=$save_CPPFLAGS
])


AS_IF([test "x$plplot_found" = "xyes" && test -n "$PKG_CONFIG"], [
  AC_MSG_CHECKING([plplot version >= $plplot_version])
  AS_IF([$PKG_CONFIG --atleast-version=$plplot_version plplotd-c++], [
    AC_MSG_RESULT([yes])
  ],[
    AC_MSG_RESULT([`$PKG_CONFIG --modversion= plplotd-c++`])
    plplot_found="old"
  ])
])

AS_IF([test "x$plplot_found" = "xyes"], [
  save_CPPFLAGS=$CPPFLAGS
  CPPFLAGS="$PLPLOT_CPPFLAGS $CPPFLAGS"
  save_LDFLAGS=$LDFLAGS
  LDFLAGS="$PLPLOT_LDFLAGS $LDFLAGS"
  save_LIBS=$LIBS
  LIBS="$PLPLOT_LIBS $LIBS"
  AC_MSG_CHECKING([for library containing plstream])
  AC_LINK_IFELSE([AC_LANG_PROGRAM([@%:@include <plplot/plstream.h>],
                                  [plstream pls(1,1,"svg", "conftest.svg");
                                   pls.scolbga(255, 255, 255, 0);
                                  ])], 
                 [AC_MSG_RESULT([yes]);
                  AC_DEFINE([HAVE_PLPLOT], [1], 
                            [Define to 1 if you have plplot])], 
                 [AC_MSG_RESULT([no])
                  plplot_found=nolib;])
  CPPFLAGS=$save_CPPFLAGS
  LDFLAGS=$save_LDFLAGS
  LIBS=$save_LIBS
])
# restore variable
export PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
AC_SUBST(PLPLOT_CPPFLAGS)
AC_SUBST(PLPLOT_LDFLAGS)
AC_SUBST(PLPLOT_LIBS)

# checking if we build in a subversion WC
AS_IF([test -d $srcdir/.svn], [wc_found="yes"], [wc_found="no"])
AM_CONDITIONAL([HAVE_SVN_WC], [test "$wc_found" = "yes"])
AC_SUBST([wc_found])

# checking if we have test repo
test_repo_filename=$srcdir/test/repo;
AS_IF([test -r $test_repo_filename], 
              [AC_DEFINE([HAVE_TEST_REPO],[1],[define if test repo is available])
               test_repo_found="yes"],
              [test_repo_found="no"])
AC_SUBST([test_repo_found])
AS_IF([test "x$test_repo_found" = xyes],
      [abs_test_repo=`cd $test_repo_filename && pwd`;
       AC_SUBST(abs_test_repo)]
     )
AC_CONFIG_FILES([test/init.sh])
AC_CONFIG_FILES([test/svn_update.sh], [chmod +x test/svn_update.sh])

dnl maintainer make rukes from yat project
YAT_SVN_RELEASE

# Restore FLAGS
APR_RESTORE_THE_ENVIRONMENT([CPPFLAGS], [DEFAULT_])
APR_RESTORE_THE_ENVIRONMENT([CXXFLAGS], [DEFAULT_])

AC_CONFIG_FILES([Makefile
                bin/Makefile
                lib/Makefile
                lib/yat/Makefile
                man/Makefile
                test/environment.h
                test/Makefile])

AC_CONFIG_HEADER([lib/yat/config_public.h])

# Print failure status information about selected items, and exit if
# fatal errors were encountered. No output will be created if
# configure is halted prematurely.

# used to trigger exit before creation of output
all_reqs_ok="true"

if (test "$wc_found" = "yes"); then 
   if test x$HELP2MAN = xno; then
     AC_MSG_WARN(m4_text_wrap(m4_normalize([
       `help2man' is missing on your system.  You will not be
       able to create the man page. A sound man page should be
       included in a distribution, and since you will not able
       to create a complete distribution `make dist' will fail.
       ]),[                   ],
          [                             ], 79))
   fi 
   # svnversion is required when building from svn wc
   if (test "$svnversion" = "no"); then
      all_reqs_ok="false";
      AC_MSG_WARN([dnl
Cannot find svnversion, which is required when building from a
subversion working copy. Please install svnversion and make sure it is
in your search path.]);
   fi
   if (test "$test_repo_found" = "no"); then
      all_reqs_ok="false";
      AC_MSG_WARN([dnl
Cannot find test repository (test_repo_filename), which should be
available when building from a subversion working copy. Try svn
update in top directory.]);
   fi
fi

# Non-existing APR is fatal -- sub-sequent compilation will fail.
if (test "$apr_found" = "no") ; then
  AC_MSG_WARN([APR not found. The Apache Portable Runtime
  (APR) library cannot be found. Please make sure APR is installed
  and supply the appropriate --with-apr option to 'configure'.])
  all_reqs_ok="false"
fi

# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
if (test "$svn_found" = "no") ; then
  svn_msg="Subversion API not found. Subversion API libraries cannot
  be found. Make sure the APIs are installed and supply the
  appropriate --with-svn option to 'configure'."
  if (test "$apr_found" = "no") ; then
    svn_msg="$svn_msg
    Note, APR was not found. Failure to locate APR affects the search
    of the subversion API. Please fix the APR problem before trying
    to resolve the subversion related issues."
  fi
  AC_MSG_WARN([$svn_msg])
  all_reqs_ok="false"
fi

# Non-existing PLplot API is fatal -- sub-sequent compilation will fail.
AS_CASE([$plplot_found], 
  [noheader],
    [AC_MSG_WARN([
    PLplot developer files cannot be found. Make sure PLplot is installed.])
    all_reqs_ok="false"],
  [old],
    [AC_MSG_WARN([
    PLplot developer files found but not required API version.
    Version at least $plplot_version is required. Please upgrade PLplot.])
    all_reqs_ok="false"],
  [nolib],
    [AC_MSG_WARN([
    PLplot developer files found but linking against plplot library failed.])
    all_reqs_ok="false"])

if test $ac_cv_type_long_long_int != yes ; then
  AC_MSG_WARN([Compiler $CXX does not support `long long'.
  svndigest must be compiled with a compiler that supports `long long'.])
  all_reqs_ok="false"
fi

if (test "$all_reqs_ok" = "false") ; then
  AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
  configure. Please consult the 'README' file for more information
  about what is needed to compile svndigest and refer to above
  warning messages. Needed files were NOT created.])
fi

# Create output.
AC_OUTPUT

# Some more messages.
AC_MSG_NOTICE([
Ready to compile the executables of svndigest $VERSION
The following flags and libs will be used:
+++++++++++++++++++++++++++++++++++++++++++++++
  Compiler:           $CXX
  Preprocessor flags: $SD_CPPFLAGS $CPPFLAGS
    CPPFLAGS:         $CPPFLAGS
    DEFAULT_CPPFLAGS: $DEFAULT_CPPFLAGS
    APR_CPPFLAGS:     $APR_CPPFLAGS
    SVN_CPPFLAGS:     $SVN_CPPFLAGS
    PLPLOT_CPPFLAGS:  $PLPLOT_CPPFLAGS
  C++ flags:
    CXXFLAGS:         $CXXFLAGS
    DEFAULT_CXXFLAGS: $DEFAULT_CXXFLAGS
  Linker flags:
    LDFLAGS:          $LDFLAGS
    APR_LDFLAGS:      $APR_LDFLAGS
    SVN_LDFLAGS:      $SVN_LDFLAGS
    PLPLOT_LDFLAGS:   $PLPLOT_LDFLAGS
  Libraries:          
    LIBS              $LIBS
    APR_LIBS          $APR_LIBS
    SVN_LIBS          $SVN_LIBS
    PLPLOT_LIBS       $PLPLOT_LIBS
+++++++++++++++++++++++++++++++++++++++++++++++]dnl
)

AC_MSG_NOTICE([Now type 'make all check'.])