source: trunk/lib/docbook/custom-styles/docbook/plain/xsl/customized.chunked.xsl @ 3307

<?xml version='1.0'?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:fo="http://www.w3.org/1999/XSL/Format"
                xmlns:date="http://exslt.org/dates-and-times"
                exclude-result-prefixes="date"
                version='1.0'>

<xsl:import href="../../../lib/docbook/docbook/xsl/html/chunk.xsl" />

<!-- (MM20040315) xsl parameters moved from ant-build-docbook.xml to here -->
<xsl:param name="table.borders.with.css" select="1"/>
<xsl:param name="html.stylesheet">css/docbook.css</xsl:param>
<xsl:param name="html.stylesheet.type">text/css</xsl:param>        
<xsl:param name="section.label.includes.component.label" select="1" />         
<xsl:param name="section.autolabel" select="1" />
<xsl:param name="section.autolabel.max.depth" select="2" />
<xsl:param name="chunk.first.sections" select="1" />
<xsl:param name="chunk.section.depth" select="2" />
<xsl:param name="chunk.fast" select="1" />
<xsl:param name="toc.max.depth" select="4"/>
<xsl:param name="toc.section.depth" select="3" />
<xsl:param name="generate.section.toc.level" select="1" />
<xsl:param name="generate.toc">
appendix  toc,title
article/appendix  nop
article   toc,title
book      toc,title
chapter   toc,title
part      toc,title
preface   toc,title
qandadiv  toc
qandaset  toc
reference toc,title
sect1     toc
sect2     toc
sect3     toc
sect4     toc
sect5     toc
section   toc
set       toc,title
</xsl:param>
<xsl:param name="make.graphic.viewport" select="0"/>
<xsl:param name="callout.graphics" select="1" />
<xsl:param name="callout.graphics.path">gfx/admonitions/callouts/</xsl:param>
<xsl:param name="callout.graphics.extension">.gif</xsl:param>
<xsl:param name="admon.graphics" select="1"/>
<xsl:param name="admon.graphics.path">gfx/admonitions/</xsl:param>
<xsl:param name="admon.graphics.extension">.gif</xsl:param>
<xsl:param name="admon.style">margin-left: 2em; margin-right: 2em;</xsl:param>
<xsl:param name="admonition.title.properties">text-align: left</xsl:param>

<xsl:param name="keep.relative.image.uris" select="false"/>

<xsl:param name="use.id.as.filename" select="1"/>

<xsl:param name="chunker.output.encoding">utf-8</xsl:param>
<xsl:param name="chunker.output.indent">yes</xsl:param>

<!-- (MM20040315) base.dir and root.filename are coming from the ant-build-docbook.xml -->
<xsl:param name="base.dir">@base.dir@/</xsl:param>
<xsl:param name="root.filename">@root.filename@</xsl:param>

<!-- doc.revision and doc.last.modified -->
<xsl:param name="doc.revision">@doc.revision@</xsl:param>
<xsl:param name="doc.last.modified">@doc.last.modified@</xsl:param>
<xsl:param name="base.version">@base.version@</xsl:param>

<!-- convert url-only references to a format that is wrappable -->

<xsl:template match="ulink" name="ulink">
  <xsl:choose>
  <xsl:when test="count(child::node())=0">
  <a>
      <xsl:if test="@id">
        <xsl:attribute name="name">
          <xsl:value-of select="@id"/>
        </xsl:attribute>
      </xsl:if>
      <xsl:attribute name="href"><xsl:value-of select="@url"/></xsl:attribute>
      <xsl:if test="$ulink.target != ''">
        <xsl:attribute name="target">
          <xsl:value-of select="$ulink.target"/>
        </xsl:attribute>
      </xsl:if> 
    <xsl:if test="count(child::node())=0">
        <xsl:call-template name="insertInvisibleBreaks">
            <xsl:with-param name="url" select="@url" />
            <xsl:with-param name="breakat" select="translate(@url, '/-_:', '____')" />
        </xsl:call-template>
    </xsl:if>
  </a>
  </xsl:when>
  <xsl:otherwise>
  <xsl:apply-imports/>
  </xsl:otherwise>
  </xsl:choose>
</xsl:template> 

<xsl:template name="insertInvisibleBreaks">
    <xsl:param name="url" />
    <xsl:param name="breakat" />
    <!-- <xsl:message><xsl:value-of select="concat('param:', $url, $breakat)" /></xsl:message> -->
    <xsl:choose>
        <xsl:when test="contains($breakat, '_')">
            <xsl:value-of select="substring($url, 1, string-length(substring-before($breakat, '_'))+1)" /><wbr/>
            <xsl:call-template name="insertInvisibleBreaks">
                <xsl:with-param name="url" select="substring($url, string-length(substring-before($breakat, '_'))+2)"/>
                <xsl:with-param name="breakat" select="substring($breakat, string-length(substring-before($breakat, '_'))+2)"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$url" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

<!-- Base specific templates -->

<xsl:template match="helptext">
  <xsl:choose>
    <xsl:when test="@webonly = '0'">  
      <xsl:apply-templates />
    </xsl:when>
  </xsl:choose>
</xsl:template>

<xsl:template match="seeother|other">
</xsl:template>

<xsl:template match="nohelp">
  <xsl:apply-templates />
</xsl:template>

<xsl:template name="user.footer.navigation">
  <div 
    class="navfooter"
    align="left">
    <p>
    <i>
      <xsl:if test="$doc.revision" >
        Version: <xsl:value-of select="$base.version"/> (build #<xsl:value-of select="$doc.revision"/>)<br/>
      </xsl:if>
      <xsl:if test="$doc.last.modified" >
        Book last modified: <xsl:value-of select="$doc.last.modified" />
      </xsl:if>
    </i></p>
  </div>
</xsl:template>

  <xsl:template name="convertpath">
    <xsl:param name="path" select="''" />
    <xsl:choose>
      <xsl:when test="contains($path, '/')">
        <xsl:text>../</xsl:text>
        <xsl:call-template name="convertpath">
          <xsl:with-param name="path" select="substring-after($path, '/')" />
        </xsl:call-template>
      </xsl:when>
    </xsl:choose>
  </xsl:template>

  <xsl:template name="pathtorootdir">
    <xsl:variable name="dir">
      <xsl:call-template name="dbhtml-dir">
        <xsl:with-param name="context" select="." />
      </xsl:call-template>
    </xsl:variable>
    <xsl:call-template name="convertpath">
      <xsl:with-param name="path" select="$dir" />
    </xsl:call-template>
  </xsl:template>

  <xsl:template name="output.html.stylesheets">
    <xsl:param name="stylesheets" select="''" />
    <xsl:variable name="pathtorootdir">
      <xsl:call-template name="pathtorootdir" />
    </xsl:variable>
    <xsl:choose>
      <xsl:when test="contains($stylesheets, ' ')">
        <link rel="stylesheet"
          href="{substring-before(concat($pathtorootdir, $stylesheets), ' ')}">
          <xsl:if test="$html.stylesheet.type != ''">
            <xsl:attribute name="type">
              <xsl:value-of select="$html.stylesheet.type" />
            </xsl:attribute>
          </xsl:if>
        </link>
        <xsl:call-template name="output.html.stylesheets">
          <xsl:with-param name="stylesheets" select="substring-after($stylesheets, ' ')" />
        </xsl:call-template>
      </xsl:when>
      <xsl:when test="$stylesheets != ''">
        <link rel="stylesheet" href="{concat($pathtorootdir,$stylesheets)}">
          <xsl:if test="$html.stylesheet.type != ''">
            <xsl:attribute name="type">
              <xsl:value-of select="$html.stylesheet.type" />
            </xsl:attribute>
          </xsl:if>
        </link>
      </xsl:when>
    </xsl:choose>
  </xsl:template>
  
  <xsl:template name="admon.graphic">
    <xsl:param name="node" select="." />
    <xsl:variable name="pathtorootdir">
      <xsl:call-template name="pathtorootdir"/>
    </xsl:variable>
    <xsl:value-of select="concat($pathtorootdir, $admon.graphics.path)" />
    <xsl:choose>
      <xsl:when test="local-name($node)='note'">note</xsl:when>
      <xsl:when test="local-name($node)='warning'">warning</xsl:when>
      <xsl:when test="local-name($node)='caution'">caution</xsl:when>
      <xsl:when test="local-name($node)='tip'">tip</xsl:when>
      <xsl:when test="local-name($node)='important'">important</xsl:when>
      <xsl:otherwise>note</xsl:otherwise>
    </xsl:choose>
    <xsl:value-of select="$admon.graphics.extension" />
  </xsl:template>

</xsl:stylesheet>