source: branches/replacing_gnuplot/configure.ac @ 646

Last change on this file since 646 was 646, checked in by Jari Häkkinen, 13 years ago

Merged trunk changes r608:645 to replacing_gnuplot branch.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 10.9 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 646 2008-06-03 22:05:22Z jari $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson
15#
16# This file is part of svndigest, http://trac.thep.lu.se/svndigest
17#
18# svndigest is free software; you can redistribute it and/or modify it
19# under the terms of the GNU General Public License as published by
20# the Free Software Foundation; either version 2 of the License, or
21# (at your option) any later version.
22#
23# svndigest is distributed in the hope that it will be useful, but
24# WITHOUT ANY WARRANTY; without even the implied warranty of
25# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
26# General Public License for more details.
27#
28# You should have received a copy of the GNU General Public License
29# along with this program; if not, write to the Free Software
30# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
31# 02111-1307, USA.
32
33AC_PREREQ(2.60)
34
35
36m4_include([./build_support/version.m4])
37AC_INIT([svndigest],[SVNDIGEST_VERSION],[jari@thep.lu.se])
38AC_CONFIG_SRCDIR([lib/File.h])
39AC_CONFIG_AUX_DIR([autotools])
40AC_PREFIX_DEFAULT([/usr/local])
41test $prefix = NONE && prefix=/usr/local
42
43AC_SUBST([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION])
44AC_SUBST([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION])
45AC_SUBST([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION])
46
47AC_DEFINE([DEV_BUILD],[SVNDIGEST_DEV_BUILD],
48          [true if dev build (version starts with pre)])
49AC_DEFINE([VERSION_MAJOR], [SVNDIGEST_MAJOR_VERSION],
50                    [Define to the svndigest major version])
51AC_DEFINE([VERSION_MINOR], [SVNDIGEST_MINOR_VERSION],
52                    [Define to the svndigest minor version])
53AC_DEFINE([VERSION_PATCH], [SVNDIGEST_PATCH_VERSION],
54                    [Define to the svndigest patch version])
55
56AC_CONFIG_HEADER([config.h])
57AM_INIT_AUTOMAKE([std-options check-news])
58
59# seems like these variables are not set with older autoconf(?)
60AC_SUBST([abs_srcdir], ["`cd $srcdir && pwd`"])
61AC_SUBST([abs_builddir], ["`pwd`"])
62
63# Set default programming language
64AC_LANG(C++)
65
66# Let user overide default CXXFLAGS
67if test "${CXXFLAGS+set}" != set; then
68  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
69fi
70# Checks for programs.
71AC_PROG_CXXCPP
72AC_PROG_CXX
73AC_PROG_INSTALL
74AC_PROG_LIBTOOL
75AC_PROG_SED
76AC_CHECK_PROG([GNUPLOT],[gnuplot],[ok])
77
78# Save FLAGS
79SAVE_CPPFLAGS="$CPPFLAGS"
80SAVE_CXXFLAGS="$CXXFLAGS"
81SAVE_LDFLAGS="$LDFLAGS"
82SAVE_LIBS="$LIBS"
83
84# -Wno-long-long is needed to suppress compiler diagnostics regarding
85# using extension beyond the C++ standard (usage of non C++ standard
86# 'long long' types).
87SD_CXXFLAGS="$SD_CXXFLAGS-Wall -pedantic -Wno-long-long"
88AC_TYPE_LONG_LONG_INT()
89
90AC_ARG_ENABLE(debug,
91  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])],
92  [SD_CXXFLAGS="$SD_CXXFLAGS -g -O"],
93  [SD_CPPFLAGS="-DNDEBUG" SD_CXXFLAGS="$SD_CXXFLAGS -O3"])
94
95# optionally prepare for building static libraries.
96AC_ARG_ENABLE(staticbin,
97  [AS_HELP_STRING([--enable-staticbin], [create a static binary,
98  at least as static as the available underlying libraries
99  allows])])
100if test "$enable_staticbin" = "yes"; then
101  case $host in
102  *-apple-darwin*)
103    # At the time of creating this libsvn_subr uses
104    # Keychain on Mac OSX. In consequence the below
105    # frameworks are needed for succesful static builds.
106    SD_LIBS="$SD_LIBS -framework Security"
107    SD_LIBS="$SD_LIBS -framework CoreFoundation"
108    SD_LIBS="$SD_LIBS -framework CoreServices"
109    ;;
110  esac
111  STATICFLAG=-static
112  AC_SUBST(STATICFLAG)
113fi
114
115# Apache Portable Runtime (APR) API checks
116# The next three lines are not needed as long as APR_FIND_APR is used.
117# AC_ARG_WITH(apr,
118#  [  --with-apr=DIR          prefix for installed APR or path to APR build
119#                          tree [[PREFIX]]])
120# Include APR_FIND_APR macro distributed within the APR project. If
121# the usage of the APR macro is to be omitted then the construct for
122# setting the CXXFLAGS (header file location) and LDFLAGS (linking
123# informaion) for APR must be changed. The latter can be achieved with
124# AC_SEARCH_LIBS([apr_allocator_create],[apr-0],,apr_found="no") but
125# apr-0 must be prior knowledge.
126m4_sinclude(./build_support/find_apr.m4)
127APR_FIND_APR(,,1,[1 0])
128if test "$apr_found" = "yes" ; then
129    SD_LDFLAGS="`$apr_config --link-ld` $SD_LDFLAGS"
130    SD_CPPFLAGS="`$apr_config --includes --cppflags` $SD_CPPFLAGS"
131fi
132
133# Subversion API checks
134svn_found="yes"
135AC_ARG_WITH(svn,
136  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
137  [ SD_LDFLAGS="-L$withval/lib $SD_LDFLAGS"
138    SD_CPPFLAGS="-I$withval/include $SD_CPPFLAGS"])
139
140
141# Use SD_*FLAGS in tests
142CPPFLAGS="$SD_CPPFLAGS $CPPFLAGS"
143CXXFLAGS="$SD_CXXFLAGS $CXXFLAGS"
144LDFLAGS="$SD_LDFLAGS $LDFLAGS"
145LIBS="$SD_LIBS $LIBS"
146
147AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
148AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
149# The library checks below may match shared libs even when
150# --enable-staticbin is given to configure. This should probably not
151# pose any problems since in a properly installed system the shared
152# and static libraries should be the same.
153AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],
154               [SD_LIBS="-lsvn_subr-1 $SD_LIBS"],svn_found="no")
155AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],
156               [SD_LIBS="-lsvn_ra-1 $SD_LIBS"],svn_found="no")
157AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],
158               [SD_LIBS="-lsvn_wc-1 $SD_LIBS"],svn_found="no")
159AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],
160               [SD_LIBS="-lsvn_diff-1 $SD_LIBS"],svn_found="no")
161AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],
162               [SD_LIBS="-lsvn_client-1 $SD_LIBS"],svn_found="no")
163
164# Export flags
165AC_SUBST([SVNDIGEST_CPPFLAGS], $SD_CPPFLAGS)
166AC_SUBST([SVNDIGEST_CXXFLAGS], $SD_CXXFLAGS)
167AC_SUBST([SVNDIGEST_LDFLAGS], $SD_LDFLAGS)
168AC_SUBST([SVNDIGEST_LIBS], $SD_LIBS)
169
170# Reset FLAGS
171CPPFLAGS="$SAVE_CPPFLAGS"
172CXXFLAGS="$SAVE_CXXFLAGS"
173LDFLAGS="$SAVE_LDFLAGS"
174LIBS="$SAVE_LIBS"
175
176# check if svnversion is installed
177have_svnversion="yes"
178AC_PATH_PROG(SVNVERSION, svnversion, have_svnversion="no")
179
180# checking if we build in a subversion WC
181wc_found="no";
182if (test $have_svnversion != "no" &&
183    test `$SVNVERSION -n $srcdir` != "exported");
184then
185   wc_found="yes";
186fi
187AC_CHECK_FILE("$srcdir/lib/subversion_info.cc",info_found="yes",info_found="no")
188
189# checking that DEV_BUILD is set to false at time of release
190# Failure should be captured by distcheck
191if (test "$wc_found" = "no" && test "$SVNDIGEST_DEV_BUILD" = "true") ; then
192  AC_MSG_ERROR([Incorrect version:
193               [SVNDIGEST_DEV_BUILD] is set to SVNDIGEST_DEV_BUILD.
194         [SVNDIGEST_DEV_BUILD] should be set to false at time of release.
195               Please, update version.m4.])
196fi
197
198
199# devel version should have svn WC and SVNVERSION installed
200AM_CONDITIONAL(HAVE_SVN_WC, test "$wc_found" = "yes" )
201
202
203AC_CONFIG_FILES([Makefile
204                bin/Makefile
205                lib/Makefile
206                test/environment.h
207                test/Makefile])
208
209# Print failure status information about selected items, and exit if
210# fatal errors were encountered. No output will be created if
211# configure is halted prematurely.
212
213# used to trigger exit before creation of output
214all_reqs_ok="true"
215
216if (test "$wc_found" != "yes") ; then
217if (test "$info_found" = "no") ; then
218   AC_MSG_WARN([Cannot find sources (lib/subversion_info.cc).])
219   if (test "$svnversion" = "no") ; then
220     AC_MSG_WARN([If you grabbed the source from the subversion repository,
221     the file will be generated automatically. However, svnversion cannot
222     be found and therefore the file cannot be generated. Please install
223     svnversion and make sure it is in your search path.])
224   else
225     AC_MSG_WARN([If you grabbed the source from the subversion repository,
226     the file will be generated automatically. However, the output from
227     svnversion was incorrect. Either your installation of svnversion is
228     is not healthy or there is something wrong with the repository.])
229   fi
230   all_reqs_ok="false"
231else
232   dnl test repo is not distributed
233   AC_CONFIG_FILES([test/test_repo.sh
234                    test/check_repo_status.sh],
235                   [chmod +x test/test_repo.sh;
236                    chmod +x test/check_repo_status.sh])
237   
238fi
239fi
240
241# Non-existing APR is fatal -- sub-sequent compilation will fail.
242if (test "$apr_found" = "no") ; then
243    AC_MSG_WARN([APR not found. The Apache Portable Runtime
244    (APR) library cannot be found. Please make sure APR is installed
245    and supply the appropriate --with-apr option to 'configure'.])
246    all_reqs_ok="false"
247fi
248
249# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
250if (test "$svn_found" = "no") ; then
251    svn_msg="Subversion API not found. Subversion API libraries cannot
252    be found. Make sure the APIs are installed and supply the
253    appropriate --with-svn option to 'configure'."
254if (test "$apr_found" = "no") ; then
255    svn_msg="$svn_msg
256    Note, APR was not found. Failure to locate APR affects the search
257    of the subversion API. Please fix the APR problem before trying
258    to resolve the subversion related issues."
259fi
260    AC_MSG_WARN([$svn_msg])
261    all_reqs_ok="false"
262fi
263
264if test $ac_cv_type_long_long_int != yes ; then
265   AC_MSG_WARN([Compiler $CXX does not support `long long'.
266          svndigest must be compiled with a compiler that supports `long long'.])
267   all_reqs_ok="false"
268fi
269
270if (test "$all_reqs_ok" = "false") ; then
271    AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
272    configure. Please consult the 'README' file for more information
273    about what is needed to compile svndigest and refer to above
274    warning messages. Needed files were NOT created.])
275fi
276
277# Create output.
278AC_OUTPUT
279
280# Some more messages.
281AC_MSG_NOTICE([])
282AC_MSG_NOTICE([   Ready to compile the executables of svndigest $VERSION])
283AC_MSG_NOTICE([   The following flags and libs will be used:])
284AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
285AC_MSG_NOTICE([    Compiler:           $CXX])
286AC_MSG_NOTICE([    Preprocessor flags: $SD_CPPFLAGS $CPPFLAGS])
287AC_MSG_NOTICE([    C++ flags:          $SD_CXXFLAGS $CXXFLAGS])
288AC_MSG_NOTICE([    Linker flags:       $SD_LDFLAGS $LDFLAGS])
289AC_MSG_NOTICE([    LIBS:               $SD_LIBS $LIBS])
290AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
291AC_MSG_NOTICE([])
292
293# Failure to locate gnuplot is not considered fatal
294if (test "$GNUPLOT" != "ok") ; then
295    AC_MSG_WARN([Gnuplot was not found. svndigest will compile
296    without gnuplot but will throw an exception at run-time. Please
297    install gnuplot (available for a wide range of operating systems
298    at http://www.gnuplot.info).])
299    AC_MSG_NOTICE([])
300fi
301
302if test "$enable_staticbin" = "yes"; then
303    AC_MSG_NOTICE([A statically linked 'svndigest' binary will be created.])
304else
305    AC_MSG_NOTICE([A dynamically linked 'svndigest' binary will be created.])
306fi
307    AC_MSG_NOTICE([])
308
309AC_MSG_NOTICE([Now type 'make ; make check'.])
310
Note: See TracBrowser for help on using the repository browser.