source: trunk/configure.ac @ 729

Last change on this file since 729 was 729, checked in by Peter Johansson, 13 years ago

we require automake 1.10 so these lines are not needed

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 9.4 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 729 2008-12-14 16:59:35Z peter $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson
15#
16# This file is part of svndigest, http://dev.thep.lu.se/svndigest
17#
18# svndigest is free software; you can redistribute it and/or modify it
19# under the terms of the GNU General Public License as published by
20# the Free Software Foundation; either version 3 of the License, or
21# (at your option) any later version.
22#
23# svndigest is distributed in the hope that it will be useful, but
24# WITHOUT ANY WARRANTY; without even the implied warranty of
25# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
26# General Public License for more details.
27#
28# You should have received a copy of the GNU General Public License
29# along with svndigest. If not, see <http://www.gnu.org/licenses/>.
30
31AC_PREREQ(2.60)
32
33
34m4_include([build_support/version.m4])
35AC_INIT([svndigest],[SVNDIGEST_VERSION],[jari@thep.lu.se])
36AC_CONFIG_SRCDIR([lib/File.h])
37AC_CONFIG_AUX_DIR([autotools])
38dnl arg below should be the same as in Makefile.am
39AC_CONFIG_MACRO_DIR([build_support])
40AC_PREFIX_DEFAULT([/usr/local])
41test $prefix = NONE && prefix=/usr/local
42
43AC_SUBST([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION])
44AC_SUBST([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION])
45AC_SUBST([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION])
46
47AC_DEFINE([DEV_BUILD],[SVNDIGEST_DEV_BUILD],
48          [true if dev build (version ends with pre)])
49AC_DEFINE([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION],
50                    [Define to the svndigest major version])
51AC_DEFINE([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION],
52                    [Define to the svndigest minor version])
53AC_DEFINE([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION],
54                    [Define to the svndigest patch version])
55
56AC_CONFIG_HEADER([config.h])
57AM_INIT_AUTOMAKE([1.10 std-options check-news])
58
59# Set default programming language
60AC_LANG(C++)
61
62# Let user overide default CXXFLAGS
63if test "${CXXFLAGS+set}" != set; then
64  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
65fi
66
67# Checks for programs.
68AC_PROG_CXXCPP
69AC_PROG_CXX
70AC_PROG_INSTALL
71AC_PROG_RANLIB
72AC_PROG_SED
73AM_MISSING_PROG([HELP2MAN], [help2man])
74AC_CHECK_PROG([GNUPLOT],[gnuplot],[ok])
75
76# Save FLAGS
77SAVE_CPPFLAGS="$CPPFLAGS"
78SAVE_CXXFLAGS="$CXXFLAGS"
79SAVE_LDFLAGS="$LDFLAGS"
80SAVE_LIBS="$LIBS"
81
82# -Wno-long-long is needed to suppress compiler diagnostics regarding
83# using extension beyond the C++ standard (usage of non C++ standard
84# 'long long' types).
85SD_CXXFLAGS="$SD_CXXFLAGS-Wall -pedantic -Wno-long-long"
86AC_TYPE_LONG_LONG_INT()
87
88AC_ARG_ENABLE(debug,
89  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])],
90  [SD_CXXFLAGS="$SD_CXXFLAGS -g -O"],
91  [SD_CPPFLAGS="-DNDEBUG" SD_CXXFLAGS="$SD_CXXFLAGS -O3"])
92
93# Apache Portable Runtime (APR) API checks
94# The next three lines are not needed as long as APR_FIND_APR is used.
95# AC_ARG_WITH(apr,
96#  [  --with-apr=DIR          prefix for installed APR or path to APR build
97#                          tree [[PREFIX]]])
98# Include APR_FIND_APR macro distributed within the APR project. If
99# the usage of the APR macro is to be omitted then the construct for
100# setting the CXXFLAGS (header file location) and LDFLAGS (linking
101# informaion) for APR must be changed. The latter can be achieved with
102# AC_SEARCH_LIBS([apr_allocator_create],[apr-0],,apr_found="no") but
103# apr-0 must be prior knowledge.
104APR_FIND_APR(,,1,[1 0])
105if test "$apr_found" = "yes" ; then
106    SD_LIBS="`$apr_config --libs` $SD_LIBS"
107    SD_LDFLAGS="`$apr_config --link-ld` $SD_LDFLAGS"
108    SD_CPPFLAGS="`$apr_config --includes --cppflags` $SD_CPPFLAGS"
109fi
110
111# Subversion API checks
112svn_found="yes"
113AC_ARG_WITH(svn,
114  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
115  [ SD_LDFLAGS="-L$withval/lib $SD_LDFLAGS"
116    SD_CPPFLAGS="-I$withval/include $SD_CPPFLAGS"])
117
118
119# Use SD_*FLAGS in tests
120CPPFLAGS="$SD_CPPFLAGS $CPPFLAGS"
121CXXFLAGS="$SD_CXXFLAGS $CXXFLAGS"
122LDFLAGS="$SD_LDFLAGS $LDFLAGS"
123LIBS="$SD_LIBS $LIBS"
124
125AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
126AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
127AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],
128               [SD_LIBS="-lsvn_subr-1 $SD_LIBS"],svn_found="no")
129AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],
130               [SD_LIBS="-lsvn_ra-1 $SD_LIBS"],svn_found="no")
131AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],
132               [SD_LIBS="-lsvn_wc-1 $SD_LIBS"],svn_found="no")
133AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],
134               [SD_LIBS="-lsvn_diff-1 $SD_LIBS"],svn_found="no")
135AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],
136               [SD_LIBS="-lsvn_client-1 $SD_LIBS"],svn_found="no")
137
138# Export flags
139AC_SUBST([SVNDIGEST_CPPFLAGS], $SD_CPPFLAGS)
140AC_SUBST([SVNDIGEST_CXXFLAGS], $SD_CXXFLAGS)
141AC_SUBST([SVNDIGEST_LDFLAGS], $SD_LDFLAGS)
142AC_SUBST([SVNDIGEST_LIBS], $SD_LIBS)
143
144# Reset FLAGS
145CPPFLAGS="$SAVE_CPPFLAGS"
146CXXFLAGS="$SAVE_CXXFLAGS"
147LDFLAGS="$SAVE_LDFLAGS"
148LIBS="$SAVE_LIBS"
149
150# check if svnversion is installed
151AC_PATH_PROG([SVNVERSION], [svnversion], [no])
152
153# checking if we build in a subversion WC
154AC_MSG_CHECKING([if we build from subversion wc])
155wc_found="no";
156if (test "$SVNVERSION" != "no" &&
157  test `$SVNVERSION -n $srcdir` != "exported");
158then
159  wc_found="yes";
160fi
161AC_MSG_RESULT([$wc_found])
162AC_CHECK_FILE("$srcdir/lib/subversion_info.cc",info_found="yes",info_found="no")
163
164
165# devel version should have svn WC and SVNVERSION installed
166AM_CONDITIONAL(HAVE_SVN_WC, test "$wc_found" = "yes" )
167
168
169AC_CONFIG_FILES([Makefile
170                bin/Makefile
171                lib/Makefile
172                man/Makefile
173                test/environment.h
174                test/Makefile])
175
176# Print failure status information about selected items, and exit if
177# fatal errors were encountered. No output will be created if
178# configure is halted prematurely.
179
180# used to trigger exit before creation of output
181all_reqs_ok="true"
182
183if (test "$wc_found" != "yes") ; then
184if (test "$info_found" = "no") ; then
185   AC_MSG_WARN([Cannot find sources (lib/subversion_info.cc).])
186   if (test "$svnversion" = "no") ; then
187     AC_MSG_WARN([If you grabbed the source from the subversion repository,
188     the file will be generated automatically. However, svnversion cannot
189     be found and therefore the file cannot be generated. Please install
190     svnversion and make sure it is in your search path.])
191   else
192     AC_MSG_WARN([If you grabbed the source from the subversion repository,
193     the file will be generated automatically. However, the output from
194     svnversion was incorrect. Either your installation of svnversion is
195     is not healthy or there is something wrong with the repository.])
196   fi
197   all_reqs_ok="false"
198fi
199else
200  dnl test repo is not distributed
201  AC_CONFIG_FILES([test/test_repo.sh], [chmod +x test/test_repo.sh])
202  AC_CONFIG_FILES([test/check_repo_status.sh], [chmod +x test/check_repo_status.sh])   
203fi
204
205# Non-existing APR is fatal -- sub-sequent compilation will fail.
206if (test "$apr_found" = "no") ; then
207  AC_MSG_WARN([APR not found. The Apache Portable Runtime
208  (APR) library cannot be found. Please make sure APR is installed
209  and supply the appropriate --with-apr option to 'configure'.])
210  all_reqs_ok="false"
211fi
212
213# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
214if (test "$svn_found" = "no") ; then
215  svn_msg="Subversion API not found. Subversion API libraries cannot
216  be found. Make sure the APIs are installed and supply the
217  appropriate --with-svn option to 'configure'."
218  if (test "$apr_found" = "no") ; then
219    svn_msg="$svn_msg
220    Note, APR was not found. Failure to locate APR affects the search
221    of the subversion API. Please fix the APR problem before trying
222    to resolve the subversion related issues."
223  fi
224  AC_MSG_WARN([$svn_msg])
225  all_reqs_ok="false"
226fi
227
228if test $ac_cv_type_long_long_int != yes ; then
229  AC_MSG_WARN([Compiler $CXX does not support `long long'.
230  svndigest must be compiled with a compiler that supports `long long'.])
231  all_reqs_ok="false"
232fi
233
234if (test "$all_reqs_ok" = "false") ; then
235  AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
236  configure. Please consult the 'README' file for more information
237  about what is needed to compile svndigest and refer to above
238  warning messages. Needed files were NOT created.])
239fi
240
241# Create output.
242AC_OUTPUT
243
244# Some more messages.
245AC_MSG_NOTICE([])
246AC_MSG_NOTICE([   Ready to compile the executables of svndigest $VERSION])
247AC_MSG_NOTICE([   The following flags and libs will be used:])
248AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
249AC_MSG_NOTICE([    Compiler:           $CXX])
250AC_MSG_NOTICE([    Preprocessor flags: $SD_CPPFLAGS $CPPFLAGS])
251AC_MSG_NOTICE([    C++ flags:          $SD_CXXFLAGS $CXXFLAGS])
252AC_MSG_NOTICE([    Linker flags:       $SD_LDFLAGS $LDFLAGS])
253AC_MSG_NOTICE([    LIBS:               $SD_LIBS $LIBS])
254AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
255AC_MSG_NOTICE([])
256
257# Failure to locate gnuplot is not considered fatal
258if (test "$GNUPLOT" != "ok") ; then
259  AC_MSG_WARN([Gnuplot was not found. svndigest will compile
260  without gnuplot but will throw an exception at run-time. Please
261  install gnuplot (available for a wide range of operating systems
262  at http://www.gnuplot.info).])
263  AC_MSG_NOTICE([])
264fi
265
266AC_MSG_NOTICE([Now type 'make ; make check'.])
Note: See TracBrowser for help on using the repository browser.