source: plugins/base2/net.sf.basedb.normalizers/trunk/src/c++/configure.ac @ 1055

# Process this file with autoconf to produce a configure script.
#
# $Id: configure.ac 1055 2009-05-06 22:43:30Z jari $
#
# Copyright (C) 2005, 2006 Jari Häkkinen, Peter Johansson
# Copyright (C) 2007 Peter Johansson
# Copyright (C) 2008, 2009 Jari Häkkinen, Peter Johansson
#
# This file is part of the Normalizers plug-in package for BASE
# (net.sf.based.normalizers). The package is available at
# http://baseplugins.thep.lu.se/ BASE main site is
# http://base.thep.lu.se/
#
# This is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3 of the License, or
# (at your option) any later version.
#
# The software is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
# General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program. If not, see <http://www.gnu.org/licenses/>.
#
# If you grabbed the source from subversion you should, at top-level,
# execute:
#   ./bootstrap
#

AC_INIT([qqn],[@PKGVERSION@],[jari.hakkinen@med.lu.se])
AC_PREREQ(2.61)
AC_CONFIG_SRCDIR([bin/qQN.cc])
AC_CONFIG_AUX_DIR([autotools])
AC_PREFIX_DEFAULT([/usr/local])
AC_CONFIG_MACRO_DIR([m4])

AM_CONFIG_HEADER([config.h])
AM_INIT_AUTOMAKE([1.10 std-options])

# Set default programming language
AC_LANG(C++)

# Let user overide default CXXFLAGS
if (test "${CXXFLAGS+set}" != set) ; then
  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
  CXXFLAGS="-Wall -pedantic -O3"
fi

# Checks for programs.
AC_PROG_CXXCPP
AC_PROG_CXX
AC_PROG_INSTALL

AC_ARG_ENABLE(libcheck,
              [AS_HELP_STRING([--enable-libcheck],
                              [Check for dependency libs (default is yes)])],
              if (test "$enableval" = "no") ; then
                libcheck=no
              fi
             )

# checking for dependency libs may be disabled, normally used to
# create a source distribuion on a machine wihtout required APIs like
# yat.
if (test "${libcheck}" = "no") ; then
  yat_found="not checked"
else
  yat_found="no"
  yat_version="0.5.3"
  YAT_CHECK_YAT([${yat_version}],[yat_found="yes"])
  if (test "${yat_found}" = "yes") ; then
    AM_CPPFLAGS="$YAT_CPPFLAGS $AM_CPPFLAGS"
    AM_CXXFLAGS="$YAT_CXXFLAGS $AM_CXXFLAGS"
    AM_LDFLAGS="$YAT_LDFLAGS $AM_LDFLAGS"
    LIBS="$YAT_LIBS $LIBS"
  fi
  AC_SUBST(AM_CPPFLAGS)
  AC_SUBST(AM_CXXFLAGS)
  AC_SUBST(AM_LDFLAGS)
fi

AC_CONFIG_FILES([Makefile
                 bin/Makefile])

# Non-existing or too old yat is fatal -- sub-sequent compilation will fail.
if (test "${yat_found}" = "no") ; then
  AC_CHECK_HEADER(
    [yat/utility/utility.h],
    AC_MSG_FAILURE([
    yat found but not the required version.
    Please upgrade to yat version ${yat_version} or later]),
    AC_MSG_FAILURE([
    yat not found. The yat library cannot be found.
    Please make sure yat is installed.])
  )
fi

AC_OUTPUT

# Some more messages.
AC_MSG_NOTICE([])
AC_MSG_NOTICE([Ready to build qQN])
AC_MSG_NOTICE([])
AC_MSG_NOTICE([qQN will be installed in])
AC_MSG_NOTICE([    $bindir ])
AC_MSG_NOTICE([])
AC_MSG_NOTICE([The following libs and flags will be used:])
AC_MSG_NOTICE([+++++++++++++++++++++++++++++++++++++++++++++++])
AC_MSG_NOTICE([  CPPFLAGS     = $CPPFLAGS $AM_CPPFLAGS])
AC_MSG_NOTICE([  CXXFLAGS     = $CXXFLAGS $AM_CXXFLAGS])
AC_MSG_NOTICE([  LDFLAGS      = $LDFLAGS $AM_LDFLAGS])
AC_MSG_NOTICE([  LIBS         = $LIBS])
AC_MSG_NOTICE([+++++++++++++++++++++++++++++++++++++++++++++++])
AC_MSG_NOTICE([])
AC_MSG_NOTICE([ Now type 'make && make install'.])
if (test "${libcheck}" = "no") ; then
  AC_MSG_NOTICE([])
  AC_MSG_NOTICE([Checks for dependency libs disabled, make will probably fail.])
fi