source: trunk/configure.ac @ 551

Last change on this file since 551 was 551, checked in by Peter Johansson, 14 years ago

trying to make configure.ac work under autoconf 2.59

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 9.6 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 551 2008-01-08 01:01:27Z peter $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007 Jari Häkkinen, Peter Johansson
15# Copyright (C) 2008 Peter Johansson
16#
17# This file is part of svndigest, http://trac.thep.lu.se/svndigest
18#
19# svndigest is free software; you can redistribute it and/or modify it
20# under the terms of the GNU General Public License as published by
21# the Free Software Foundation; either version 2 of the License, or
22# (at your option) any later version.
23#
24# svndigest is distributed in the hope that it will be useful, but
25# WITHOUT ANY WARRANTY; without even the implied warranty of
26# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
27# General Public License for more details.
28#
29# You should have received a copy of the GNU General Public License
30# along with this program; if not, write to the Free Software
31# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
32# 02111-1307, USA.
33
34AC_PREREQ(2.57)
35
36
37AC_INIT([svndigest],[pre0.7],[jari@thep.lu.se])
38AC_CONFIG_SRCDIR([lib/File.h])
39AC_CONFIG_AUX_DIR([autotools])
40AC_PREFIX_DEFAULT([/usr/local])
41test $prefix = NONE && prefix=/usr/local
42
43AM_CONFIG_HEADER([config.h])
44AM_INIT_AUTOMAKE([std-options check-news])
45
46DEV=`echo $VERSION|sed 's/\([[a-z]]*\).*/\1/'`
47if test "$DEV" = "pre"; then
48  DEV="1"
49else
50  DEV="0"
51fi
52MY_MAJOR=`echo $VERSION|sed 's/[[a-z]]*\([[0-9]]*\).*/\1/'`
53MY_MINOR=`echo $VERSION|sed 's/[[a-z]]*[[0-9]]*\.\([[0-9]]*\).*/\1/'`
54if test "$MY_MINOR" = "$VERSION" || test "$MY_MAJOR" = "$VERSION" ; then
55   AC_MSG_ERROR([version number is incorrect])
56fi
57
58MY_PATCH=`echo $VERSION|sed 's/[[a-z]]*[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*/\1/'`
59
60if test "$MY_PATCH" = "$VERSION"; then
61   MY_PATCH="0"
62fi
63
64# AM_CONDITIONAL(DEV_BUILD, $DEV )
65AC_SUBST([VERSION_MAJOR], [$MY_MAJOR])
66AC_SUBST([VERSION_MINOR], [$MY_MINOR])
67AC_SUBST([VERSION_PATCH], [$MY_PATCH])
68AC_DEFINE_UNQUOTED([DEV_BUILD],[$DEV],
69                   [true if dev build (version starts with pre)])
70AC_DEFINE_UNQUOTED([VERSION_MAJOR], [$MY_MAJOR],
71                   [Define to the svndigest major version])
72AC_DEFINE_UNQUOTED([VERSION_MINOR], [$MY_MINOR],
73                   [Define to the svndigest minor version])
74AC_DEFINE_UNQUOTED([VERSION_PATCH], [$MY_PATCH],
75                   [Define to the svndigest patch version])
76
77
78# seems like these variables are not set with older autoconf(?)
79AC_SUBST([abs_srcdir], ["`cd $srcdir && pwd`"])
80AC_SUBST([abs_builddir], ["`pwd`"])
81
82# Set default programming language
83AC_LANG(C++)
84
85# Checks for programs.
86AC_PROG_CPP
87AC_PROG_CXX
88AC_PROG_INSTALL
89AC_PROG_LIBTOOL
90AC_PROG_RANLIB
91AC_CHECK_PROG([GNUPLOT],[gnuplot],[ok])
92
93# -Wno-long-long is needed to suppress compiler diagnostics regarding
94# using extension beyond the C++ standard (usage of non C++ standard
95# 'long long' types).
96CXXFLAGS="-Wall -pedantic -Wno-long-long"
97
98AC_ARG_ENABLE(debug,
99  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])],
100  [CXXFLAGS="$CXXFLAGS -g -O"],
101  [CPPFLAGS="$CPPFLAGS -DNDEBUG" CXXFLAGS="$CXXFLAGS -O3"])
102
103# optionally prepare for building static libraries.
104AC_ARG_ENABLE(staticbin,
105  [AS_HELP_STRING([--enable-staticbin], [create a static binary,
106  at least as static as the available underlying libraries
107  allows])])
108if test "$enable_staticbin" = "yes"; then
109  case $host in
110  *-apple-darwin*)
111    # At the time of creating this libsvn_subr uses
112    # Keychain on Mac OSX. In consequence the below
113    # frameworks are needed for succesful static builds.
114    LIBS="$LIBS -framework Security"
115    LIBS="$LIBS -framework CoreFoundation"
116    LIBS="$LIBS -framework CoreServices"
117    ;;
118  esac
119  STATICFLAG=-static
120  AC_SUBST(STATICFLAG)
121fi
122
123# Apache Portable Runtime (APR) API checks
124# The next three lines are not needed as long as APR_FIND_APR is used.
125# AC_ARG_WITH(apr,
126#  [  --with-apr=DIR          prefix for installed APR or path to APR build
127#                          tree [[PREFIX]]])
128# Include APR_FIND_APR macro distributed within the APR project. If
129# the usage of the APR macro is to be omitted then the construct for
130# setting the CXXFLAGS (header file location) and LDFLAGS (linking
131# informaion) for APR must be changed. The latter can be achieved with
132# AC_SEARCH_LIBS([apr_allocator_create],[apr-0],,apr_found="no") but
133# apr-0 must be prior knowledge.
134sinclude(./build_support/find_apr.m4)
135APR_FIND_APR(,,1)
136if test "$apr_found" = "yes" ; then
137    LDFLAGS="`$apr_config --link-ld` $LDFLAGS"
138    CPPFLAGS="`$apr_config --includes` $CPPFLAGS"
139    AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
140fi
141
142# Subversion API checks
143svn_found="yes"
144AC_ARG_WITH(svn,
145  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
146  [ LDFLAGS="-L$withval/lib $LDFLAGS" CPPFLAGS="-I$withval/include $CPPFLAGS"])
147AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
148# The library checks below may match shared libs even when
149# --enable-staticbin is given to configure. This should probably not
150# pose any problems since in a properly installed system the shared
151# and static libraries should be the same.
152AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],,svn_found="no")
153AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],,svn_found="no")
154AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],,svn_found="no")
155AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],,svn_found="no")
156AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],,svn_found="no")
157
158
159# check if svnversion is installed
160have_svnversion="yes"
161AC_PATH_PROG(SVNVERSION, svnversion, have_svnversion="no")
162
163wc_found="no";
164if (test `$SVNVERSION -n '.'` != "exported"); then
165   wc_found="yes";
166fi
167AC_CHECK_FILE("lib/subversion_info.h", info_found="yes", info_found="no")
168
169# devel version should have svn WC and SVNVERSION installed
170AM_CONDITIONAL(HAVE_SVN_WC, test "$wc_found" = "yes" )
171
172
173AC_CONFIG_FILES([Makefile
174                bin/Makefile
175                lib/Makefile
176                test/Makefile])
177
178# Print failure status information about selected items, and exit if
179# fatal errors were encountered. No output will be created if
180# configure is halted prematurely.
181
182# used to trigger exit before creation of output
183all_reqs_ok="true"
184
185#
186if (test "$info_found" = "no" && test "$wc_found" = "no") ; then
187   AC_MSG_WARN([Cannot find sources (lib/subverion_info.h).])
188   if (test "$svnversion" = "no") ; then
189     AC_MSG_WARN([If you grabbed the source from the subversion repository,
190     the file will be generated automatically. However, svnversion cannot
191     be found and therefore the file cannot be generated. Please install
192     svnversion and make sure it is in your search path.])
193   else
194     AC_MSG_WARN([If you grabbed the source from the subversion repository,
195     the file will be generated automatically. However, the output from
196     svnversion was incorrect. Either your installation of svnversion is
197     is not healthy or there is something wrong with the repository.])
198   fi
199   all_reqs_ok="false"
200fi
201
202# Non-existing APR is fatal -- sub-sequent compilation will fail.
203if (test "$apr_found" = "no") ; then
204    AC_MSG_WARN([APR not found. The Apache Portable Runtime
205    (APR) library cannot be found. Please make sure APR is installed
206    and supply the appropriate --with-apr option to 'configure'.])
207    all_reqs_ok="false"
208fi
209
210# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
211if (test "$svn_found" = "no") ; then
212    svn_msg="Subversion API not found. Subversion API libraries cannot
213    be found. Make sure the APIs are installed and supply the
214    appropriate --with-svn option to 'configure'."
215if (test "$apr_found" = "no") ; then
216    svn_msg="$svn_msg
217    Note, APR was not found. Failure to locate APR affects the
218    location of the subversion API. Please fix the APR problem before
219    trying to resolve the subversion related issues."
220fi
221    AC_MSG_WARN([$svn_msg])
222    all_reqs_ok="false"
223fi
224
225if (test "$all_reqs_ok" = "false") ; then
226    AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
227    configure. Please consult the 'README' file for more information
228    about what is needed to compile svndigest and refer to above
229    warning messages. Needed files were NOT created.])
230fi
231
232# Create output.
233AC_OUTPUT
234
235# Some more messages.
236AC_MSG_NOTICE([])
237AC_MSG_NOTICE([   Ready to compile the executables of svndiget])
238AC_MSG_NOTICE([   The following flags and libs will be used:])
239AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
240AC_MSG_NOTICE([    Preprocessor flags: CPPFLAGS=\"$CPPFLAGS\"])
241AC_MSG_NOTICE([    C++ flags:          CXXFLAGS=\"$CXXFLAGS\"])
242AC_MSG_NOTICE([    Linker flags:       LDFLAGS=\"$LDFLAGS\"])
243AC_MSG_NOTICE([    LIBS:               LIBS=\"$LIBS\"])
244AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
245AC_MSG_NOTICE([])
246
247if (test "$wctests") ; then
248    AC_MSG_NOTICE([WC dependent tests are enabled])
249else
250    AC_MSG_NOTICE([WC dependent tests are disabled ... okay for most users])
251    AC_MSG_NOTICE([Developers, use --enable-wctests to enable WC tests])
252fi
253AC_MSG_NOTICE([])
254
255# Failure to locate gnuplot is not considered fatal
256if (test "$GNUPLOT" != "ok") ; then
257    AC_MSG_WARN([Gnuplot was not found. svndigest will compile
258    without gnuplot but will throw an exception at run-time. Please
259    install gnuplot (available for a wide range of operating systems
260    at http://www.gnuplot.info).])
261    AC_MSG_NOTICE([])
262fi
263
264if test "$enable_staticbin" = "yes"; then
265    AC_MSG_NOTICE([A statically linked 'svndigest' binary will be created.])
266else
267    AC_MSG_NOTICE([A dynamically linked 'svndigest' binary will be created.])
268fi
269    AC_MSG_NOTICE([])
270
271AC_MSG_NOTICE([Now type 'make ; make check'.])
272
Note: See TracBrowser for help on using the repository browser.