source: trunk/configure.ac @ 591

Last change on this file since 591 was 590, checked in by Jari Häkkinen, 14 years ago

Updating bootstrap script together with corresponding changes to other files.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 10.0 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 590 2008-04-12 18:20:32Z jari $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson
15# Copyright (C) 2008 Peter Johansson
16#
17# This file is part of svndigest, http://trac.thep.lu.se/svndigest
18#
19# svndigest is free software; you can redistribute it and/or modify it
20# under the terms of the GNU General Public License as published by
21# the Free Software Foundation; either version 2 of the License, or
22# (at your option) any later version.
23#
24# svndigest is distributed in the hope that it will be useful, but
25# WITHOUT ANY WARRANTY; without even the implied warranty of
26# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
27# General Public License for more details.
28#
29# You should have received a copy of the GNU General Public License
30# along with this program; if not, write to the Free Software
31# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
32# 02111-1307, USA.
33
34AC_PREREQ(2.57)
35
36
37m4_include([./build_support/version.m4])
38AC_INIT([svndigest],[SVNDIGEST_VERSION],[jari@thep.lu.se])
39AC_CONFIG_SRCDIR([lib/File.h])
40AC_CONFIG_AUX_DIR([autotools])
41AC_PREFIX_DEFAULT([/usr/local])
42test $prefix = NONE && prefix=/usr/local
43
44AC_SUBST([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION])
45AC_SUBST([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION])
46AC_SUBST([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION])
47
48AC_DEFINE([DEV_BUILD],[SVNDIGEST_DEV_BUILD],
49          [true if dev build (version starts with pre)])
50AC_DEFINE([VERSION_MAJOR], [SVNDIGEST_MAJOR_VERSION],
51                    [Define to the svndigest major version])
52AC_DEFINE([VERSION_MINOR], [SVNDIGEST_MINOR_VERSION],
53                    [Define to the svndigest minor version])
54AC_DEFINE([VERSION_PATCH], [SVNDIGEST_PATCH_VERSION],
55                    [Define to the svndigest patch version])
56
57AC_CONFIG_HEADER([config.h])
58AM_INIT_AUTOMAKE([std-options check-news])
59
60# seems like these variables are not set with older autoconf(?)
61AC_SUBST([abs_srcdir], ["`cd $srcdir && pwd`"])
62AC_SUBST([abs_builddir], ["`pwd`"])
63
64# Set default programming language
65AC_LANG(C++)
66
67# Let user overide default CXXFLAGS
68if test "${CXXFLAGS+set}" != set; then
69  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
70fi
71# Checks for programs.
72AC_PROG_CXXCPP
73AC_PROG_CXX
74AC_PROG_INSTALL
75AC_PROG_LIBTOOL
76AC_PROG_SED
77AC_CHECK_PROG([GNUPLOT],[gnuplot],[ok])
78
79# -Wno-long-long is needed to suppress compiler diagnostics regarding
80# using extension beyond the C++ standard (usage of non C++ standard
81# 'long long' types).
82CXXFLAGS="$CXXFLAGS -Wall -pedantic -Wno-long-long"
83AC_TYPE_LONG_LONG_INT()
84
85AC_ARG_ENABLE(debug,
86  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])],
87  [CXXFLAGS="$CXXFLAGS -g -O"],
88  [CPPFLAGS="$CPPFLAGS -DNDEBUG" CXXFLAGS="$CXXFLAGS -O3"])
89
90# optionally prepare for building static libraries.
91AC_ARG_ENABLE(staticbin,
92  [AS_HELP_STRING([--enable-staticbin], [create a static binary,
93  at least as static as the available underlying libraries
94  allows])])
95if test "$enable_staticbin" = "yes"; then
96  case $host in
97  *-apple-darwin*)
98    # At the time of creating this libsvn_subr uses
99    # Keychain on Mac OSX. In consequence the below
100    # frameworks are needed for succesful static builds.
101    LIBS="$LIBS -framework Security"
102    LIBS="$LIBS -framework CoreFoundation"
103    LIBS="$LIBS -framework CoreServices"
104    ;;
105  esac
106  STATICFLAG=-static
107  AC_SUBST(STATICFLAG)
108fi
109
110# Apache Portable Runtime (APR) API checks
111# The next three lines are not needed as long as APR_FIND_APR is used.
112# AC_ARG_WITH(apr,
113#  [  --with-apr=DIR          prefix for installed APR or path to APR build
114#                          tree [[PREFIX]]])
115# Include APR_FIND_APR macro distributed within the APR project. If
116# the usage of the APR macro is to be omitted then the construct for
117# setting the CXXFLAGS (header file location) and LDFLAGS (linking
118# informaion) for APR must be changed. The latter can be achieved with
119# AC_SEARCH_LIBS([apr_allocator_create],[apr-0],,apr_found="no") but
120# apr-0 must be prior knowledge.
121sinclude(./build_support/find_apr.m4)
122APR_FIND_APR(,,1,[1 0])
123if test "$apr_found" = "yes" ; then
124    LDFLAGS="`$apr_config --link-ld` $LDFLAGS"
125    CPPFLAGS="`$apr_config --includes` $CPPFLAGS"
126    AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
127fi
128
129# Subversion API checks
130svn_found="yes"
131AC_ARG_WITH(svn,
132  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
133  [ LDFLAGS="-L$withval/lib $LDFLAGS" CPPFLAGS="-I$withval/include $CPPFLAGS"])
134AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
135# The library checks below may match shared libs even when
136# --enable-staticbin is given to configure. This should probably not
137# pose any problems since in a properly installed system the shared
138# and static libraries should be the same.
139AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],,svn_found="no")
140AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],,svn_found="no")
141AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],,svn_found="no")
142AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],,svn_found="no")
143AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],,svn_found="no")
144
145
146# check if svnversion is installed
147have_svnversion="yes"
148AC_PATH_PROG(SVNVERSION, svnversion, have_svnversion="no")
149
150wc_found="no";
151if (test $have_svnversion != "no" &&
152    test `$SVNVERSION -n $srcdir` != "exported");
153then
154   wc_found="yes";
155fi
156echo $wc_found
157AC_CHECK_FILE("$srcdir/lib/subversion_info.cc",info_found="yes",info_found="no")
158
159# Checking that a release (non-dev) has no pre in VERSION
160# Failure should be captured by distcheck
161if (test "$wc_found" = "no" && test "$DEV_BUILD" = "yes") ; then
162   AC_MSG_ERROR([Incorrect version number: $VERSION
163                 Version number of an official release should have format
164                 MAJOR.MINOR or MAJOR.MINOR.PATCH])
165fi
166
167# devel version should have svn WC and SVNVERSION installed
168AM_CONDITIONAL(HAVE_SVN_WC, test "$wc_found" = "yes" )
169
170
171AC_CONFIG_FILES([Makefile
172                bin/Makefile
173                lib/Makefile
174                test/Makefile])
175
176# Print failure status information about selected items, and exit if
177# fatal errors were encountered. No output will be created if
178# configure is halted prematurely.
179
180# used to trigger exit before creation of output
181all_reqs_ok="true"
182
183if (test "$wc_found" != "yes") ; then
184if (test "$info_found" = "no") ; then
185   AC_MSG_WARN([Cannot find sources (lib/subversion_info.cc).])
186   if (test "$svnversion" = "no") ; then
187     AC_MSG_WARN([If you grabbed the source from the subversion repository,
188     the file will be generated automatically. However, svnversion cannot
189     be found and therefore the file cannot be generated. Please install
190     svnversion and make sure it is in your search path.])
191   else
192     AC_MSG_WARN([If you grabbed the source from the subversion repository,
193     the file will be generated automatically. However, the output from
194     svnversion was incorrect. Either your installation of svnversion is
195     is not healthy or there is something wrong with the repository.])
196   fi
197   all_reqs_ok="false"
198else
199   dnl test repo is not distributed
200   AC_CONFIG_FILES([test/test_repo.sh
201                    test/check_repo_status.sh],
202                   [chmod +x test/test_repo.sh;
203                    chmod +x test/check_repo_status.sh])
204   
205fi
206fi
207
208# Non-existing APR is fatal -- sub-sequent compilation will fail.
209if (test "$apr_found" = "no") ; then
210    AC_MSG_WARN([APR not found. The Apache Portable Runtime
211    (APR) library cannot be found. Please make sure APR is installed
212    and supply the appropriate --with-apr option to 'configure'.])
213    all_reqs_ok="false"
214fi
215
216# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
217if (test "$svn_found" = "no") ; then
218    svn_msg="Subversion API not found. Subversion API libraries cannot
219    be found. Make sure the APIs are installed and supply the
220    appropriate --with-svn option to 'configure'."
221if (test "$apr_found" = "no") ; then
222    svn_msg="$svn_msg
223    Note, APR was not found. Failure to locate APR affects the search
224    of the subversion API. Please fix the APR problem before trying
225    to resolve the subversion related issues."
226fi
227    AC_MSG_WARN([$svn_msg])
228    all_reqs_ok="false"
229fi
230
231if test $ac_cv_type_long_long_int != yes ; then
232   AC_MSG_WARN([Compiler $CXX does not support `long long'.
233          svndigest must be compiled with a compiler that supports `long long'.])
234   all_reqs_ok="false"
235fi
236
237if (test "$all_reqs_ok" = "false") ; then
238    AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
239    configure. Please consult the 'INSTALL' file for more information
240    about what is needed to compile svndigest and refer to above
241    warning messages. Needed files were NOT created.])
242fi
243
244# Create output.
245AC_OUTPUT
246
247# Some more messages.
248AC_MSG_NOTICE([])
249AC_MSG_NOTICE([   Ready to compile the executables of svndigest $VERSION])
250AC_MSG_NOTICE([   The following flags and libs will be used:])
251AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
252AC_MSG_NOTICE([    Compiler:           CXX=\"$CXX\"])
253AC_MSG_NOTICE([    Preprocessor flags: CPPFLAGS=\"$CPPFLAGS\"])
254AC_MSG_NOTICE([    C++ flags:          CXXFLAGS=\"$CXXFLAGS\"])
255AC_MSG_NOTICE([    Linker flags:       LDFLAGS=\"$LDFLAGS\"])
256AC_MSG_NOTICE([    LIBS:               LIBS=\"$LIBS\"])
257AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
258AC_MSG_NOTICE([])
259
260# Failure to locate gnuplot is not considered fatal
261if (test "$GNUPLOT" != "ok") ; then
262    AC_MSG_WARN([Gnuplot was not found. svndigest will compile
263    without gnuplot but will throw an exception at run-time. Please
264    install gnuplot (available for a wide range of operating systems
265    at http://www.gnuplot.info).])
266    AC_MSG_NOTICE([])
267fi
268
269if test "$enable_staticbin" = "yes"; then
270    AC_MSG_NOTICE([A statically linked 'svndigest' binary will be created.])
271else
272    AC_MSG_NOTICE([A dynamically linked 'svndigest' binary will be created.])
273fi
274    AC_MSG_NOTICE([])
275
276AC_MSG_NOTICE([Now type 'make ; make check'.])
277
Note: See TracBrowser for help on using the repository browser.