Changeset 1767 for trunk/configure.ac

Timestamp:

Feb 3, 2009, 8:44:16 PM (12 years ago)

Author:

Peter

Message:

reduce autoconf warnings:

• replace macro AC_TRY_COMPILE
• avoid backslash escapes within AC_MSG_NOTICE

File:

• trunk/configure.ac (modified) (2 diffs)

trunk/configure.ac

@@ -272 +272 @@
 
 AC_MSG_CHECKING([g++ deprecation attribute])
-AC_TRY_COMPILE([void f() __attribute__ ((deprecated));], [], 
-               [AC_DEFINE([YAT_HAVE_GCC_DEPRECATED], [1], 
-          [Define if compiler supports deprecated attribute, as in g++ 4.0]) 
-               AC_MSG_RESULT([yes])],
-               [AC_MSG_RESULT([no])] )
+AC_COMPILE_IFELSE(
+   [AC_LANG_PROGRAM([[void f() __attribute__ ((deprecated));]],)],  
+   [AC_DEFINE([YAT_HAVE_GCC_DEPRECATED], [1], 
+              [Define if compiler supports deprecated attribute, as in g++ 4.0]) 
+    AC_MSG_RESULT([yes])],
+   [AC_MSG_RESULT([no])] )
 
 AC_MSG_CHECKING([if std::multiset::iterator is mutable])
-AC_TRY_COMPILE([@%:@include <set> 
-                @%:@include <vector>
-               ], 
-               [std::set<std::vector<double> > s;
-                std::vector<double> v;
-                s.insert(v);
-                s.begin()->reserve(100);
-               ], 
-               [AC_DEFINE([MULTISET_ITERATOR_IS_MUTABLE], [1], 
-                          [Define if std::multiset::iterator is mutable]) 
-                AC_MSG_RESULT([yes])
-               ],
-               [AC_MSG_RESULT([no])] )
-
+AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@%:@include <set> 
+                                     @%:@include <vector>]],
+                                   [[std::set<std::vector<double> > s;
+                                     std::vector<double> v;
+                                     s.insert(v);
+                                     s.begin()->reserve(100);
+                                   ]])],
+                  [AC_DEFINE([MULTISET_ITERATOR_IS_MUTABLE], [1], 
+                             [Define if std::multiset::iterator is mutable]) 
+                   AC_MSG_RESULT([yes])
+                  ],
+                  [AC_MSG_RESULT([no])] )
 
 # yat specific settings
@@ -430 +429 @@
 AC_MSG_NOTICE([ The following flags and libraries will be used:])
 AC_MSG_NOTICE([ +++++++++++++++++++++++++++++++++++++++++++++++])
-AC_MSG_NOTICE([  CPPFLAGS=\"$CPPFLAGS\"])
-AC_MSG_NOTICE([  AM_CPPFLAGS=\"$AM_CPPFLAGS\"])
-AC_MSG_NOTICE([  CXXFLAGS=\"$CXXFLAGS\"])
-AC_MSG_NOTICE([  AM_CXXFLAGS=\"$AM_CXXFLAGS\"])
-AC_MSG_NOTICE([  LDFLAGS=\"$LDFLAGS\"])
-AC_MSG_NOTICE([  AM_LDFLAGS=\"$AM_LDFLAGS\"])
-AC_MSG_NOTICE([  LIBS=\"$LIBS\"])
+AC_MSG_NOTICE([  CPPFLAGS=$CPPFLAGS])
+AC_MSG_NOTICE([  AM_CPPFLAGS=$AM_CPPFLAGS])
+AC_MSG_NOTICE([  CXXFLAGS=$CXXFLAGS])
+AC_MSG_NOTICE([  AM_CXXFLAGS=$AM_CXXFLAGS])
+AC_MSG_NOTICE([  LDFLAGS=$LDFLAGS])
+AC_MSG_NOTICE([  AM_LDFLAGS=$AM_LDFLAGS])
+AC_MSG_NOTICE([  LIBS=$LIBS])
 AC_MSG_NOTICE([ +++++++++++++++++++++++++++++++++++++++++++++++])
 AC_MSG_NOTICE([])