source: plugins/base1/se.lu.thep.wenni/trunk/configure.ac @ 837

# Process this file with autoconf to produce a configure script.
#
# $Id: configure.ac 837 2008-11-28 19:12:47Z peter $
#
# Copyright (C) 2005, 2006 Jari Häkkinen, Peter Johansson
# Copyright (C) 2007 Peter Johansson
# Copyright (C) 2008 Jari Häkkinen Peter Johansson
#
# This file is part of WeNNI,
# http://baseplugins.thep.lu.se/wiki/se.lu.thep.WeNNI
#
# WeNNI is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by the
# Free Software Foundation; either version 3 of the License, or (at
# your option) any later version.
#
# WeNNI is distributed in the hope that it will be useful, but WITHOUT
# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
# FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
# for more details.
#
# You should have received a copy of the GNU General Public License
# along with WeNNI. If not, see <http://www.gnu.org/licenses/>.
#
# Author: Jari Hakkinen, jari@thep.lu.se
#
# If you grabbed the source from subversion you should, at top-level,
# execute:
#   ./bootstrap
#

AC_PREREQ(2.57)
AC_INIT([wenni],[0.7pre],[jari@thep.lu.se])
AC_CONFIG_SRCDIR([lib/weight.h])
AC_CONFIG_AUX_DIR([autotools])
AC_PREFIX_DEFAULT([/usr/local])

AM_CONFIG_HEADER([config.h])
AM_INIT_AUTOMAKE

# Set default programming language
AC_LANG(C++)

# Checks for programs.
AC_PROG_CPP
AC_PROG_CXX
AC_PROG_INSTALL
AC_PROG_LIBTOOL
AC_PROG_RANLIB
AC_PROG_SED

CXXFLAGS="-Wall -pedantic"
CPPFLAGS="-DHAVE_INLINE=1"
AC_ARG_ENABLE(debug,
              [ AS_HELP_STRING([--enable-debug],
                               [turn on debug options and code]) ],
              [ CXXFLAGS="$CXXFLAGS -g -O" ],
              [ CXXFLAGS="$CXXFLAGS -O3"
                CPPFLAGS="$CPPFLAGS -DNDEBUG -DGSL_RANGE_CHECK_OFF" ])

AC_ARG_ENABLE(state,
              [ AS_HELP_STRING([--enable-state],
                               [stand-alone, base1, or base2 [default=base2]])],
              [ if test "x$enableval" = "xstand-alone" ; then
                    state="stand-alone"
                elif test "x$enableval" = "xbase1" ; then
                    state="base1"
                elif test "x$enableval" = "xbase2" ; then
                    state="base2"
                else
                    AC_MSG_ERROR([dnl
Unknown value for `--enable-state'
allowed values are: `base2', `base1', or `stand-alone'])
                fi ],
              [ state="base2" ])

AM_CONDITIONAL([BASE1], [test x$state = xbase1])
AM_CONDITIONAL([BASE2], [test x$state = xbase2])

AC_ARG_WITH(basedir,[AS_HELP_STRING([--with-basedir=DIR]), 
                     [root directory for base installation])],
            [BASEDIR=$withval],[BASEDIR=/usr/local/base])

AC_ARG_WITH(plugindir,[AS_HELP_STRING([--with-plugindir=DIR],
                      [root directory for base plug-ins])],
            [PLUGINDIR=$withval],
            [if (test x$state = xbase1); then
               PLUGINDIR="$BASEDIR/plugins/bin/wenni"
             elif (test x$state = xbase2); then
               PLUGINDIR="$BASEDIR/plugins/se/lu/thep/wenni"
             fi])

if (test x$state = xbase1); then
  # check for BASE1 API
  OLD_CPPFLAGS=$CPPFLAGS;
  OLD_LDFLAGS=$LDFLAGS;
  LDFLAGS="-L$BASEDIR/lib"
  AC_CHECK_LIB([base], [base_finite], [BASELDFLAGS="-L$BASEDIR/lib -lbase"],
               [AC_MSG_FAILURE([cannot find base library])])
  CPPFLAGS="-I$BASEDIR/include/cxx $CPPFLAGS"
  AC_CHECK_HEADERS([basefile.h],[BASECPPFLAGS=-I$BASEDIR/include/cxx],
               [AC_MSG_FAILURE([cannot find base header files])])
  CPPFLAGS=$OLD_CPPFLAGS;
  LDFLAGS=$OLD_LDFLAGS;
  AC_SUBST(BASECPPFLAGS)
  AC_SUBST(BASELDFLAGS)
  # Set BASE1 plug-in name
  BASEPLUGINEXECNAME=$PLUGINDIR/wenni.pl
  AC_SUBST(BASEPLUGINEXECNAME)
  AC_CONFIG_FILES([base/base1/base_plugin_script/plugin_WeNNI.base])
fi
if (test x$state = xbase2); then
  AC_CHECK_FILE([$BASEDIR/www/WEB-INF/lib/BASE2Core.jar], [],
                [AC_MSG_FAILURE([cannot find BASE2Core.jar])])
  JAVACFLAGS=$BASEDIR/www/WEB-INF/lib/BASE2Core.jar
  AC_CHECK_FILE([$BASEDIR/www/WEB-INF/lib/BASE2CorePlugins.jar], [],
                [AC_MSG_FAILURE([cannot find BASE2CorePlugins.jar])])
  JAVACFLAGS="$BASEDIR/www/WEB-INF/lib/BASE2CorePlugins.jar:$JAVACFLAGS"
  AC_SUBST(JAVACFLAGS)
fi

AC_ARG_WITH(gsl,[AS_HELP_STRING([--with-gsl=DIR], [prefix for gsl files])],
            [CPPFLAGS="-I$withval/include $CPPFLAGS" 
             LDFLAGS="-L$withval/lib $LDFLAGS"], [])

AC_SEARCH_LIBS(sqrt, m)
AC_SEARCH_LIBS(ATL_ctrsv, atlas, [LIBS="-lcblas $LIBS"],
               AC_SEARCH_LIBS(cblas_sdsdot, gslcblas))
AC_SEARCH_LIBS(gsl_vector_alloc, gsl)

CPP_TOOLS_LIBPATH="lib/c++_tools"
AC_SUBST(CPP_TOOLS_LIBPATH)

AC_CONFIG_FILES([Makefile
                 base/Makefile
                 base/base1/Makefile
                 base/base1/base_plugin_script/Makefile
                 base/base1/BaseFileConverter/Makefile
                 base/base2/Makefile
                 bin/Makefile
                 bin/NNIFileConverter/Makefile
                 bin/nni/Makefile
                 data/Makefile
                 lib/Makefile
                 lib/c++_tools/Makefile
                 lib/c++_tools/gslapi/Makefile
                 lib/c++_tools/utility/Makefile
                 test/Makefile])

AC_OUTPUT

# Some more messages.
AC_MSG_NOTICE([])
AC_MSG_NOTICE([ Ready to build WeNNI package containing])
AC_MSG_NOTICE([])
AC_MSG_NOTICE([     stand-alone binaries:])
AC_MSG_NOTICE([         NNIFileConverter])
AC_MSG_NOTICE([         nni])
if (test x$state = xbase1); then
  AC_MSG_NOTICE([     BASE1 plug-in:])
  AC_MSG_NOTICE([         BaseFileConverter])
  AC_MSG_NOTICE([         base_plugin_script])
fi
if (test x$state = xbase2); then
  AC_MSG_NOTICE([     BASE2 plug-in:])
  AC_MSG_NOTICE([         WeNNI.jar])
fi
AC_MSG_NOTICE([])
AC_MSG_NOTICE([ WeNNI package will be installed in])
AC_MSG_NOTICE([    $PLUGINDIR ])
AC_MSG_NOTICE([])
AC_MSG_NOTICE([ The following libs and flags will be used:])
AC_MSG_NOTICE([ +++++++++++++++++++++++++++++++++++++++++++++++])
AC_MSG_NOTICE([  CPPFLAGS    =\"$CPPFLAGS\"])
AC_MSG_NOTICE([  CXXFLAGS    =\"$CXXFLAGS\"])
AC_MSG_NOTICE([  LDFLAGS     =\"$LDFLAGS\"])
AC_MSG_NOTICE([  LIBS        =\"$LIBS\"])
if (test x$state = xbase1); then
  AC_MSG_NOTICE([  BASECPPFLAGS=\"$BASECPPFLAGS\"])
  AC_MSG_NOTICE([  BASELDFLAGS =\"$BASELDFLAGS\"])
fi
if (test x$state = xbase2); then
  AC_MSG_NOTICE([  JAVACFLAGS=\"$JAVACFLAGS\"])
fi
AC_MSG_NOTICE([ +++++++++++++++++++++++++++++++++++++++++++++++])
AC_MSG_NOTICE([])
AC_MSG_NOTICE([ Now type 'make ; make check ; make install'.])