source: trunk/configure.ac @ 611

Last change on this file since 611 was 606, checked in by Peter Johansson, 13 years ago

Fixes ticket:318. Changed HtmlStream? to be inherited from ostream and created a HtmlBuf? (inherited from streambuf) that does the real work.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 10.0 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 606 2008-04-20 03:46:56Z peter $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson
15#
16# This file is part of svndigest, http://trac.thep.lu.se/svndigest
17#
18# svndigest is free software; you can redistribute it and/or modify it
19# under the terms of the GNU General Public License as published by
20# the Free Software Foundation; either version 2 of the License, or
21# (at your option) any later version.
22#
23# svndigest is distributed in the hope that it will be useful, but
24# WITHOUT ANY WARRANTY; without even the implied warranty of
25# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
26# General Public License for more details.
27#
28# You should have received a copy of the GNU General Public License
29# along with this program; if not, write to the Free Software
30# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
31# 02111-1307, USA.
32
33AC_PREREQ(2.60)
34
35
36m4_include([./build_support/version.m4])
37AC_INIT([svndigest],[SVNDIGEST_VERSION],[jari@thep.lu.se])
38AC_CONFIG_SRCDIR([lib/File.h])
39AC_CONFIG_AUX_DIR([autotools])
40AC_PREFIX_DEFAULT([/usr/local])
41test $prefix = NONE && prefix=/usr/local
42
43AC_SUBST([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION])
44AC_SUBST([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION])
45AC_SUBST([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION])
46
47AC_DEFINE([DEV_BUILD],[SVNDIGEST_DEV_BUILD],
48          [true if dev build (version starts with pre)])
49AC_DEFINE([VERSION_MAJOR], [SVNDIGEST_MAJOR_VERSION],
50                    [Define to the svndigest major version])
51AC_DEFINE([VERSION_MINOR], [SVNDIGEST_MINOR_VERSION],
52                    [Define to the svndigest minor version])
53AC_DEFINE([VERSION_PATCH], [SVNDIGEST_PATCH_VERSION],
54                    [Define to the svndigest patch version])
55
56AC_CONFIG_HEADER([config.h])
57AM_INIT_AUTOMAKE([std-options check-news])
58
59# seems like these variables are not set with older autoconf(?)
60AC_SUBST([abs_srcdir], ["`cd $srcdir && pwd`"])
61AC_SUBST([abs_builddir], ["`pwd`"])
62
63# Set default programming language
64AC_LANG(C++)
65
66# Let user overide default CXXFLAGS
67if test "${CXXFLAGS+set}" != set; then
68  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
69fi
70# Checks for programs.
71AC_PROG_CXXCPP
72AC_PROG_CXX
73AC_PROG_INSTALL
74AC_PROG_LIBTOOL
75AC_PROG_SED
76AC_CHECK_PROG([GNUPLOT],[gnuplot],[ok])
77
78# -Wno-long-long is needed to suppress compiler diagnostics regarding
79# using extension beyond the C++ standard (usage of non C++ standard
80# 'long long' types).
81CXXFLAGS="$CXXFLAGS -Wall -pedantic -Wno-long-long"
82AC_TYPE_LONG_LONG_INT()
83
84AC_ARG_ENABLE(debug,
85  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])],
86  [CXXFLAGS="$CXXFLAGS -g -O"],
87  [CPPFLAGS="$CPPFLAGS -DNDEBUG" CXXFLAGS="$CXXFLAGS -O3"])
88
89# optionally prepare for building static libraries.
90AC_ARG_ENABLE(staticbin,
91  [AS_HELP_STRING([--enable-staticbin], [create a static binary,
92  at least as static as the available underlying libraries
93  allows])])
94if test "$enable_staticbin" = "yes"; then
95  case $host in
96  *-apple-darwin*)
97    # At the time of creating this libsvn_subr uses
98    # Keychain on Mac OSX. In consequence the below
99    # frameworks are needed for succesful static builds.
100    LIBS="$LIBS -framework Security"
101    LIBS="$LIBS -framework CoreFoundation"
102    LIBS="$LIBS -framework CoreServices"
103    ;;
104  esac
105  STATICFLAG=-static
106  AC_SUBST(STATICFLAG)
107fi
108
109# Apache Portable Runtime (APR) API checks
110# The next three lines are not needed as long as APR_FIND_APR is used.
111# AC_ARG_WITH(apr,
112#  [  --with-apr=DIR          prefix for installed APR or path to APR build
113#                          tree [[PREFIX]]])
114# Include APR_FIND_APR macro distributed within the APR project. If
115# the usage of the APR macro is to be omitted then the construct for
116# setting the CXXFLAGS (header file location) and LDFLAGS (linking
117# informaion) for APR must be changed. The latter can be achieved with
118# AC_SEARCH_LIBS([apr_allocator_create],[apr-0],,apr_found="no") but
119# apr-0 must be prior knowledge.
120sinclude(./build_support/find_apr.m4)
121APR_FIND_APR(,,1,[1 0])
122if test "$apr_found" = "yes" ; then
123    LDFLAGS="`$apr_config --link-ld` $LDFLAGS"
124    CPPFLAGS="`$apr_config --includes` $CPPFLAGS"
125    AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
126fi
127
128# Subversion API checks
129svn_found="yes"
130AC_ARG_WITH(svn,
131  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
132  [ LDFLAGS="-L$withval/lib $LDFLAGS" CPPFLAGS="-I$withval/include $CPPFLAGS"])
133AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
134# The library checks below may match shared libs even when
135# --enable-staticbin is given to configure. This should probably not
136# pose any problems since in a properly installed system the shared
137# and static libraries should be the same.
138AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],,svn_found="no")
139AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],,svn_found="no")
140AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],,svn_found="no")
141AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],,svn_found="no")
142AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],,svn_found="no")
143
144
145# check if svnversion is installed
146have_svnversion="yes"
147AC_PATH_PROG(SVNVERSION, svnversion, have_svnversion="no")
148
149wc_found="no";
150if (test $have_svnversion != "no" &&
151    test `$SVNVERSION -n $srcdir` != "exported");
152then
153   wc_found="yes";
154fi
155AC_CHECK_FILE("$srcdir/lib/subversion_info.cc",info_found="yes",info_found="no")
156
157# Checking that a release (non-dev) has no pre in VERSION
158# Failure should be captured by distcheck
159if (test "$wc_found" = "no" && test "$DEV_BUILD" = "yes") ; then
160   AC_MSG_ERROR([Incorrect version number: $VERSION
161                 Version number of an official release should have format
162                 MAJOR.MINOR or MAJOR.MINOR.PATCH])
163fi
164
165# devel version should have svn WC and SVNVERSION installed
166AM_CONDITIONAL(HAVE_SVN_WC, test "$wc_found" = "yes" )
167
168
169AC_CONFIG_FILES([Makefile
170                bin/Makefile
171                lib/Makefile
172                test/environment.h
173                test/Makefile])
174
175# Print failure status information about selected items, and exit if
176# fatal errors were encountered. No output will be created if
177# configure is halted prematurely.
178
179# used to trigger exit before creation of output
180all_reqs_ok="true"
181
182if (test "$wc_found" != "yes") ; then
183if (test "$info_found" = "no") ; then
184   AC_MSG_WARN([Cannot find sources (lib/subversion_info.cc).])
185   if (test "$svnversion" = "no") ; then
186     AC_MSG_WARN([If you grabbed the source from the subversion repository,
187     the file will be generated automatically. However, svnversion cannot
188     be found and therefore the file cannot be generated. Please install
189     svnversion and make sure it is in your search path.])
190   else
191     AC_MSG_WARN([If you grabbed the source from the subversion repository,
192     the file will be generated automatically. However, the output from
193     svnversion was incorrect. Either your installation of svnversion is
194     is not healthy or there is something wrong with the repository.])
195   fi
196   all_reqs_ok="false"
197else
198   dnl test repo is not distributed
199   AC_CONFIG_FILES([test/test_repo.sh
200                    test/check_repo_status.sh],
201                   [chmod +x test/test_repo.sh;
202                    chmod +x test/check_repo_status.sh])
203   
204fi
205fi
206
207# Non-existing APR is fatal -- sub-sequent compilation will fail.
208if (test "$apr_found" = "no") ; then
209    AC_MSG_WARN([APR not found. The Apache Portable Runtime
210    (APR) library cannot be found. Please make sure APR is installed
211    and supply the appropriate --with-apr option to 'configure'.])
212    all_reqs_ok="false"
213fi
214
215# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
216if (test "$svn_found" = "no") ; then
217    svn_msg="Subversion API not found. Subversion API libraries cannot
218    be found. Make sure the APIs are installed and supply the
219    appropriate --with-svn option to 'configure'."
220if (test "$apr_found" = "no") ; then
221    svn_msg="$svn_msg
222    Note, APR was not found. Failure to locate APR affects the search
223    of the subversion API. Please fix the APR problem before trying
224    to resolve the subversion related issues."
225fi
226    AC_MSG_WARN([$svn_msg])
227    all_reqs_ok="false"
228fi
229
230if test $ac_cv_type_long_long_int != yes ; then
231   AC_MSG_WARN([Compiler $CXX does not support `long long'.
232          svndigest must be compiled with a compiler that supports `long long'.])
233   all_reqs_ok="false"
234fi
235
236if (test "$all_reqs_ok" = "false") ; then
237    AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
238    configure. Please consult the 'README' file for more information
239    about what is needed to compile svndigest and refer to above
240    warning messages. Needed files were NOT created.])
241fi
242
243# Create output.
244AC_OUTPUT
245
246# Some more messages.
247AC_MSG_NOTICE([])
248AC_MSG_NOTICE([   Ready to compile the executables of svndigest $VERSION])
249AC_MSG_NOTICE([   The following flags and libs will be used:])
250AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
251AC_MSG_NOTICE([    Compiler:           CXX=\"$CXX\"])
252AC_MSG_NOTICE([    Preprocessor flags: CPPFLAGS=\"$CPPFLAGS\"])
253AC_MSG_NOTICE([    C++ flags:          CXXFLAGS=\"$CXXFLAGS\"])
254AC_MSG_NOTICE([    Linker flags:       LDFLAGS=\"$LDFLAGS\"])
255AC_MSG_NOTICE([    LIBS:               LIBS=\"$LIBS\"])
256AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
257AC_MSG_NOTICE([])
258
259# Failure to locate gnuplot is not considered fatal
260if (test "$GNUPLOT" != "ok") ; then
261    AC_MSG_WARN([Gnuplot was not found. svndigest will compile
262    without gnuplot but will throw an exception at run-time. Please
263    install gnuplot (available for a wide range of operating systems
264    at http://www.gnuplot.info).])
265    AC_MSG_NOTICE([])
266fi
267
268if test "$enable_staticbin" = "yes"; then
269    AC_MSG_NOTICE([A statically linked 'svndigest' binary will be created.])
270else
271    AC_MSG_NOTICE([A dynamically linked 'svndigest' binary will be created.])
272fi
273    AC_MSG_NOTICE([])
274
275AC_MSG_NOTICE([Now type 'make ; make check'.])
276
Note: See TracBrowser for help on using the repository browser.