source: trunk/misc/install/update_proteios-win.bat @ 4085

@echo off
rem
rem update_proteios-win.bat
rem

rem Copyright (C) 2009 Olle Mansson
rem
rem Files are copyright by their respective authors. The contributions to
rem files where copyright is not explicitly stated can be traced with the
rem source code revision system.
rem
rem This file is part of Proteios.
rem Available at http://www.proteios.org/
rem
rem Proteios is free software; you can redistribute it and/or
rem modify it under the terms of the GNU General Public License
rem as published by the Free Software Foundation; either version 2
rem of the License, or (at your option) any later version.
rem
rem Proteios is distributed in the hope that it will be useful,
rem but WITHOUT ANY WARRANTY, without even the implied warranty of
rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
rem GNU General Public License for more details.
rem
rem You should have received a copy of the GNU General Public License
rem along with this program; if not, write to the Free Software
rem Foundation, Inc., 59 Temple Place - Suite 330,
rem Boston, MA 02111-1307, USA.

rem
rem Performs Proteios 2.x update on Microsoft Windows.
rem
rem Uses bat file inp2var.bat to store console input data
rem into a given variable.
rem
rem Usage: inp2var.bat var_name [promptfile [mask_input|no_input]]
rem
rem Used programs/files:
rem
rem inp2var.bat
rem   inp2var.jar
rem

rem
rem Configuration
rem
set app_name=proteios
set build_dir=www\WEB-INF\classes
rem
rem End Configuration
rem

rem
rem Welcome message and update references
rem
echo.
echo.
echo Welcome to the %app_name% update routine.
echo.
echo.
echo It is assumed that %app_name% is already installed.
echo.
echo For more information on the installation steps, see:
echo http://www.proteios.org/wiki/Update
echo.

rem
rem Try to copy configuration files from previous Tomcat installation.
rem
:step_1a
set body_text=1. Trying to copy configuration files from previous Tomcat installation.
set next_step=step_1b
goto print
:step_1b
echo.

rem
rem
rem Set variable catalina_home (tomcat installation directory)
rem
rem set catalina_home=
if not "%catalina_home%"=="" goto catalina_ok
echo    Catalina home: > prompt.txt
call inp2var.bat catalina_home prompt.txt
rem echo catalina_home = %catalina_home%
:catalina_ok
set catalina_inst_dir=%catalina_home%\webapps\%app_name%\WEB-INF\classes
echo.

rem
rem Store current directory in variable %here%
rem
cd > prompt.txt
call inp2var.bat here prompt.txt no_input

rem
rem Try to copy configuration files from previous Tomcat installation.
rem

set filename=proteios.config
set rel_path="."
set next_step=step_1c1
goto copy_file_from_tomcat_installation
:step_1c1

set filename=web.xml
set rel_path=".."
set next_step=step_1c2
goto copy_file_from_tomcat_installation
:step_1c2

set filename=ftp.properties
set rel_path="."
set next_step=step_1c3
goto copy_file_from_tomcat_installation
:step_1c3

set filename=xtandem.properties
set rel_path="."
set next_step=step_1c4
goto copy_file_from_tomcat_installation
:step_1c4

set filename=mascot.properties
set rel_path="."
set next_step=step_1c5
goto copy_file_from_tomcat_installation
:step_1c5

set filename=omssa.properties
set rel_path="."
set next_step=step_1c6
goto copy_file_from_tomcat_installation
:step_1c6

set filename=pike.properties
set rel_path="."
set next_step=step_1c7
goto copy_file_from_tomcat_installation
:step_1c7

set filename=msinspect.properties
set rel_path="."
set next_step=step_1c8
goto copy_file_from_tomcat_installation
:step_1c8

set filename=log4j.properties
set rel_path="."
set next_step=step_1c9
goto copy_file_from_tomcat_installation
:step_1c9

rem
rem Check if necessary configuration files exist.
rem
:step_2a
set body_text=2. Checking if necessary configuration files exist.
set next_step=step_2b
goto print
:step_2b
echo.

set filename=proteios.config
set rel_path="."
set next_step=step_2c1
goto check_if_necessary_configuration_file_exists
:step_2c1

set filename=web.xml
set rel_path=".."
set next_step=step_2c2
goto check_if_necessary_configuration_file_exists
:step_2c2

set filename=ftp.properties
set rel_path="."
set next_step=step_2c3
goto check_if_necessary_configuration_file_exists
:step_2c3

rem
rem Create other configuration files if not existing.
rem
:step_3a
set body_text=3. Create other configuration files if not existing.
set next_step=step_3b
goto print
:step_3b
echo.

set filename=xtandem.properties
set rel_path="."
set file_title="X!Tandem search"
set next_step=step_3c1
goto create_config_file_if_not_existing
:step_3c1

set filename=mascot.properties
set rel_path="."
set file_title="Mascot search"
set next_step=step_3c2
goto create_config_file_if_not_existing
:step_3c2

set filename=omssa.properties
set rel_path="."
set file_title="OMSSA search"
set next_step=step_3c3
goto create_config_file_if_not_existing
:step_3c3

set filename=pike.properties
set rel_path="."
set file_title="PIKE search"
set next_step=step_3c4
goto create_config_file_if_not_existing
:step_3c4

set filename=log4j.properties
set rel_path="."
set file_title="Log"
set next_step=step_3c5
goto create_config_file_if_not_existing
:step_3c5

rem
rem Get Proteios root password
rem
:step_4a
set body_text=4. Enter a password for the root account in %app_name%.
set next_step=step_4b
goto print
:step_4b
echo    Password: > prompt.txt
call inp2var.bat root_pwd prompt.txt mask_input
echo.

rem
rem Execute update
rem

rem
rem Build class path
rem
set cp=.\%build_dir%
rem
rem Note: Variables like %cp% are interpreted before a for-statement
rem is executed, so a for-loop like
rem
rem for %%i in (.\www\WEB-INF\lib\*.jar) do set cp=%cp%;%%i
rem
rem will only add the last of the *.jar files to the %cp% list
rem after the for-loop is finished. This can be solved by calling
rem a temporary batch file that updates the %cp% value for each loop.
rem The contents of the temporary batch file tmp1.bat is
rem
rem set cp=%cp%;%1
rem
rem where %1 is the argument that will be provided by the
rem for-loop variable %%i.
rem
echo set cp=%%cp%%;%%1> tmp1.bat
for %%i in (.\www\WEB-INF\lib\*.jar) do call tmp1.bat %%i
del tmp1.bat

rem
rem Update database.
rem
java -cp %cp% org.proteios.install.InitDB update %root_pwd%

rem
rem Create link in tomcat webapps directory to proteomics directory
rem

rem
rem Store current directory in variable %here%
rem
cd > prompt.txt
call inp2var.bat here prompt.txt no_input
echo Deploying %app_name% into %catalina_home%
echo ________________________________________________________________________
echo.
echo Copying new installation from %here%\www to %catalina_home%\webapps\www.
xcopy "%here%"\www "%catalina_home%"\webapps\www /E /I /V /Q
if ERRORLEVEL 1 goto failure
echo Removing old installation.
rmdir "%catalina_home%"\webapps\%app_name% /S /Q
if ERRORLEVEL 1 goto failure
echo Activating new installation in %catalina_home%\webapps\%app_name%.
move "%catalina_home%"\webapps\www "%catalina_home%"\webapps\%app_name%
if ERRORLEVEL 1 goto failure

rem
rem Print finishing remarks
rem
:step_5a
set body_text=%app_name% is now updated. Restart tomcat before use.
set next_step=step_5b
goto print
:step_5b
echo.
echo.

goto finish


:print
rem
rem Subroutine print
rem
rem Prints header text for current step.
rem
rem Argument %body_text%: String to print
rem Argument %next_step%: Return label when finished
rem
  echo.
  echo.
  echo %body_text%
  echo.
goto %next_step%


:copy_file_from_tomcat_installation
rem
rem Subroutine copy_file_from_tomcat_installation
rem
rem Argument %filename%: Name of file to copy
rem Argument %rel_path%: Directory path relative to WEB-INF\classes\ directory
rem Argument %next_step%: Return label when finished
rem
cd %build_dir%\%rel_path%
if exist "%catalina_inst_dir%\%rel_path%\%filename%" goto tomcat_config_file_ok
echo No configuration file %filename% to copy from previous Tomcat installation.
goto tomcat_config_file_end
:tomcat_config_file_ok
echo Copying file %filename% from previous Tomcat installation.
copy "%catalina_inst_dir%\%rel_path%\%filename%" %filename%
:tomcat_config_file_end
cd %here%
goto %next_step%


:check_if_necessary_configuration_file_exists
rem
rem Subroutine check_if_necessary_configuration_file_exists
rem
rem Argument %filename%: Name of file to check
rem Argument %rel_path%: Directory path relative to WEB-INF\classes\ directory
rem Argument %next_step%: Return label when finished
rem
cd %build_dir%\%rel_path%
if exist %filename% goto necessary_config_file_ok
echo Configuration file %filename% missing - Use installation script instead.
goto finish
:necessary_config_file_ok
echo Configuration file %filename% exists - OK.
cd %here%
goto %next_step%


:create_config_file_if_not_existing
rem
rem Subroutine create_config_file_if_not_existing
rem
rem Argument %filename%: Name of file to create
rem Argument %rel_path%: Directory path relative to WEB-INF\classes\ directory
rem Argument %file_title%: file title
rem Argument %next_step%: Return label when finished
rem
cd %build_dir%\%rel_path%
if exist %filename% goto config_file_ok
echo Creating %file_title% config file %fileanme% ...
copy %filename%.in %filename%
goto config_file_end
:config_file_ok
echo %file_title% config file %filename% exists - OK.
:config_file_end
cd %here%
goto %next_step%

:failure
echo Installation failed
goto finish


:finish
rem
rem Clear used environment variables
rem
rem
rem Remove values of used batch file parameters,
rem so they cannot be accessed from the command line.
rem
  set app_name=
  set build_dir=
  set root_pwd=
  set cp=
  set body_text=
  set next_step= 
  set here= 
  
echo    Press Enter to finish: > prompt.txt
call inp2var.bat dummy_var prompt.txt
:end