source: trunk/configure.ac @ 670

Last change on this file since 670 was 670, checked in by Jari Häkkinen, 13 years ago

Fixing indentation.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 9.8 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 670 2008-07-04 00:15:16Z jari $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson
15#
16# This file is part of svndigest, http://trac.thep.lu.se/svndigest
17#
18# svndigest is free software; you can redistribute it and/or modify it
19# under the terms of the GNU General Public License as published by
20# the Free Software Foundation; either version 2 of the License, or
21# (at your option) any later version.
22#
23# svndigest is distributed in the hope that it will be useful, but
24# WITHOUT ANY WARRANTY; without even the implied warranty of
25# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
26# General Public License for more details.
27#
28# You should have received a copy of the GNU General Public License
29# along with this program; if not, write to the Free Software
30# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
31# 02111-1307, USA.
32
33AC_PREREQ(2.60)
34
35
36m4_include([./build_support/version.m4])
37AC_INIT([svndigest],[SVNDIGEST_VERSION],[jari@thep.lu.se])
38AC_CONFIG_SRCDIR([lib/File.h])
39AC_CONFIG_AUX_DIR([autotools])
40AC_PREFIX_DEFAULT([/usr/local])
41test $prefix = NONE && prefix=/usr/local
42
43AC_SUBST([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION])
44AC_SUBST([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION])
45AC_SUBST([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION])
46
47AC_DEFINE([DEV_BUILD],[SVNDIGEST_DEV_BUILD],
48          [true if dev build (version starts with pre)])
49AC_DEFINE([VERSION_MAJOR], [SVNDIGEST_MAJOR_VERSION],
50                    [Define to the svndigest major version])
51AC_DEFINE([VERSION_MINOR], [SVNDIGEST_MINOR_VERSION],
52                    [Define to the svndigest minor version])
53AC_DEFINE([VERSION_PATCH], [SVNDIGEST_PATCH_VERSION],
54                    [Define to the svndigest patch version])
55
56AC_CONFIG_HEADER([config.h])
57AM_INIT_AUTOMAKE([std-options check-news])
58
59# seems like these variables are not set with older autoconf(?)
60AC_SUBST([abs_srcdir], ["`cd $srcdir && pwd`"])
61AC_SUBST([abs_builddir], ["`pwd`"])
62
63# Set default programming language
64AC_LANG(C++)
65
66# Let user overide default CXXFLAGS
67if test "${CXXFLAGS+set}" != set; then
68  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
69fi
70# Checks for programs.
71AC_PROG_CXXCPP
72AC_PROG_CXX
73AC_PROG_INSTALL
74AC_PROG_RANLIB
75AC_PROG_SED
76AC_CHECK_PROG([GNUPLOT],[gnuplot],[ok])
77
78# Save FLAGS
79SAVE_CPPFLAGS="$CPPFLAGS"
80SAVE_CXXFLAGS="$CXXFLAGS"
81SAVE_LDFLAGS="$LDFLAGS"
82SAVE_LIBS="$LIBS"
83
84# -Wno-long-long is needed to suppress compiler diagnostics regarding
85# using extension beyond the C++ standard (usage of non C++ standard
86# 'long long' types).
87SD_CXXFLAGS="$SD_CXXFLAGS-Wall -pedantic -Wno-long-long"
88AC_TYPE_LONG_LONG_INT()
89
90AC_ARG_ENABLE(debug,
91  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])],
92  [SD_CXXFLAGS="$SD_CXXFLAGS -g -O"],
93  [SD_CPPFLAGS="-DNDEBUG" SD_CXXFLAGS="$SD_CXXFLAGS -O3"])
94
95# Apache Portable Runtime (APR) API checks
96# The next three lines are not needed as long as APR_FIND_APR is used.
97# AC_ARG_WITH(apr,
98#  [  --with-apr=DIR          prefix for installed APR or path to APR build
99#                          tree [[PREFIX]]])
100# Include APR_FIND_APR macro distributed within the APR project. If
101# the usage of the APR macro is to be omitted then the construct for
102# setting the CXXFLAGS (header file location) and LDFLAGS (linking
103# informaion) for APR must be changed. The latter can be achieved with
104# AC_SEARCH_LIBS([apr_allocator_create],[apr-0],,apr_found="no") but
105# apr-0 must be prior knowledge.
106m4_sinclude(./build_support/find_apr.m4)
107APR_FIND_APR(,,1,[1 0])
108if test "$apr_found" = "yes" ; then
109    SD_LDFLAGS="`$apr_config --link-ld` $SD_LDFLAGS"
110    SD_CPPFLAGS="`$apr_config --includes --cppflags` $SD_CPPFLAGS"
111fi
112
113# Subversion API checks
114svn_found="yes"
115AC_ARG_WITH(svn,
116  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
117  [ SD_LDFLAGS="-L$withval/lib $SD_LDFLAGS"
118    SD_CPPFLAGS="-I$withval/include $SD_CPPFLAGS"])
119
120
121# Use SD_*FLAGS in tests
122CPPFLAGS="$SD_CPPFLAGS $CPPFLAGS"
123CXXFLAGS="$SD_CXXFLAGS $CXXFLAGS"
124LDFLAGS="$SD_LDFLAGS $LDFLAGS"
125LIBS="$SD_LIBS $LIBS"
126
127AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
128AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
129AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],
130               [SD_LIBS="-lsvn_subr-1 $SD_LIBS"],svn_found="no")
131AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],
132               [SD_LIBS="-lsvn_ra-1 $SD_LIBS"],svn_found="no")
133AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],
134               [SD_LIBS="-lsvn_wc-1 $SD_LIBS"],svn_found="no")
135AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],
136               [SD_LIBS="-lsvn_diff-1 $SD_LIBS"],svn_found="no")
137AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],
138               [SD_LIBS="-lsvn_client-1 $SD_LIBS"],svn_found="no")
139
140# Export flags
141AC_SUBST([SVNDIGEST_CPPFLAGS], $SD_CPPFLAGS)
142AC_SUBST([SVNDIGEST_CXXFLAGS], $SD_CXXFLAGS)
143AC_SUBST([SVNDIGEST_LDFLAGS], $SD_LDFLAGS)
144AC_SUBST([SVNDIGEST_LIBS], $SD_LIBS)
145
146# Reset FLAGS
147CPPFLAGS="$SAVE_CPPFLAGS"
148CXXFLAGS="$SAVE_CXXFLAGS"
149LDFLAGS="$SAVE_LDFLAGS"
150LIBS="$SAVE_LIBS"
151
152# check if svnversion is installed
153have_svnversion="yes"
154AC_PATH_PROG(SVNVERSION, svnversion, have_svnversion="no")
155
156# checking if we build in a subversion WC
157wc_found="no";
158if (test $have_svnversion != "no" &&
159  test `$SVNVERSION -n $srcdir` != "exported");
160then
161  wc_found="yes";
162fi
163AC_CHECK_FILE("$srcdir/lib/subversion_info.cc",info_found="yes",info_found="no")
164
165# checking that DEV_BUILD is set to false at time of release
166# Failure should be captured by distcheck
167if (test "$wc_found" = "no" && test "$SVNDIGEST_DEV_BUILD" = "true") ; then
168  AC_MSG_ERROR([Incorrect version:
169               [SVNDIGEST_DEV_BUILD] is set to SVNDIGEST_DEV_BUILD.
170         [SVNDIGEST_DEV_BUILD] should be set to false at time of release.
171               Please, update version.m4.])
172fi
173
174
175# devel version should have svn WC and SVNVERSION installed
176AM_CONDITIONAL(HAVE_SVN_WC, test "$wc_found" = "yes" )
177
178
179AC_CONFIG_FILES([Makefile
180                bin/Makefile
181                lib/Makefile
182                test/environment.h
183                test/Makefile])
184
185# Print failure status information about selected items, and exit if
186# fatal errors were encountered. No output will be created if
187# configure is halted prematurely.
188
189# used to trigger exit before creation of output
190all_reqs_ok="true"
191
192if (test "$wc_found" != "yes") ; then
193if (test "$info_found" = "no") ; then
194   AC_MSG_WARN([Cannot find sources (lib/subversion_info.cc).])
195   if (test "$svnversion" = "no") ; then
196     AC_MSG_WARN([If you grabbed the source from the subversion repository,
197     the file will be generated automatically. However, svnversion cannot
198     be found and therefore the file cannot be generated. Please install
199     svnversion and make sure it is in your search path.])
200   else
201     AC_MSG_WARN([If you grabbed the source from the subversion repository,
202     the file will be generated automatically. However, the output from
203     svnversion was incorrect. Either your installation of svnversion is
204     is not healthy or there is something wrong with the repository.])
205   fi
206   all_reqs_ok="false"
207else
208  dnl test repo is not distributed
209  AC_CONFIG_FILES([test/test_repo.sh], [chmod +x test/test_repo.sh])
210  AC_CONFIG_FILES([test/check_repo_status.sh], [chmod +x test/check_repo_status.sh])   
211fi
212fi
213
214# Non-existing APR is fatal -- sub-sequent compilation will fail.
215if (test "$apr_found" = "no") ; then
216  AC_MSG_WARN([APR not found. The Apache Portable Runtime
217  (APR) library cannot be found. Please make sure APR is installed
218  and supply the appropriate --with-apr option to 'configure'.])
219  all_reqs_ok="false"
220fi
221
222# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
223if (test "$svn_found" = "no") ; then
224  svn_msg="Subversion API not found. Subversion API libraries cannot
225  be found. Make sure the APIs are installed and supply the
226  appropriate --with-svn option to 'configure'."
227  if (test "$apr_found" = "no") ; then
228    svn_msg="$svn_msg
229    Note, APR was not found. Failure to locate APR affects the search
230    of the subversion API. Please fix the APR problem before trying
231    to resolve the subversion related issues."
232  fi
233  AC_MSG_WARN([$svn_msg])
234  all_reqs_ok="false"
235fi
236
237if test $ac_cv_type_long_long_int != yes ; then
238  AC_MSG_WARN([Compiler $CXX does not support `long long'.
239  svndigest must be compiled with a compiler that supports `long long'.])
240  all_reqs_ok="false"
241fi
242
243if (test "$all_reqs_ok" = "false") ; then
244  AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
245  configure. Please consult the 'README' file for more information
246  about what is needed to compile svndigest and refer to above
247  warning messages. Needed files were NOT created.])
248fi
249
250# Create output.
251AC_OUTPUT
252
253# Some more messages.
254AC_MSG_NOTICE([])
255AC_MSG_NOTICE([   Ready to compile the executables of svndigest $VERSION])
256AC_MSG_NOTICE([   The following flags and libs will be used:])
257AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
258AC_MSG_NOTICE([    Compiler:           $CXX])
259AC_MSG_NOTICE([    Preprocessor flags: $SD_CPPFLAGS $CPPFLAGS])
260AC_MSG_NOTICE([    C++ flags:          $SD_CXXFLAGS $CXXFLAGS])
261AC_MSG_NOTICE([    Linker flags:       $SD_LDFLAGS $LDFLAGS])
262AC_MSG_NOTICE([    LIBS:               $SD_LIBS $LIBS])
263AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
264AC_MSG_NOTICE([])
265
266# Failure to locate gnuplot is not considered fatal
267if (test "$GNUPLOT" != "ok") ; then
268  AC_MSG_WARN([Gnuplot was not found. svndigest will compile
269  without gnuplot but will throw an exception at run-time. Please
270  install gnuplot (available for a wide range of operating systems
271  at http://www.gnuplot.info).])
272  AC_MSG_NOTICE([])
273fi
274
275AC_MSG_NOTICE([Now type 'make ; make check'.])
Note: See TracBrowser for help on using the repository browser.