source: trunk/configure.ac @ 567

Last change on this file since 567 was 567, checked in by Peter Johansson, 13 years ago

use std macro

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 9.1 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 567 2008-03-07 20:31:46Z peter $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson
15#
16# This file is part of svndigest, http://trac.thep.lu.se/svndigest
17#
18# svndigest is free software; you can redistribute it and/or modify it
19# under the terms of the GNU General Public License as published by
20# the Free Software Foundation; either version 2 of the License, or
21# (at your option) any later version.
22#
23# svndigest is distributed in the hope that it will be useful, but
24# WITHOUT ANY WARRANTY; without even the implied warranty of
25# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
26# General Public License for more details.
27#
28# You should have received a copy of the GNU General Public License
29# along with this program; if not, write to the Free Software
30# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
31# 02111-1307, USA.
32
33AC_PREREQ(2.57)
34
35
36AC_INIT([svndigest],[pre0.7],[jari@thep.lu.se])
37AC_CONFIG_SRCDIR([lib/File.h])
38AC_CONFIG_AUX_DIR([autotools])
39AC_PREFIX_DEFAULT([/usr/local])
40test $prefix = NONE && prefix=/usr/local
41
42AM_CONFIG_HEADER([config.h])
43AM_INIT_AUTOMAKE([std-options check-news])
44
45sinclude(./build_support/svndigest.m4)
46SPLIT_VERSION([VERSION], [$VERSION])
47
48# seems like these variables are not set with older autoconf(?)
49AC_SUBST([abs_srcdir], ["`cd $srcdir && pwd`"])
50AC_SUBST([abs_builddir], ["`pwd`"])
51
52# Set default programming language
53AC_LANG(C++)
54
55# Let user overide default CXXFLAGS
56if test "${CXXFLAGS+set}" != set; then
57  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
58fi
59# Checks for programs.
60AC_PROG_CXXCPP
61AC_PROG_CXX
62AC_PROG_INSTALL
63AC_PROG_LIBTOOL
64AC_PROG_RANLIB
65AC_CHECK_PROG([GNUPLOT],[gnuplot],[ok])
66
67# -Wno-long-long is needed to suppress compiler diagnostics regarding
68# using extension beyond the C++ standard (usage of non C++ standard
69# 'long long' types).
70CXXFLAGS="$CXXFLAGS -Wall -pedantic -Wno-long-long"
71AC_TYPE_LONG_LONG_INT()
72
73AC_ARG_ENABLE(debug,
74  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])],
75  [CXXFLAGS="$CXXFLAGS -g -O"],
76  [CPPFLAGS="$CPPFLAGS -DNDEBUG" CXXFLAGS="$CXXFLAGS -O3"])
77
78# optionally prepare for building static libraries.
79AC_ARG_ENABLE(staticbin,
80  [AS_HELP_STRING([--enable-staticbin], [create a static binary,
81  at least as static as the available underlying libraries
82  allows])])
83if test "$enable_staticbin" = "yes"; then
84  case $host in
85  *-apple-darwin*)
86    # At the time of creating this libsvn_subr uses
87    # Keychain on Mac OSX. In consequence the below
88    # frameworks are needed for succesful static builds.
89    LIBS="$LIBS -framework Security"
90    LIBS="$LIBS -framework CoreFoundation"
91    LIBS="$LIBS -framework CoreServices"
92    ;;
93  esac
94  STATICFLAG=-static
95  AC_SUBST(STATICFLAG)
96fi
97
98# Apache Portable Runtime (APR) API checks
99# The next three lines are not needed as long as APR_FIND_APR is used.
100# AC_ARG_WITH(apr,
101#  [  --with-apr=DIR          prefix for installed APR or path to APR build
102#                          tree [[PREFIX]]])
103# Include APR_FIND_APR macro distributed within the APR project. If
104# the usage of the APR macro is to be omitted then the construct for
105# setting the CXXFLAGS (header file location) and LDFLAGS (linking
106# informaion) for APR must be changed. The latter can be achieved with
107# AC_SEARCH_LIBS([apr_allocator_create],[apr-0],,apr_found="no") but
108# apr-0 must be prior knowledge.
109sinclude(./build_support/find_apr.m4)
110APR_FIND_APR(,,1)
111if test "$apr_found" = "yes" ; then
112    LDFLAGS="`$apr_config --link-ld` $LDFLAGS"
113    CPPFLAGS="`$apr_config --includes` $CPPFLAGS"
114    AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
115fi
116
117# Subversion API checks
118svn_found="yes"
119AC_ARG_WITH(svn,
120  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
121  [ LDFLAGS="-L$withval/lib $LDFLAGS" CPPFLAGS="-I$withval/include $CPPFLAGS"])
122AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
123# The library checks below may match shared libs even when
124# --enable-staticbin is given to configure. This should probably not
125# pose any problems since in a properly installed system the shared
126# and static libraries should be the same.
127AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],,svn_found="no")
128AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],,svn_found="no")
129AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],,svn_found="no")
130AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],,svn_found="no")
131AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],,svn_found="no")
132
133
134# check if svnversion is installed
135have_svnversion="yes"
136AC_PATH_PROG(SVNVERSION, svnversion, have_svnversion="no")
137
138wc_found="no";
139if (test `$SVNVERSION -n '.'` != "exported"); then
140   wc_found="yes";
141fi
142AC_CHECK_FILE("lib/subversion_info.h", info_found="yes", info_found="no")
143
144# Checking that a release (non-dev) has no pre in VERSION
145# Failure should be captured by distcheck
146if (test "$wc_found" = "no" && test "$DEV_BUILD" = "yes") ; then
147   AC_MSG_ERROR([Incorrect version number: $VERSION
148                 Version number of an official release should have format
149                 MAJOR.MINOR or MAJOR.MINOR.PATCH])
150fi
151
152# devel version should have svn WC and SVNVERSION installed
153AM_CONDITIONAL(HAVE_SVN_WC, test "$wc_found" = "yes" )
154
155
156AC_CONFIG_FILES([Makefile
157                bin/Makefile
158                lib/Makefile
159                test/Makefile])
160
161# Print failure status information about selected items, and exit if
162# fatal errors were encountered. No output will be created if
163# configure is halted prematurely.
164
165# used to trigger exit before creation of output
166all_reqs_ok="true"
167
168#
169if (test "$info_found" = "no" && test "$wc_found" = "no") ; then
170   AC_MSG_WARN([Cannot find sources (lib/subverion_info.h).])
171   if (test "$svnversion" = "no") ; then
172     AC_MSG_WARN([If you grabbed the source from the subversion repository,
173     the file will be generated automatically. However, svnversion cannot
174     be found and therefore the file cannot be generated. Please install
175     svnversion and make sure it is in your search path.])
176   else
177     AC_MSG_WARN([If you grabbed the source from the subversion repository,
178     the file will be generated automatically. However, the output from
179     svnversion was incorrect. Either your installation of svnversion is
180     is not healthy or there is something wrong with the repository.])
181   fi
182   all_reqs_ok="false"
183fi
184
185# Non-existing APR is fatal -- sub-sequent compilation will fail.
186if (test "$apr_found" = "no") ; then
187    AC_MSG_WARN([APR not found. The Apache Portable Runtime
188    (APR) library cannot be found. Please make sure APR is installed
189    and supply the appropriate --with-apr option to 'configure'.])
190    all_reqs_ok="false"
191fi
192
193# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
194if (test "$svn_found" = "no") ; then
195    svn_msg="Subversion API not found. Subversion API libraries cannot
196    be found. Make sure the APIs are installed and supply the
197    appropriate --with-svn option to 'configure'."
198if (test "$apr_found" = "no") ; then
199    svn_msg="$svn_msg
200    Note, APR was not found. Failure to locate APR affects the search
201    of the subversion API. Please fix the APR problem before trying
202    to resolve the subversion related issues."
203fi
204    AC_MSG_WARN([$svn_msg])
205    all_reqs_ok="false"
206fi
207
208if test $ac_cv_type_long_long_int != yes ; then
209   AC_MSG_WARN([Compiler $CXX does not support `long long'.
210          svndigest must be compiled with a compiler that supports `long long'.])
211   all_reqs_ok="false"
212fi
213
214if (test "$all_reqs_ok" = "false") ; then
215    AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
216    configure. Please consult the 'INSTALL' file for more information
217    about what is needed to compile svndigest and refer to above
218    warning messages. Needed files were NOT created.])
219fi
220
221# Create output.
222AC_OUTPUT
223
224# Some more messages.
225AC_MSG_NOTICE([])
226AC_MSG_NOTICE([   Ready to compile the executables of svndigest $VERSION])
227AC_MSG_NOTICE([   The following flags and libs will be used:])
228AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
229AC_MSG_NOTICE([    Compiler:           CXX=\"$CXX\"])
230AC_MSG_NOTICE([    Preprocessor flags: CPPFLAGS=\"$CPPFLAGS\"])
231AC_MSG_NOTICE([    C++ flags:          CXXFLAGS=\"$CXXFLAGS\"])
232AC_MSG_NOTICE([    Linker flags:       LDFLAGS=\"$LDFLAGS\"])
233AC_MSG_NOTICE([    LIBS:               LIBS=\"$LIBS\"])
234AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
235AC_MSG_NOTICE([])
236
237# Failure to locate gnuplot is not considered fatal
238if (test "$GNUPLOT" != "ok") ; then
239    AC_MSG_WARN([Gnuplot was not found. svndigest will compile
240    without gnuplot but will throw an exception at run-time. Please
241    install gnuplot (available for a wide range of operating systems
242    at http://www.gnuplot.info).])
243    AC_MSG_NOTICE([])
244fi
245
246if test "$enable_staticbin" = "yes"; then
247    AC_MSG_NOTICE([A statically linked 'svndigest' binary will be created.])
248else
249    AC_MSG_NOTICE([A dynamically linked 'svndigest' binary will be created.])
250fi
251    AC_MSG_NOTICE([])
252
253AC_MSG_NOTICE([Now type 'make ; make check'.])
254
Note: See TracBrowser for help on using the repository browser.