source: trunk/misc/install/install-win.bat @ 4085

@echo off
rem
rem install-win.bat
rem

rem Copyright (C) 2006 Gregory Vincic, Jari Hakkinen, Olle Mansson
rem Copyright (C) 2007 Gregory Vincic, Olle Mansson
rem
rem Files are copyright by their respective authors. The contributions to
rem files where copyright is not explicitly stated can be traced with the
rem source code revision system.
rem
rem This file is part of Proteios.
rem Available at http://www.proteios.org/
rem
rem Proteios is free software; you can redistribute it and/or
rem modify it under the terms of the GNU General Public License
rem as published by the Free Software Foundation; either version 2
rem of the License, or (at your option) any later version.
rem
rem Proteios is distributed in the hope that it will be useful,
rem but WITHOUT ANY WARRANTY, without even the implied warranty of
rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
rem GNU General Public License for more details.
rem
rem You should have received a copy of the GNU General Public License
rem along with this program; if not, write to the Free Software
rem Foundation, Inc., 59 Temple Place - Suite 330,
rem Boston, MA 02111-1307, USA.

rem
rem Performs Proteios 2.x installation on Microsoft Windows.
rem
rem Uses bat file inp2var.bat to store console input data
rem into a given variable.
rem
rem Usage: inp2var.bat var_name [promptfile [mask_input]]
rem
rem Used programs/files:
rem
rem inp2var.bat
rem   inp2var.jar
rem Replace.jar
rem

rem
rem Configuration
rem
set sql_client=mysql
set app_name=proteios
set build_dir=www\WEB-INF\classes
rem Store system host name in environment variable %host_name% for use in default notification e-mail "from"-address
java -jar GetHostName.jar > prompt.txt
call inp2var.bat host_name prompt.txt no_input
rem
rem End Configuration
rem

rem
rem Welcome message and installation references
rem
echo.
echo.
echo Welcome to the %app_name% installation.
echo.
echo For more information on the installation steps, see:
echo http://www.proteios.org/wiki/Installation
echo.

rem
rem Get DBMS hostname, administrator name and password
rem
:step_1a
set body_text=1. Enter database host name and user name with create privileges on your DBMS.
set next_step=step_1b
goto print
:step_1b
echo    Database Host [localhost]: > prompt.txt
call inp2var.bat db_host prompt.txt
if "%db_host%"=="" set db_host=localhost
echo    Username [root]: > prompt.txt
call inp2var.bat db_manager prompt.txt
if "%db_manager%"=="" set db_manager=root
echo    Password: > prompt.txt
call inp2var.bat db_manager_pwd prompt.txt mask_input
echo.

rem
rem Get Proteios root password
rem
:step_2a
set body_text=2. Enter a password for the root account in %app_name%.
set next_step=step_2b
goto print
:step_2b
echo    Password: > prompt.txt
call inp2var.bat root_pwd prompt.txt mask_input
echo.

rem
rem Get DBMS name
rem
:step_3a
set body_text=3. Configure the database name and user that %app_name% will use to connect to your DBMS.
set next_step=step_3b
goto print
:step_3b
echo    Database name [%app_name%]: > prompt.txt
call inp2var.bat db_name prompt.txt
if "%db_name%"=="" set db_name=%app_name%

rem
rem Get DBMS user name and password
rem
echo    Username [%app_name%]: > prompt.txt
call inp2var.bat app_user prompt.txt
if "%app_user%"=="" set app_user=%app_name%
echo    Password: > prompt.txt
call inp2var.bat app_user_pwd prompt.txt mask_input
echo.


rem
rem Get user files directory.
rem
:step_4a
set body_text=4. Select a directory for %app_name% to use for user files.
set next_step=step_4b
goto print
:step_4b
echo    User files directory [C:\%app_name%]: > prompt.txt
call inp2var.bat user_files_dir prompt.txt
if "%user_files_dir%"=="" set user_files_dir=C:\%app_name%
rem
rem Store user files directory name with backslashes "\"
rem exchanged for slashes "/" in variable %user_files_dir_slashes%
rem
echo %user_files_dir% > prompt.txt
call inp2var.bat user_files_dir_slashes prompt.txt no_input_convert_backslashes

rem
rem Get temporary files directory.
rem
:step_5a
set body_text=5. Select a directory for %app_name% to use for temporary files.
set next_step=step_5b
goto print
:step_5b
echo    Temporary files directory [C:\temp]: > prompt.txt
call inp2var.bat temp_files_dir prompt.txt
if "%temp_files_dir%"=="" set temp_files_dir=C:\temp
rem
rem Store temporary files directory name with backslashes "\"
rem exchanged for slashes "/" in variable %temp_files_dir_slashes%
rem
echo %temp_files_dir% > prompt.txt
call inp2var.bat temp_files_dir_slashes prompt.txt no_input_convert_backslashes

rem
rem Get FTP control port.
rem
:step_6a
set body_text=6. Select control port for %app_name% FTP Server.
set next_step=step_6b
goto print
:step_6b
echo    FTP Server Control Port [8021]: > prompt.txt
call inp2var.bat ftp_control_port prompt.txt
if "%ftp_control_port%"=="" set ftp_control_port=8021

rem
rem Get optional FTP passive port range.
rem
:step_7a
set body_text=7. Set optional passive port range for %app_name% FTP Server (min,max or blank).
set next_step=step_7b
goto print
:step_7b
echo    FTP Server Passive Port Range []: > prompt.txt
call inp2var.bat ftp_passive_port_range prompt.txt
if "%ftp_passive_port_range%"=="" set ftp_passive_port_range=

rem
rem Get outgoing mail server for notification e-mail.
rem
:step_8a
set body_text=8. Set outgoing mail server for %app_name% notification e-mail.
set next_step=step_8b
goto print
:step_8b
echo    Mail server []: > prompt.txt
call inp2var.bat mail_server prompt.txt
if "%mail_server%"=="" set mail_server=

rem
rem Get "from"-address for notification e-mail.
rem
:step_9a
set body_text=9. Set "from"-address for %app_name% notification e-mail.
set next_step=step_9b
goto print
:step_9b
echo    Mail "from"-address [noreply@%host_name%]: > prompt.txt
call inp2var.bat mail_from_address prompt.txt
if "%mail_from_address%"=="" set mail_from_address=noreply@%host_name%

:step_9c
rem
rem Print summary of selected options
rem
set body_text=Thank you! Selected options for the installation:
set next_step=step_9c1
goto print
:step_9c1
echo    Database Host name       : %db_host%
echo    Database Manager Username: %db_manager%
echo    Database name            : %db_name%
echo    '%app_name%' Database Username                 : %app_user%
echo    '%app_name%' User Files Directory              : %user_files_dir%
echo    '%app_name%' Temporary Files Directory         : %temp_files_dir%
echo    '%app_name%' FTP Server Control Port           : %ftp_control_port%
echo    '%app_name%' FTP Server Passive Port Range     : %ftp_passive_port_range%
echo    '%app_name%' Outgoing mail server              : %mail_server%
echo    '%app_name%' notification e-mail "from"-address: %mail_from_address%
echo.
echo Do you want to continue the installation[y/N]? > prompt.txt
call inp2var.bat continue_install prompt.txt
if "%continue_install%"=="" set continue_install=N
if "%continue_install%"=="y" set continue_install=Y
if not "%continue_install%"=="Y" set continue_install=N
if "%continue_install%"=="Y" goto yes_install
set body_text=Installation stopped. Please try again later.
set next_step=step_9c2
goto print
:step_9c2
goto finish
rem
rem
rem
:yes_install
set body_text=Let's continue with the installation.
set next_step=step_9c3
goto print
:step_9c3


rem
rem Installation
rem
rem
rem Database setup. If database at localhost, do not use -h option.
rem
set sql_exec=%sql_client% -h %db_host% -u %db_manager% -p%db_manager_pwd% -e
if "%db_host%"=="localhost" set sql_exec=%sql_client% -u %db_manager% -p%db_manager_pwd% -e
rem
rem Only ask if database should be dropped, if it shouldn't be updated.
rem
echo Do you want to update an existing '%db_name%' database [y/N]? > prompt.txt
call inp2var.bat update_db prompt.txt
if "%update_db%"=="" set update_db=N
if "%update_db%"=="y" set update_db=Y
if not "%update_db%"=="Y" set update_db=N
if "%update_db%"=="Y" goto yes_update
rem
rem No database update, ask if database should be dropped.
rem
echo Do you want to drop the existing '%db_name%' database [y/N]? > prompt.txt
call inp2var.bat drop_db prompt.txt
if "%drop_db%"=="" set drop_db=N
if "%drop_db%"=="y" set drop_db=Y
if not "%drop_db%"=="Y" set drop_db=N
if "%drop_db%"=="N" goto no_drop
rem
rem Dropping existing database [optional]
rem
echo Dropping database...
%sql_exec% "DROP DATABASE IF EXISTS `%db_name%`;"
echo done
:no_drop
:yes_update

rem
rem Create database if not existing
rem
rem (Error checking is needed here)
rem
%sql_exec% "CREATE DATABASE IF NOT EXISTS `%db_name%` DEFAULT CHARACTER SET utf8;"
%sql_exec% "GRANT ALL ON `%db_name%`.* TO '%app_user%'@'%db_host%' IDENTIFIED BY '%app_user_pwd%'; FLUSH PRIVILEGES;"

rem
rem Update proteios configuration file (parsed by InitDB program)
rem
rem
rem Store current directory in variable %here%
rem
cd > prompt.txt
call inp2var.bat here prompt.txt no_input
echo Updating %app_name% *.config files in %build_dir%
cd %build_dir%
rem
rem Insert database username, password, name, and user files directory
rem in file proteios.config.in.
rem
java -jar "%here%"\Replace.jar proteios.config.in proteios.config __USERNAME__=%app_user% __PASSWORD__=%app_user_pwd% __DATABASE__=%db_name% __USERFILES__=%user_files_dir_slashes% __HOST__=%db_host% __SMTPHOST__=%mail_server% __MAIL_FROM_ADDRESS__=%mail_from_address%
cd %here%

rem
rem Update proteios web.xml file (used by Tomcat)
rem
echo Updating %app_name% web.xml file
cd %build_dir%\..
rem
rem Insert temporary files directory
rem in file web.xml.in.
rem
java -jar "%here%"\Replace.jar web.xml.in web.xml __TEMPFILES__=%temp_files_dir_slashes%
cd %here%

rem
rem Update proteios ftp.properties file (used by FTP Server)
rem
echo Updating %app_name% ftp.properties file
cd %build_dir%
rem
rem Insert control port number
rem and passive port range
rem in file ftp.properties.in.
rem
java -jar "%here%"\Replace.jar ftp.properties.in ftp.properties __CONTROL_PORT__=%ftp_control_port% __PASSIVE_PORT_RANGE__=%ftp_passive_port_range% __USERNAME__=%app_user% __PASSWORD__=%app_user_pwd% __DATABASE__=%db_name% __USERFILES__=%user_files_dir_slashes%  __HOST__=%db_host%
cd %here%

rem
rem Create proteios xtandem.properties file if not existing.
rem
cd %build_dir%
if exist xtandem.properties goto xtandem_properties_file_ok
echo Creating X!Tandem search config file xtandem.properties...
copy xtandem.properties.in xtandem.properties
goto xtandem_properties_file_end
:xtandem_properties_file_ok
echo X!Tandem search config file xtandem.properties exists - OK.
:xtandem_properties_file_end
cd %here%

rem
rem Create proteios mascot.properties file if not existing.
rem
cd %build_dir%
if exist mascot.properties goto mascot_properties_file_ok
echo Creating Mascot search config file mascot.properties...
copy mascot.properties.in mascot.properties
goto mascot_properties_file_end
:mascot_properties_file_ok
echo Mascot search config file mascot.properties exists - OK.
:mascot_properties_file_end
cd %here%

rem
rem Create proteios omssa.properties file if not existing.
rem
cd %build_dir%
if exist omssa.properties goto omssa_properties_file_ok
echo Creating OMSSA search config file omssa.properties...
copy omssa.properties.in omssa.properties
goto omssa_properties_file_end
:omssa_properties_file_ok
echo OMSSA search config file omssa.properties exists - OK.
:omssa_properties_file_end
cd %here%

rem
rem Create proteios pike.properties file if not existing.
rem
cd %build_dir%
if exist pike.properties goto pike_properties_file_ok
echo Creating PIKE search config file pike.properties...
copy pike.properties.in pike.properties
goto pike_properties_file_end
:pike_properties_file_ok
echo PIKE search config file pike.properties exists - OK.
:pike_properties_file_end
cd %here%

rem
rem Create proteios msinspect.properties file if not existing.
rem
cd %build_dir%
if exist msinspect.properties goto msinspect_properties_file_ok
echo Creating msInspect feature detection config file msinspect.properties...
copy msinspect.properties.in msinspect.properties
goto msinspect_properties_file_end
:msinspect_properties_file_ok
echo msInspect feature detection config file msinspect.properties exists - OK.
:msinspect_properties_file_end
cd %here%

rem
rem Create proteios log4j.properties file if not existing.
rem
cd %build_dir%
if exist log4j.properties goto log4j_properties_file_ok
echo Creating log config file log4j.properties...
copy log4j.properties.in log4j.properties
goto log4j_properties_file_end
:log4j_properties_file_ok
echo Log config file log4j.properties exists - OK.
:log4j_properties_file_end
cd %here%

rem
rem Build class path
rem
set cp=.\%build_dir%
rem
rem Note: Variables like %cp% are interpreted before a for-statement
rem is executed, so a for-loop like
rem
rem for %%i in (.\www\WEB-INF\lib\*.jar) do set cp=%cp%;%%i
rem
rem will only add the last of the *.jar files to the %cp% list
rem after the for-loop is finished. This can be solved by calling
rem a temporary batch file that updates the %cp% value for each loop.
rem The contents of the temporary batch file tmp1.bat is
rem
rem set cp=%cp%;%1
rem
rem where %1 is the argument that will be provided by the
rem for-loop variable %%i.
rem
echo set cp=%%cp%%;%%1> tmp1.bat
for %%i in (.\www\WEB-INF\lib\*.jar) do call tmp1.bat %%i
del tmp1.bat
rem
rem Run proteios java installation program InitDB
rem
rem java -server -cp %cp% org.proteios.install.InitDB %root_pwd%

rem
rem Initialize database.
rem
if not "%update_db%"=="Y" goto no_update
java -cp %cp% org.proteios.install.InitDB update %root_pwd%
goto db_init_end
:no_update
java -cp %cp% org.proteios.install.InitDB %root_pwd%
:db_init_end

rem
rem Create user files directory if not existing.
rem
if exist %user_files_dir% goto user_files_dir_ok
echo Creating user files directory...
mkdir %user_files_dir%
rem
rem Check if user files directory exists.
rem
if exist %user_files_dir% goto user_files_dir_ok2
echo Failed.
echo User files directory could not be created.
echo Create user files directory %user_files_dir% yourself.
goto user_files_dir_end
:user_files_dir_ok2
echo done
goto user_files_dir_end
:user_files_dir_ok
echo User files directory exists - OK.
:user_files_dir_end

rem
rem Create "conf" directory in user files directory if not existing.
rem
if exist "%user_files_dir%\conf" goto user_files_conf_dir_ok
echo Creating \"conf\" directory in user files directory...
mkdir "%user_files_dir%\conf"
rem
rem Check if "conf" directory in  user files directory exists.
rem
if exist "%user_files_dir%\conf" goto user_files_conf_dir_ok2
echo Failed.
echo Directory \"conf\" in user files directory could not be created.
echo Create \"conf\" directory in user files directory %user_files_dir% yourself.
goto user_files_conf_dir_end
:user_files_conf_dir_ok2
echo done
goto user_files_dir_end
:user_files_conf_dir_ok
echo Directory \"conf\" in user files directory exists - OK.
:user_files_conf_dir_end

rem
rem Create temporary files directory if not existing.
rem
if exist %temp_files_dir% goto temp_files_dir_ok
echo Creating temporary files directory...
mkdir %temp_files_dir%
rem
rem Check if temporary files directory exists.
rem
if exist %temp_files_dir% goto temp_files_dir_ok2
echo Failed.
echo Temporary files directory could not be created.
echo Create temporary files directory %temp_files_dir% yourself.
goto temp_files_dir_end
:temp_files_dir_ok2
echo done
goto temp_files_dir_end
:temp_files_dir_ok
echo Temporary files directory exists - OK.
:temp_files_dir_end

rem
rem Set variable catalina_home (tomcat installation directory)
rem
:step_10a
set body_text=10. Let's deploy the web application into tomcat.
set next_step=step_10b
goto print
:step_10b
if defined catalina_home goto catalina_ok
echo    Catalina home: > prompt.txt
call inp2var.bat catalina_home prompt.txt
rem echo catalina_home = %catalina_home%
:catalina_ok
echo.

rem
rem Create link in tomcat webapps directory to proteomics directory
rem

rem
rem Store current directory in variable %here%
rem
cd > prompt.txt
call inp2var.bat here prompt.txt no_input
echo Deploying %app_name% into %catalina_home%
echo ________________________________________________________________________
echo Copying new installation from %here%\www to %catalina_home%\webapps\www.
xcopy "%here%"\www "%catalina_home%"\webapps\www /E /I /V /Q
if ERRORLEVEL 1 goto failure
echo Removing old installation.
rmdir "%catalina_home%"\webapps\%app_name% /S /Q
if ERRORLEVEL 1 goto failure
echo Activating new installation in %catalina_home%\webapps\%app_name%.
move "%catalina_home%"\webapps\www "%catalina_home%"\webapps\%app_name%
if ERRORLEVEL 1 goto failure
echo ________________________________________________________________________
echo.

rem
rem Update proteios Proteios FTP Server start script (bat-file)
rem
echo Updating Proteios FTP Server start script (bat-file)
cd %here%
rem
rem Insert Tomcat installation directory
rem in file proteios_ftp_server.bat.in.
rem
java -jar "%here%"\Replace.jar proteios_ftp_server.bat.in proteios_ftp_server.bat __CATALINA_HOME__="%catalina_home%"
rem
rem Insert Tomcat installation directory
rem in files proteios_ftp_server_start.bat.in.
rem and proteios_ftp_server_stop.bat.in.
rem
java -jar "%here%"\Replace.jar proteios_ftp_server_start.bat.in proteios_ftp_server_start.bat __CATALINA_HOME__="%catalina_home%"
java -jar "%here%"\Replace.jar proteios_ftp_server_stop.bat.in proteios_ftp_server_stop.bat __CATALINA_HOME__="%catalina_home%"
cd %here%
echo.

rem
rem Print finishing remarks
rem
:step_11a
set body_text=%app_name% is now installed. Start tomcat before use.
set next_step=step_11b
goto print
:step_11b
echo.
echo.
rem
rem Extra dummy input to keep command prompt window open until input is given
rem
echo    Press Enter to finish: > prompt.txt
call inp2var.bat dummy_var prompt.txt

goto finish


:print
rem
rem Subroutine print
rem
rem
rem Prints header text for current step.
rem
  echo.
  echo.
  echo %body_text%
  echo.
goto %next_step%


:failure
echo Activation of installation failed
goto step_11b

:finish
rem
rem Clear used environment variables
rem
rem
rem Remove values of used batch file parameters,
rem so they cannot be accessed from the command line.
rem
  set db_socket=
  set sql_client=
  set app_name=
  set db_manager=
  set db_manager_pwd=
  set db_name=
  set db_host=
  set app_user=
  set app_user_pwd=
  set user_files_dir=
  set user_files_dir_slashes=
  set ftp_control_port=
  set ftp_passive_port_range=
  set mail_server=
  set mail_from_address=
  set sql_exec=
  set continue_install=
  set drop_db=
  set cp=
  set body_text=
  set next_step= 
  set here= 
  set dummy_var= 
:end