source: trunk/configure.ac @ 730

Last change on this file since 730 was 730, checked in by Peter Johansson, 12 years ago

Check if we HAVE_SVN_WC by looking for .svn directory rather
than relying on svnversion output.

Check if we HAVE_TEST_REPO by looking for test/repo. This variable is
used to activate test that need the test repo, i.e., they are
activated also in svn export mode.

refs #362 and #355

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 9.2 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 730 2008-12-15 13:14:14Z peter $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson
15#
16# This file is part of svndigest, http://dev.thep.lu.se/svndigest
17#
18# svndigest is free software; you can redistribute it and/or modify it
19# under the terms of the GNU General Public License as published by
20# the Free Software Foundation; either version 3 of the License, or
21# (at your option) any later version.
22#
23# svndigest is distributed in the hope that it will be useful, but
24# WITHOUT ANY WARRANTY; without even the implied warranty of
25# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
26# General Public License for more details.
27#
28# You should have received a copy of the GNU General Public License
29# along with svndigest. If not, see <http://www.gnu.org/licenses/>.
30
31AC_PREREQ(2.60)
32
33m4_include([build_support/version.m4])
34AC_INIT([svndigest],[SVNDIGEST_VERSION],[jari@thep.lu.se])
35AC_CONFIG_SRCDIR([lib/File.h])
36AC_CONFIG_AUX_DIR([autotools])
37dnl arg below should be the same as in Makefile.am
38AC_CONFIG_MACRO_DIR([build_support])
39AC_PREFIX_DEFAULT([/usr/local])
40test $prefix = NONE && prefix=/usr/local
41
42AC_SUBST([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION])
43AC_SUBST([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION])
44AC_SUBST([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION])
45
46AC_DEFINE([DEV_BUILD],[SVNDIGEST_DEV_BUILD],
47          [true if dev build (version ends with pre)])
48AC_DEFINE([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION],
49                    [Define to the svndigest major version])
50AC_DEFINE([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION],
51                    [Define to the svndigest minor version])
52AC_DEFINE([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION],
53                    [Define to the svndigest patch version])
54
55AC_CONFIG_HEADER([config.h])
56AM_INIT_AUTOMAKE([1.10 std-options check-news])
57
58# Set default programming language
59AC_LANG(C++)
60
61# Let user overide default CXXFLAGS
62if test "${CXXFLAGS+set}" != set; then
63  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
64fi
65
66# Checks for programs.
67AC_PROG_CXXCPP
68AC_PROG_CXX
69AC_PROG_INSTALL
70AC_PROG_RANLIB
71AC_PROG_SED
72AM_MISSING_PROG([HELP2MAN], [help2man])
73AC_CHECK_PROG([GNUPLOT],[gnuplot],[ok])
74
75# Save FLAGS
76SAVE_CPPFLAGS="$CPPFLAGS"
77SAVE_CXXFLAGS="$CXXFLAGS"
78SAVE_LDFLAGS="$LDFLAGS"
79SAVE_LIBS="$LIBS"
80
81# -Wno-long-long is needed to suppress compiler diagnostics regarding
82# using extension beyond the C++ standard (usage of non C++ standard
83# 'long long' types).
84SD_CXXFLAGS="$SD_CXXFLAGS-Wall -pedantic -Wno-long-long"
85AC_TYPE_LONG_LONG_INT()
86
87AC_ARG_ENABLE(debug,
88  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])],
89  [SD_CXXFLAGS="$SD_CXXFLAGS -g -O"],
90  [SD_CPPFLAGS="-DNDEBUG" SD_CXXFLAGS="$SD_CXXFLAGS -O3"])
91
92# Apache Portable Runtime (APR) API checks
93# The next three lines are not needed as long as APR_FIND_APR is used.
94# AC_ARG_WITH(apr,
95#  [  --with-apr=DIR          prefix for installed APR or path to APR build
96#                          tree [[PREFIX]]])
97# Include APR_FIND_APR macro distributed within the APR project. If
98# the usage of the APR macro is to be omitted then the construct for
99# setting the CXXFLAGS (header file location) and LDFLAGS (linking
100# informaion) for APR must be changed. The latter can be achieved with
101# AC_SEARCH_LIBS([apr_allocator_create],[apr-0],,apr_found="no") but
102# apr-0 must be prior knowledge.
103APR_FIND_APR(,,1,[1 0])
104if test "$apr_found" = "yes" ; then
105    SD_LIBS="`$apr_config --libs` $SD_LIBS"
106    SD_LDFLAGS="`$apr_config --link-ld` $SD_LDFLAGS"
107    SD_CPPFLAGS="`$apr_config --includes --cppflags` $SD_CPPFLAGS"
108fi
109
110# Subversion API checks
111svn_found="yes"
112AC_ARG_WITH(svn,
113  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
114  [ SD_LDFLAGS="-L$withval/lib $SD_LDFLAGS"
115    SD_CPPFLAGS="-I$withval/include $SD_CPPFLAGS"])
116
117
118# Use SD_*FLAGS in tests
119CPPFLAGS="$SD_CPPFLAGS $CPPFLAGS"
120CXXFLAGS="$SD_CXXFLAGS $CXXFLAGS"
121LDFLAGS="$SD_LDFLAGS $LDFLAGS"
122LIBS="$SD_LIBS $LIBS"
123
124AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
125AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
126AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],
127               [SD_LIBS="-lsvn_subr-1 $SD_LIBS"],svn_found="no")
128AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],
129               [SD_LIBS="-lsvn_ra-1 $SD_LIBS"],svn_found="no")
130AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],
131               [SD_LIBS="-lsvn_wc-1 $SD_LIBS"],svn_found="no")
132AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],
133               [SD_LIBS="-lsvn_diff-1 $SD_LIBS"],svn_found="no")
134AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],
135               [SD_LIBS="-lsvn_client-1 $SD_LIBS"],svn_found="no")
136
137# Export flags
138AC_SUBST([SVNDIGEST_CPPFLAGS], $SD_CPPFLAGS)
139AC_SUBST([SVNDIGEST_CXXFLAGS], $SD_CXXFLAGS)
140AC_SUBST([SVNDIGEST_LDFLAGS], $SD_LDFLAGS)
141AC_SUBST([SVNDIGEST_LIBS], $SD_LIBS)
142
143# Reset FLAGS
144CPPFLAGS="$SAVE_CPPFLAGS"
145CXXFLAGS="$SAVE_CXXFLAGS"
146LDFLAGS="$SAVE_LDFLAGS"
147LIBS="$SAVE_LIBS"
148
149# check if svnversion is installed
150AC_PATH_PROG([SVNVERSION], [svnversion], [no])
151
152# checking if we build in a subversion WC
153AC_CHECK_FILE([$srcdir/.svn], [wc_found="yes"], [wc_found="no"])
154AM_CONDITIONAL([HAVE_SVN_WC], [test "$wc_found" = "yes"])
155
156# checking if we have test repo
157test_repo_filename=$srcdir/test/repo;
158AC_CHECK_FILE([$test_repo_filename], [test_repo_found="yes"],
159              [test_repo_found="no"])
160AM_CONDITIONAL([HAVE_TEST_REPO], [test "$test_repo_found" = "yes"])
161if (test "$test_repo_found" = "yes"); then
162   dnl test repo is not distributed
163   AC_CONFIG_FILES([test/test_repo.sh], [chmod +x test/test_repo.sh])
164   AC_CONFIG_FILES([test/check_repo_status.sh],
165                   [chmod +x test/check_repo_status.sh])   
166fi
167
168
169AC_CONFIG_FILES([Makefile
170                bin/Makefile
171                lib/Makefile
172                man/Makefile
173                test/environment.h
174                test/Makefile])
175
176# Print failure status information about selected items, and exit if
177# fatal errors were encountered. No output will be created if
178# configure is halted prematurely.
179
180# used to trigger exit before creation of output
181all_reqs_ok="true"
182
183if (test "$wc_found" = "yes"); then
184   # svnversion is required when building from svn wc
185   if (test "$svnversion" = "no"); then
186      all_reqs_ok="false";
187      AC_MSG_WARN([dnl
188Cannot find svnversion, which is required when building from a
189subversion working copy. Please install svnversion and make sure it is
190in your search path.]);
191   fi
192   if (test "$test_repo_found" = "no"); then
193      all_reqs_ok="false";
194      AC_MSG_WARN([dnl
195Cannot find test repository (test_repo_filename), which should be
196available when building from a subversion working copy. Try svn
197update in top directory.]);
198   fi
199fi
200
201# Non-existing APR is fatal -- sub-sequent compilation will fail.
202if (test "$apr_found" = "no") ; then
203  AC_MSG_WARN([APR not found. The Apache Portable Runtime
204  (APR) library cannot be found. Please make sure APR is installed
205  and supply the appropriate --with-apr option to 'configure'.])
206  all_reqs_ok="false"
207fi
208
209# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
210if (test "$svn_found" = "no") ; then
211  svn_msg="Subversion API not found. Subversion API libraries cannot
212  be found. Make sure the APIs are installed and supply the
213  appropriate --with-svn option to 'configure'."
214  if (test "$apr_found" = "no") ; then
215    svn_msg="$svn_msg
216    Note, APR was not found. Failure to locate APR affects the search
217    of the subversion API. Please fix the APR problem before trying
218    to resolve the subversion related issues."
219  fi
220  AC_MSG_WARN([$svn_msg])
221  all_reqs_ok="false"
222fi
223
224if test $ac_cv_type_long_long_int != yes ; then
225  AC_MSG_WARN([Compiler $CXX does not support `long long'.
226  svndigest must be compiled with a compiler that supports `long long'.])
227  all_reqs_ok="false"
228fi
229
230if (test "$all_reqs_ok" = "false") ; then
231  AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
232  configure. Please consult the 'README' file for more information
233  about what is needed to compile svndigest and refer to above
234  warning messages. Needed files were NOT created.])
235fi
236
237# Create output.
238AC_OUTPUT
239
240# Some more messages.
241AC_MSG_NOTICE([])
242AC_MSG_NOTICE([   Ready to compile the executables of svndigest $VERSION])
243AC_MSG_NOTICE([   The following flags and libs will be used:])
244AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
245AC_MSG_NOTICE([    Compiler:           $CXX])
246AC_MSG_NOTICE([    Preprocessor flags: $SD_CPPFLAGS $CPPFLAGS])
247AC_MSG_NOTICE([    C++ flags:          $SD_CXXFLAGS $CXXFLAGS])
248AC_MSG_NOTICE([    Linker flags:       $SD_LDFLAGS $LDFLAGS])
249AC_MSG_NOTICE([    LIBS:               $SD_LIBS $LIBS])
250AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
251AC_MSG_NOTICE([])
252
253# Failure to locate gnuplot is not considered fatal
254if (test "$GNUPLOT" != "ok") ; then
255  AC_MSG_WARN([Gnuplot was not found. svndigest will compile
256  without gnuplot but will throw an exception at run-time. Please
257  install gnuplot (available for a wide range of operating systems
258  at http://www.gnuplot.info).])
259  AC_MSG_NOTICE([])
260fi
261
262AC_MSG_NOTICE([Now type 'make ; make check'.])
Note: See TracBrowser for help on using the repository browser.