source: trunk/configure.ac @ 740

Last change on this file since 740 was 740, checked in by Peter Johansson, 13 years ago

refs #363: moved configure warning about missing help2man when have_svn_wc rather than when --enable-debug

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 9.7 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 740 2008-12-17 18:54:14Z peter $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson
15#
16# This file is part of svndigest, http://dev.thep.lu.se/svndigest
17#
18# svndigest is free software; you can redistribute it and/or modify it
19# under the terms of the GNU General Public License as published by
20# the Free Software Foundation; either version 3 of the License, or
21# (at your option) any later version.
22#
23# svndigest is distributed in the hope that it will be useful, but
24# WITHOUT ANY WARRANTY; without even the implied warranty of
25# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
26# General Public License for more details.
27#
28# You should have received a copy of the GNU General Public License
29# along with svndigest. If not, see <http://www.gnu.org/licenses/>.
30
31AC_PREREQ(2.60)
32
33m4_include([build_support/version.m4])
34AC_INIT([svndigest],[SVNDIGEST_VERSION],[jari@thep.lu.se])
35AC_CONFIG_SRCDIR([lib/File.h])
36AC_CONFIG_AUX_DIR([autotools])
37dnl arg below should be the same as in Makefile.am
38AC_CONFIG_MACRO_DIR([build_support])
39AC_PREFIX_DEFAULT([/usr/local])
40test $prefix = NONE && prefix=/usr/local
41
42AC_SUBST([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION])
43AC_SUBST([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION])
44AC_SUBST([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION])
45
46AC_DEFINE([DEV_BUILD],[SVNDIGEST_DEV_BUILD],
47          [true if dev build (version ends with pre)])
48AC_DEFINE([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION],
49                    [Define to the svndigest major version])
50AC_DEFINE([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION],
51                    [Define to the svndigest minor version])
52AC_DEFINE([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION],
53                    [Define to the svndigest patch version])
54
55AC_CONFIG_HEADER([config.h])
56AM_INIT_AUTOMAKE([1.10 std-options check-news])
57
58# Set default programming language
59AC_LANG(C++)
60
61# Let user overide default CXXFLAGS
62if test "${CXXFLAGS+set}" != set; then
63  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
64fi
65
66# Checks for programs.
67AC_PROG_CXXCPP
68AC_PROG_CXX
69AC_PROG_INSTALL
70AC_PROG_RANLIB
71AC_PROG_SED
72AC_PATH_PROG([HELP2MAN], [help2man], [no])
73AM_CONDITIONAL([HAVE_HELP2MAN], [test x$help2man != xno])
74AC_CHECK_PROG([GNUPLOT],[gnuplot],[ok])
75
76# Save FLAGS
77SAVE_CPPFLAGS="$CPPFLAGS"
78SAVE_CXXFLAGS="$CXXFLAGS"
79SAVE_LDFLAGS="$LDFLAGS"
80SAVE_LIBS="$LIBS"
81
82# -Wno-long-long is needed to suppress compiler diagnostics regarding
83# using extension beyond the C++ standard (usage of non C++ standard
84# 'long long' types).
85SD_CXXFLAGS="$SD_CXXFLAGS-Wall -pedantic -Wno-long-long"
86AC_TYPE_LONG_LONG_INT()
87
88AC_ARG_ENABLE(debug,
89  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])],
90  [SD_CXXFLAGS="$SD_CXXFLAGS -g -O"],
91  [SD_CPPFLAGS="-DNDEBUG" SD_CXXFLAGS="$SD_CXXFLAGS -O3"])
92
93# Apache Portable Runtime (APR) API checks
94# The next three lines are not needed as long as APR_FIND_APR is used.
95# AC_ARG_WITH(apr,
96#  [  --with-apr=DIR          prefix for installed APR or path to APR build
97#                          tree [[PREFIX]]])
98# Include APR_FIND_APR macro distributed within the APR project. If
99# the usage of the APR macro is to be omitted then the construct for
100# setting the CXXFLAGS (header file location) and LDFLAGS (linking
101# informaion) for APR must be changed. The latter can be achieved with
102# AC_SEARCH_LIBS([apr_allocator_create],[apr-0],,apr_found="no") but
103# apr-0 must be prior knowledge.
104APR_FIND_APR(,,1,[1 0])
105if test "$apr_found" = "yes" ; then
106    SD_LIBS="`$apr_config --libs` $SD_LIBS"
107    SD_LDFLAGS="`$apr_config --link-ld` $SD_LDFLAGS"
108    SD_CPPFLAGS="`$apr_config --includes --cppflags` $SD_CPPFLAGS"
109fi
110
111# Subversion API checks
112svn_found="yes"
113AC_ARG_WITH(svn,
114  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
115  [ SD_LDFLAGS="-L$withval/lib $SD_LDFLAGS"
116    SD_CPPFLAGS="-I$withval/include $SD_CPPFLAGS"])
117
118
119# Use SD_*FLAGS in tests
120CPPFLAGS="$SD_CPPFLAGS $CPPFLAGS"
121CXXFLAGS="$SD_CXXFLAGS $CXXFLAGS"
122LDFLAGS="$SD_LDFLAGS $LDFLAGS"
123LIBS="$SD_LIBS $LIBS"
124
125AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
126AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
127AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],
128               [SD_LIBS="-lsvn_subr-1 $SD_LIBS"],svn_found="no")
129AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],
130               [SD_LIBS="-lsvn_ra-1 $SD_LIBS"],svn_found="no")
131AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],
132               [SD_LIBS="-lsvn_wc-1 $SD_LIBS"],svn_found="no")
133AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],
134               [SD_LIBS="-lsvn_diff-1 $SD_LIBS"],svn_found="no")
135AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],
136               [SD_LIBS="-lsvn_client-1 $SD_LIBS"],svn_found="no")
137
138# Export flags
139AC_SUBST([SVNDIGEST_CPPFLAGS], $SD_CPPFLAGS)
140AC_SUBST([SVNDIGEST_CXXFLAGS], $SD_CXXFLAGS)
141AC_SUBST([SVNDIGEST_LDFLAGS], $SD_LDFLAGS)
142AC_SUBST([SVNDIGEST_LIBS], $SD_LIBS)
143
144# Reset FLAGS
145CPPFLAGS="$SAVE_CPPFLAGS"
146CXXFLAGS="$SAVE_CXXFLAGS"
147LDFLAGS="$SAVE_LDFLAGS"
148LIBS="$SAVE_LIBS"
149
150# check if svnversion is installed
151AC_PATH_PROG([SVNVERSION], [svnversion], [no])
152
153# checking if we build in a subversion WC
154AC_CHECK_FILE([$srcdir/.svn], [wc_found="yes"], [wc_found="no"])
155AM_CONDITIONAL([HAVE_SVN_WC], [test "$wc_found" = "yes"])
156AC_SUBST([wc_found])
157
158# checking if we have test repo
159test_repo_filename=$srcdir/test/repo;
160AC_CHECK_FILE([$test_repo_filename], [test_repo_found="yes"],
161              [test_repo_found="no"])
162AM_CONDITIONAL([HAVE_TEST_REPO], [test "$test_repo_found" = "yes"])
163if (test "$test_repo_found" = "yes"); then
164   dnl test repo is not distributed
165   AC_CONFIG_FILES([test/test_repo.sh], [chmod +x test/test_repo.sh])
166   AC_CONFIG_FILES([test/check_repo_status.sh],
167                   [chmod +x test/check_repo_status.sh])   
168fi
169
170
171AC_CONFIG_FILES([Makefile
172                bin/Makefile
173                lib/Makefile
174                man/Makefile
175                test/environment.h
176                test/Makefile])
177
178# Print failure status information about selected items, and exit if
179# fatal errors were encountered. No output will be created if
180# configure is halted prematurely.
181
182# used to trigger exit before creation of output
183all_reqs_ok="true"
184
185if (test "$wc_found" = "yes"); then
186   if test x$help2man = xno; then
187     AC_MSG_WARN(m4_text_wrap(m4_normalize([
188       `help2man' is missing on your system.  You will not be
189       able to create the man page. A sound man page should be
190       included in a distribution, and since you will not able
191       to create a complete distribution `make dist' will fail.
192       ]),[                   ],
193          [                             ], 79))
194   fi
195   # svnversion is required when building from svn wc
196   if (test "$svnversion" = "no"); then
197      all_reqs_ok="false";
198      AC_MSG_WARN([dnl
199Cannot find svnversion, which is required when building from a
200subversion working copy. Please install svnversion and make sure it is
201in your search path.]);
202   fi
203   if (test "$test_repo_found" = "no"); then
204      all_reqs_ok="false";
205      AC_MSG_WARN([dnl
206Cannot find test repository (test_repo_filename), which should be
207available when building from a subversion working copy. Try svn
208update in top directory.]);
209   fi
210fi
211
212# Non-existing APR is fatal -- sub-sequent compilation will fail.
213if (test "$apr_found" = "no") ; then
214  AC_MSG_WARN([APR not found. The Apache Portable Runtime
215  (APR) library cannot be found. Please make sure APR is installed
216  and supply the appropriate --with-apr option to 'configure'.])
217  all_reqs_ok="false"
218fi
219
220# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
221if (test "$svn_found" = "no") ; then
222  svn_msg="Subversion API not found. Subversion API libraries cannot
223  be found. Make sure the APIs are installed and supply the
224  appropriate --with-svn option to 'configure'."
225  if (test "$apr_found" = "no") ; then
226    svn_msg="$svn_msg
227    Note, APR was not found. Failure to locate APR affects the search
228    of the subversion API. Please fix the APR problem before trying
229    to resolve the subversion related issues."
230  fi
231  AC_MSG_WARN([$svn_msg])
232  all_reqs_ok="false"
233fi
234
235if test $ac_cv_type_long_long_int != yes ; then
236  AC_MSG_WARN([Compiler $CXX does not support `long long'.
237  svndigest must be compiled with a compiler that supports `long long'.])
238  all_reqs_ok="false"
239fi
240
241if (test "$all_reqs_ok" = "false") ; then
242  AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
243  configure. Please consult the 'README' file for more information
244  about what is needed to compile svndigest and refer to above
245  warning messages. Needed files were NOT created.])
246fi
247
248# Create output.
249AC_OUTPUT
250
251# Some more messages.
252AC_MSG_NOTICE([])
253AC_MSG_NOTICE([   Ready to compile the executables of svndigest $VERSION])
254AC_MSG_NOTICE([   The following flags and libs will be used:])
255AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
256AC_MSG_NOTICE([    Compiler:           $CXX])
257AC_MSG_NOTICE([    Preprocessor flags: $SD_CPPFLAGS $CPPFLAGS])
258AC_MSG_NOTICE([    C++ flags:          $SD_CXXFLAGS $CXXFLAGS])
259AC_MSG_NOTICE([    Linker flags:       $SD_LDFLAGS $LDFLAGS])
260AC_MSG_NOTICE([    LIBS:               $SD_LIBS $LIBS])
261AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
262AC_MSG_NOTICE([])
263
264# Failure to locate gnuplot is not considered fatal
265if (test "$GNUPLOT" != "ok") ; then
266  AC_MSG_WARN([Gnuplot was not found. svndigest will compile
267  without gnuplot but will throw an exception at run-time. Please
268  install gnuplot (available for a wide range of operating systems
269  at http://www.gnuplot.info).])
270  AC_MSG_NOTICE([])
271fi
272
273AC_MSG_NOTICE([Now type 'make ; make check'.])
Note: See TracBrowser for help on using the repository browser.