source: trunk/configure.ac @ 742

Last change on this file since 742 was 742, checked in by Peter Johansson, 13 years ago

corrected typo

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 10.0 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 742 2008-12-19 22:48:47Z peter $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson
15#
16# This file is part of svndigest, http://dev.thep.lu.se/svndigest
17#
18# svndigest is free software; you can redistribute it and/or modify it
19# under the terms of the GNU General Public License as published by
20# the Free Software Foundation; either version 3 of the License, or
21# (at your option) any later version.
22#
23# svndigest is distributed in the hope that it will be useful, but
24# WITHOUT ANY WARRANTY; without even the implied warranty of
25# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
26# General Public License for more details.
27#
28# You should have received a copy of the GNU General Public License
29# along with svndigest. If not, see <http://www.gnu.org/licenses/>.
30
31AC_PREREQ(2.60)
32
33m4_include([build_support/version.m4])
34AC_INIT([svndigest],[SVNDIGEST_VERSION],[jari@thep.lu.se])
35AC_CONFIG_SRCDIR([lib/File.h])
36AC_CONFIG_AUX_DIR([autotools])
37dnl arg below should be the same as in Makefile.am
38AC_CONFIG_MACRO_DIR([build_support])
39AC_PREFIX_DEFAULT([/usr/local])
40test $prefix = NONE && prefix=/usr/local
41
42AC_SUBST([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION])
43AC_SUBST([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION])
44AC_SUBST([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION])
45
46AC_DEFINE([DEV_BUILD],[SVNDIGEST_DEV_BUILD],
47          [true if dev build (version ends with pre)])
48AC_DEFINE([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION],
49                    [Define to the svndigest major version])
50AC_DEFINE([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION],
51                    [Define to the svndigest minor version])
52AC_DEFINE([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION],
53                    [Define to the svndigest patch version])
54
55AC_CONFIG_HEADER([config.h])
56AM_INIT_AUTOMAKE([1.10 std-options check-news])
57
58# Set default programming language
59AC_LANG(C++)
60
61# propagate selected configure variables to DISTCHECK_CONFIGURE_FLAGS
62for var in CPPFLAGS CXX CXXFLAGS CXXCPP LDFLAGS LIBS; do
63  eval isset=\${$var+set}
64  if test "$isset" = 'set' ; then
65    eval val=$`echo $var`
66    DISTCHECK_CONFIGURE_FLAGS="${DISTCHECK_CONFIGURE_FLAGS}'${var}=${val}' "
67  fi
68done
69AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
70
71# Let user overide default CXXFLAGS
72if test "${CXXFLAGS+set}" != set; then
73  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
74fi
75
76# Checks for programs.
77AC_PROG_CXXCPP
78AC_PROG_CXX
79AC_PROG_INSTALL
80AC_PROG_RANLIB
81AC_PROG_SED
82AC_PATH_PROG([HELP2MAN], [help2man], [no])
83AM_CONDITIONAL([HAVE_HELP2MAN], [test x$HELP2MAN != xno])
84AC_CHECK_PROG([GNUPLOT],[gnuplot],[ok])
85
86# Save FLAGS
87SAVE_CPPFLAGS="$CPPFLAGS"
88SAVE_CXXFLAGS="$CXXFLAGS"
89SAVE_LDFLAGS="$LDFLAGS"
90SAVE_LIBS="$LIBS"
91
92# -Wno-long-long is needed to suppress compiler diagnostics regarding
93# using extension beyond the C++ standard (usage of non C++ standard
94# 'long long' types).
95SD_CXXFLAGS="$SD_CXXFLAGS-Wall -pedantic -Wno-long-long"
96AC_TYPE_LONG_LONG_INT()
97
98AC_ARG_ENABLE(debug,
99  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])],
100  [SD_CXXFLAGS="$SD_CXXFLAGS -g -O"],
101  [SD_CPPFLAGS="-DNDEBUG" SD_CXXFLAGS="$SD_CXXFLAGS -O3"])
102
103# Apache Portable Runtime (APR) API checks
104# The next three lines are not needed as long as APR_FIND_APR is used.
105# AC_ARG_WITH(apr,
106#  [  --with-apr=DIR          prefix for installed APR or path to APR build
107#                          tree [[PREFIX]]])
108# Include APR_FIND_APR macro distributed within the APR project. If
109# the usage of the APR macro is to be omitted then the construct for
110# setting the CXXFLAGS (header file location) and LDFLAGS (linking
111# informaion) for APR must be changed. The latter can be achieved with
112# AC_SEARCH_LIBS([apr_allocator_create],[apr-0],,apr_found="no") but
113# apr-0 must be prior knowledge.
114APR_FIND_APR(,,1,[1 0])
115if test "$apr_found" = "yes" ; then
116    SD_LIBS="`$apr_config --libs` $SD_LIBS"
117    SD_LDFLAGS="`$apr_config --link-ld` $SD_LDFLAGS"
118    SD_CPPFLAGS="`$apr_config --includes --cppflags` $SD_CPPFLAGS"
119fi
120
121# Subversion API checks
122svn_found="yes"
123AC_ARG_WITH(svn,
124  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
125  [ SD_LDFLAGS="-L$withval/lib $SD_LDFLAGS"
126    SD_CPPFLAGS="-I$withval/include $SD_CPPFLAGS"])
127
128
129# Use SD_*FLAGS in tests
130CPPFLAGS="$SD_CPPFLAGS $CPPFLAGS"
131CXXFLAGS="$SD_CXXFLAGS $CXXFLAGS"
132LDFLAGS="$SD_LDFLAGS $LDFLAGS"
133LIBS="$SD_LIBS $LIBS"
134
135AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
136AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
137AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],
138               [SD_LIBS="-lsvn_subr-1 $SD_LIBS"],svn_found="no")
139AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],
140               [SD_LIBS="-lsvn_ra-1 $SD_LIBS"],svn_found="no")
141AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],
142               [SD_LIBS="-lsvn_wc-1 $SD_LIBS"],svn_found="no")
143AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],
144               [SD_LIBS="-lsvn_diff-1 $SD_LIBS"],svn_found="no")
145AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],
146               [SD_LIBS="-lsvn_client-1 $SD_LIBS"],svn_found="no")
147
148# Export flags
149AC_SUBST([SVNDIGEST_CPPFLAGS], $SD_CPPFLAGS)
150AC_SUBST([SVNDIGEST_CXXFLAGS], $SD_CXXFLAGS)
151AC_SUBST([SVNDIGEST_LDFLAGS], $SD_LDFLAGS)
152AC_SUBST([SVNDIGEST_LIBS], $SD_LIBS)
153
154# Reset FLAGS
155CPPFLAGS="$SAVE_CPPFLAGS"
156CXXFLAGS="$SAVE_CXXFLAGS"
157LDFLAGS="$SAVE_LDFLAGS"
158LIBS="$SAVE_LIBS"
159
160# check if svnversion is installed
161AC_PATH_PROG([SVNVERSION], [svnversion], [no])
162
163# checking if we build in a subversion WC
164AC_CHECK_FILE([$srcdir/.svn], [wc_found="yes"], [wc_found="no"])
165AM_CONDITIONAL([HAVE_SVN_WC], [test "$wc_found" = "yes"])
166AC_SUBST([wc_found])
167
168# checking if we have test repo
169test_repo_filename=$srcdir/test/repo;
170AC_CHECK_FILE([$test_repo_filename], [test_repo_found="yes"],
171              [test_repo_found="no"])
172AM_CONDITIONAL([HAVE_TEST_REPO], [test "$test_repo_found" = "yes"])
173if (test "$test_repo_found" = "yes"); then
174   dnl test repo is not distributed
175   AC_CONFIG_FILES([test/test_repo.sh], [chmod +x test/test_repo.sh])
176   AC_CONFIG_FILES([test/check_repo_status.sh],
177                   [chmod +x test/check_repo_status.sh])   
178fi
179
180
181AC_CONFIG_FILES([Makefile
182                bin/Makefile
183                lib/Makefile
184                man/Makefile
185                test/environment.h
186                test/Makefile])
187
188# Print failure status information about selected items, and exit if
189# fatal errors were encountered. No output will be created if
190# configure is halted prematurely.
191
192# used to trigger exit before creation of output
193all_reqs_ok="true"
194
195if (test "$wc_found" = "yes"); then
196   if test x$HELP2MAN = xno; then
197     AC_MSG_WARN(m4_text_wrap(m4_normalize([
198       `help2man' is missing on your system.  You will not be
199       able to create the man page. A sound man page should be
200       included in a distribution, and since you will not able
201       to create a complete distribution `make dist' will fail.
202       ]),[                   ],
203          [                             ], 79))
204   fi
205   # svnversion is required when building from svn wc
206   if (test "$svnversion" = "no"); then
207      all_reqs_ok="false";
208      AC_MSG_WARN([dnl
209Cannot find svnversion, which is required when building from a
210subversion working copy. Please install svnversion and make sure it is
211in your search path.]);
212   fi
213   if (test "$test_repo_found" = "no"); then
214      all_reqs_ok="false";
215      AC_MSG_WARN([dnl
216Cannot find test repository (test_repo_filename), which should be
217available when building from a subversion working copy. Try svn
218update in top directory.]);
219   fi
220fi
221
222# Non-existing APR is fatal -- sub-sequent compilation will fail.
223if (test "$apr_found" = "no") ; then
224  AC_MSG_WARN([APR not found. The Apache Portable Runtime
225  (APR) library cannot be found. Please make sure APR is installed
226  and supply the appropriate --with-apr option to 'configure'.])
227  all_reqs_ok="false"
228fi
229
230# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
231if (test "$svn_found" = "no") ; then
232  svn_msg="Subversion API not found. Subversion API libraries cannot
233  be found. Make sure the APIs are installed and supply the
234  appropriate --with-svn option to 'configure'."
235  if (test "$apr_found" = "no") ; then
236    svn_msg="$svn_msg
237    Note, APR was not found. Failure to locate APR affects the search
238    of the subversion API. Please fix the APR problem before trying
239    to resolve the subversion related issues."
240  fi
241  AC_MSG_WARN([$svn_msg])
242  all_reqs_ok="false"
243fi
244
245if test $ac_cv_type_long_long_int != yes ; then
246  AC_MSG_WARN([Compiler $CXX does not support `long long'.
247  svndigest must be compiled with a compiler that supports `long long'.])
248  all_reqs_ok="false"
249fi
250
251if (test "$all_reqs_ok" = "false") ; then
252  AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
253  configure. Please consult the 'README' file for more information
254  about what is needed to compile svndigest and refer to above
255  warning messages. Needed files were NOT created.])
256fi
257
258# Create output.
259AC_OUTPUT
260
261# Some more messages.
262AC_MSG_NOTICE([])
263AC_MSG_NOTICE([   Ready to compile the executables of svndigest $VERSION])
264AC_MSG_NOTICE([   The following flags and libs will be used:])
265AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
266AC_MSG_NOTICE([    Compiler:           $CXX])
267AC_MSG_NOTICE([    Preprocessor flags: $SD_CPPFLAGS $CPPFLAGS])
268AC_MSG_NOTICE([    C++ flags:          $SD_CXXFLAGS $CXXFLAGS])
269AC_MSG_NOTICE([    Linker flags:       $SD_LDFLAGS $LDFLAGS])
270AC_MSG_NOTICE([    LIBS:               $SD_LIBS $LIBS])
271AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
272AC_MSG_NOTICE([])
273
274# Failure to locate gnuplot is not considered fatal
275if (test "$GNUPLOT" != "ok") ; then
276  AC_MSG_WARN([Gnuplot was not found. svndigest will compile
277  without gnuplot but will throw an exception at run-time. Please
278  install gnuplot (available for a wide range of operating systems
279  at http://www.gnuplot.info).])
280  AC_MSG_NOTICE([])
281fi
282
283AC_MSG_NOTICE([Now type 'make ; make check'.])
Note: See TracBrowser for help on using the repository browser.