source: trunk/configure.ac @ 1128

Last change on this file since 1128 was 1128, checked in by Jari Häkkinen, 13 years ago

Addresses #308. Stray matrix -> Matrix.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 7.8 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 1128 2008-02-23 10:03:24Z jari $
4
5# Copyright (C) 2003 Daniel Dalevi, Jari Häkkinen
6# Copyright (C) 2004 Jari Häkkinen
7# Copyright (C) 2005, 2006, 2007 Jari Häkkinen, Peter Johansson
8# Copyright (C) 2008 Jari Häkkinen
9#
10# This file is part of the yat library, http://trac.thep.lu.se/yat
11#
12# The yat library is free software; you can redistribute it
13# and/or modify it under the terms of the GNU General Public License as
14# published by the Free Software Foundation; either version 2 of the
15# License, or (at your option) any later version.
16#
17# The yat library is distributed in the hope that it will be useful,
18# but WITHOUT ANY WARRANTY; without even the implied warranty of
19# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
20# General Public License for more details.
21#
22# You should have received a copy of the GNU General Public License
23# along with this program; if not, write to the Free Software
24# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
25# 02111-1307, USA.
26#
27# If you grabbed the source from the subversion repository you should,
28# at top-level, execute:
29#     ./bootstrap
30# To push subsequent changes of this file into the build scripts you
31# must issue:
32#     autoreconf
33
34AC_INIT([yat],[0.4pre],[jari@thep.lu.se])
35AC_PREREQ(2.60)
36AC_CONFIG_SRCDIR([yat/utility/Matrix.h])
37AC_CONFIG_AUX_DIR([autotools])
38AC_PREFIX_DEFAULT([/usr/local])
39
40# Library versioning (current:revision:age)
41# See the libtool manual for an explanation of the numbers
42#
43# yat-0.3    undefined
44# yat-0.4    1:0:0
45YAT_LT_VERSION="1:0:0"
46AC_SUBST(YAT_LT_VERSION)
47
48AM_CONFIG_HEADER([config.h])
49AM_INIT_AUTOMAKE()
50
51# Set default programming language
52AC_LANG(C++)
53
54# Checks for programs.
55AC_PROG_CXX
56AC_PROG_INSTALL
57AC_PROG_SED
58AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [true], [false])
59AC_CHECK_PROG([HAVE_LATEX], [latex], [true], [false])
60
61# Checks for libraries.
62AC_CHECK_LIB(m,main)
63# searching for cblas. Priority 1) find a cblas library, 2) find ATLAS
64# generated cblas, and 3) fall back to GSL cblas implementation. If
65# partial ATLAS is detected the configure script fails.
66cblas_found="no"  # cblas_found may get values yes or no
67# atlas_found may get values yes, no, or partial. In some cases
68# partial atlas may be installed
69atlas_found="no"
70gslcblas_found="no" # gslcblas_found may get values yes or no
71AC_SEARCH_LIBS(cblas_sdsdot,cblas,cblas_found="yes",
72  AC_SEARCH_LIBS(ATL_sdsdot,atlas,
73    AC_SEARCH_LIBS(cblas_sdsdot,cblas,atlas_found="yes",
74                   atlas_found="partial",-m64),
75      AC_SEARCH_LIBS(cblas_dswap,gslcblas,gslcblas_found="yes"),-m64),)
76if test ${atlas_found} = "yes"; then
77  CXXFLAGS="$CXXFLAGS -m64" LDFLAGS="$LDFLAGS -m64"
78fi
79
80# GNU Scientific Library, GSL http://www.gnu.org/software/gsl/, checks
81# Including AM_PATH_GSL macro from gsl.m4 distributed by GSL
82gsl_found="no"
83gsl_version="1.6"
84sinclude(./build_support/gsl.m4)
85AM_PATH_GSL(${gsl_version},gsl_found="yes",gsl_version_check="no")
86if test "$gsl_found" = "yes"; then
87  # Needed to set -lgsl
88  AC_CHECK_LIB(gsl,main)
89fi
90
91# Checks for header files.
92AC_CHECK_HEADERS([unistd.h])
93
94# Checks for typedefs, structures, and compiler characteristics.
95AC_HEADER_STDBOOL
96AC_C_CONST
97AC_C_INLINE
98AC_TYPE_SIZE_T
99
100# Checks for library functions.
101AC_PROG_LIBTOOL
102AC_FUNC_ERROR_AT_LINE
103AC_HEADER_STDC
104AC_CHECK_FUNCS([pow sqrt])
105
106CXXFLAGS="$CXXFLAGS -Wall -pedantic"
107CPPFLAGS="$CPPFLAGS -DHAVE_INLINE=1"
108AC_ARG_ENABLE(debug,
109  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])])
110if test "${enable_debug}" = "yes" ; then
111  CXXFLAGS="$CXXFLAGS -g -O"
112  CPPFLAGS="$CPPFLAGS -DYAT_DEBUG=1"
113else
114  CXXFLAGS="$CXXFLAGS -O3"
115  CPPFLAGS="$CPPFLAGS -DNDEBUG -DGSL_RANGE_CHECK_OFF"
116fi
117
118# check for quiet_NaN support in OS
119# At compile time, but this may not work if quiet_NaN exists and returns
120# an incorrect value
121AC_MSG_CHECKING([for std::numeric_limits<>::quiet_NaN()])
122AC_COMPILE_IFELSE(
123  [AC_LANG_PROGRAM(
124    [#include <limits>
125     extern void f(double);],
126    [f(std::numeric_limits<double>::quiet_NaN())])],
127  [quiet_nan=yes],
128  [quiet_nan=no])
129AC_MSG_RESULT($quiet_nan)
130# At run-time, but this has the disadvantage that yat cannot be built 
131# for cross-compilation
132AC_MSG_CHECKING([if std::numeric_limits<>::has_quiet_NaN is true])
133AC_RUN_IFELSE(
134  [AC_LANG_PROGRAM(
135    [#include <limits>],
136    [return !std::numeric_limits<double>::has_quiet_NaN])],
137  [quiet_nan=yes],
138  [quiet_nan=no])
139AC_MSG_RESULT($quiet_nan)
140
141# yat specific settings
142YAT_LIB="libyat.la"
143YAT_LIB_LOCATION="yat"
144AC_SUBST(YAT_LIB)
145AC_SUBST(YAT_LIB_LOCATION)
146
147AC_CONFIG_FILES([Makefile
148     doc/Makefile
149     test/Makefile
150     test/data/Makefile
151     yat/Makefile
152     yat/classifier/Makefile
153     yat/random/Makefile
154     yat/regression/Makefile
155     yat/statistics/Makefile
156     yat/utility/Makefile])
157
158# Only warning about missing programs (needed for docs generation)
159# when in debug mode
160if (test "$enable_debug" == "yes"); then
161if (test "$HAVE_DOXYGEN" != "true") ; then
162  AC_MSG_WARN([
163  Doxygen was not found. Yat will compile and work without doxygen.
164  However, in order to enable generation of documentation, please
165  install Doxygen available at http://www.doxygen.org/
166  ])
167fi
168if (test "$HAVE_LATEX" != "true") ; then
169  AC_MSG_WARN([
170  latex was not found. Yat will compile and work without latex.
171  However, in order to enable Doxygen to generate LaTeX,
172  Postscript, and PDF output, please install latex
173  http://www.tug.org/interest.html\#free
174  ])
175fi
176fi
177
178# Print failure status information about selected items, and exit if
179# fatal errors were encountered. No output will be created if
180# configure is halted prematurely.
181
182# used to trigger exit before creation of output
183all_reqs_ok="true"
184
185# No support for quiet NAN is fatal -- sub-sequent compilation, or execution
186# of created binary, will fail.
187if test "${quiet_nan}" = "no" ; then
188  all_reqs_ok="false"
189  AC_MSG_WARN([
190  Support for quiet NAN required.
191  Yat will not work on this system!])
192fi
193
194# Non-existing BLAS is fatal -- sub-sequent compilation will fail.
195if test "${cblas_found}" = "no" -a "${atlas_found}" = "no" -a "${gslcblas_found}" = "no"; then
196  all_reqs_ok="false"
197  AC_MSG_WARN([
198  cBLAS not found. The C implementation of Basic Linear Algebra
199  Subprograms (cBLAS) library cannot be found. Please make sure
200  cBLAS is installed.])
201fi
202if test "${atlas_found}" = "partial"; then
203  all_reqs_ok="false"
204  AC_MSG_WARN([
205  Partial ATLAS BLAS library found. Please repair your installation.])
206fi
207
208# Non-existing GSL is fatal -- sub-sequent compilation will fail.
209if test "${gsl_found}" = "no" ; then
210  all_reqs_ok="false"
211  if test "${gsl_version_check}" = "no" ; then
212  AC_MSG_WARN([
213  GSL found but not the required version. Please install
214  GSL version ${gsl_version} or later])
215  else
216  AC_MSG_WARN([
217  GSL not found. The GNU Scientific Library (GSL) library cannot be
218  found. Please make sure GSL is installed.])
219  fi
220fi
221
222if (test "$all_reqs_ok" = "false") ; then
223  AC_MSG_FAILURE([
224  Some pre-requisites were not fulfilled, aborting configure.
225  Please consult the 'README' file for more information about what
226  is needed to compile yat and refer to above warning messages.
227  Needed files were NOT created.])
228fi
229
230# Create output.
231AC_OUTPUT
232
233# Some more messages.
234AC_MSG_NOTICE([])
235AC_MSG_NOTICE([ Ready to compile the yat library])
236AC_MSG_NOTICE([ The following flags and libraries will be used:])
237AC_MSG_NOTICE([ +++++++++++++++++++++++++++++++++++++++++++++++])
238AC_MSG_NOTICE([  CPPFLAGS=\"$CPPFLAGS\"])
239AC_MSG_NOTICE([  CXXFLAGS=\"$CXXFLAGS\"])
240AC_MSG_NOTICE([  LIBS=\"$LIBS\"])
241AC_MSG_NOTICE([  LDFLAGS=\"$LDFLAGS\"])
242AC_MSG_NOTICE([ +++++++++++++++++++++++++++++++++++++++++++++++])
243AC_MSG_NOTICE([])
244if test "${gslcblas_found}" = "yes"; then
245AC_MSG_NOTICE([ GSL BLAS found. This is a reference implementation only.])
246AC_MSG_NOTICE([ Consider using hardware optimized BLAS.])
247AC_MSG_NOTICE([ ATLAS (http://math-atlas.sourceforge.net/) provides an])
248AC_MSG_NOTICE([ optimized BLAS library. It is supported by yat!])
249AC_MSG_NOTICE([])
250fi
251AC_MSG_NOTICE([ Now type 'make ; make check'.])
Note: See TracBrowser for help on using the repository browser.