source: trunk/configure.ac @ 743

Last change on this file since 743 was 743, checked in by Peter Johansson, 13 years ago

removed usage of envar HOME in Gnuplot.cc

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 10.2 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 743 2008-12-19 23:04:54Z peter $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson
15#
16# This file is part of svndigest, http://dev.thep.lu.se/svndigest
17#
18# svndigest is free software; you can redistribute it and/or modify it
19# under the terms of the GNU General Public License as published by
20# the Free Software Foundation; either version 3 of the License, or
21# (at your option) any later version.
22#
23# svndigest is distributed in the hope that it will be useful, but
24# WITHOUT ANY WARRANTY; without even the implied warranty of
25# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
26# General Public License for more details.
27#
28# You should have received a copy of the GNU General Public License
29# along with svndigest. If not, see <http://www.gnu.org/licenses/>.
30
31AC_PREREQ(2.60)
32
33m4_include([build_support/version.m4])
34AC_INIT([svndigest],[SVNDIGEST_VERSION],[jari@thep.lu.se])
35AC_CONFIG_SRCDIR([lib/File.h])
36AC_CONFIG_AUX_DIR([autotools])
37dnl arg below should be the same as in Makefile.am
38AC_CONFIG_MACRO_DIR([build_support])
39AC_PREFIX_DEFAULT([/usr/local])
40test $prefix = NONE && prefix=/usr/local
41
42AC_SUBST([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION])
43AC_SUBST([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION])
44AC_SUBST([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION])
45
46AC_DEFINE([DEV_BUILD],[SVNDIGEST_DEV_BUILD],
47          [true if dev build (version ends with pre)])
48AC_DEFINE([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION],
49                    [Define to the svndigest major version])
50AC_DEFINE([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION],
51                    [Define to the svndigest minor version])
52AC_DEFINE([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION],
53                    [Define to the svndigest patch version])
54
55AC_CONFIG_HEADER([config.h])
56AM_INIT_AUTOMAKE([1.10 std-options check-news])
57
58# Set default programming language
59AC_LANG(C++)
60
61# propagate selected configure variables to DISTCHECK_CONFIGURE_FLAGS
62for var in CPPFLAGS CXX CXXFLAGS CXXCPP LDFLAGS LIBS; do
63  eval isset=\${$var+set}
64  if test "$isset" = 'set' ; then
65    eval val=$`echo $var`
66    DISTCHECK_CONFIGURE_FLAGS="${DISTCHECK_CONFIGURE_FLAGS}'${var}=${val}' "
67  fi
68done
69AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
70
71# Let user overide default CXXFLAGS
72if test "${CXXFLAGS+set}" != set; then
73  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
74fi
75
76# Checks for programs.
77AC_PROG_CXXCPP
78AC_PROG_CXX
79AC_PROG_INSTALL
80AC_PROG_RANLIB
81AC_PROG_SED
82AC_PATH_PROG([HELP2MAN], [help2man], [no])
83AM_CONDITIONAL([HAVE_HELP2MAN], [test x$HELP2MAN != xno])
84AC_PATH_PROG([GNUPLOT],[gnuplot],[no])
85AC_DEFINE_UNQUOTED([GNUPLOT_PATH], ["$GNUPLOT"],
86                   [defined to gnuplot path (or no if gnuplot was not found)])
87
88# Save FLAGS
89SAVE_CPPFLAGS="$CPPFLAGS"
90SAVE_CXXFLAGS="$CXXFLAGS"
91SAVE_LDFLAGS="$LDFLAGS"
92SAVE_LIBS="$LIBS"
93
94# -Wno-long-long is needed to suppress compiler diagnostics regarding
95# using extension beyond the C++ standard (usage of non C++ standard
96# 'long long' types).
97SD_CXXFLAGS="$SD_CXXFLAGS-Wall -pedantic -Wno-long-long"
98AC_TYPE_LONG_LONG_INT()
99
100AC_ARG_ENABLE(debug,
101  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])],
102  [SD_CXXFLAGS="$SD_CXXFLAGS -g -O"],
103  [SD_CPPFLAGS="-DNDEBUG" SD_CXXFLAGS="$SD_CXXFLAGS -O3"])
104
105# Apache Portable Runtime (APR) API checks
106# The next three lines are not needed as long as APR_FIND_APR is used.
107# AC_ARG_WITH(apr,
108#  [  --with-apr=DIR          prefix for installed APR or path to APR build
109#                          tree [[PREFIX]]])
110# Include APR_FIND_APR macro distributed within the APR project. If
111# the usage of the APR macro is to be omitted then the construct for
112# setting the CXXFLAGS (header file location) and LDFLAGS (linking
113# informaion) for APR must be changed. The latter can be achieved with
114# AC_SEARCH_LIBS([apr_allocator_create],[apr-0],,apr_found="no") but
115# apr-0 must be prior knowledge.
116APR_FIND_APR(,,1,[1 0])
117if test "$apr_found" = "yes" ; then
118    SD_LIBS="`$apr_config --libs` $SD_LIBS"
119    SD_LDFLAGS="`$apr_config --link-ld` $SD_LDFLAGS"
120    SD_CPPFLAGS="`$apr_config --includes --cppflags` $SD_CPPFLAGS"
121fi
122
123# Subversion API checks
124svn_found="yes"
125AC_ARG_WITH(svn,
126  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
127  [ SD_LDFLAGS="-L$withval/lib $SD_LDFLAGS"
128    SD_CPPFLAGS="-I$withval/include $SD_CPPFLAGS"])
129
130
131# Use SD_*FLAGS in tests
132CPPFLAGS="$SD_CPPFLAGS $CPPFLAGS"
133CXXFLAGS="$SD_CXXFLAGS $CXXFLAGS"
134LDFLAGS="$SD_LDFLAGS $LDFLAGS"
135LIBS="$SD_LIBS $LIBS"
136
137AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
138AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
139AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],
140               [SD_LIBS="-lsvn_subr-1 $SD_LIBS"],svn_found="no")
141AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],
142               [SD_LIBS="-lsvn_ra-1 $SD_LIBS"],svn_found="no")
143AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],
144               [SD_LIBS="-lsvn_wc-1 $SD_LIBS"],svn_found="no")
145AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],
146               [SD_LIBS="-lsvn_diff-1 $SD_LIBS"],svn_found="no")
147AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],
148               [SD_LIBS="-lsvn_client-1 $SD_LIBS"],svn_found="no")
149
150# Export flags
151AC_SUBST([SVNDIGEST_CPPFLAGS], $SD_CPPFLAGS)
152AC_SUBST([SVNDIGEST_CXXFLAGS], $SD_CXXFLAGS)
153AC_SUBST([SVNDIGEST_LDFLAGS], $SD_LDFLAGS)
154AC_SUBST([SVNDIGEST_LIBS], $SD_LIBS)
155
156# Reset FLAGS
157CPPFLAGS="$SAVE_CPPFLAGS"
158CXXFLAGS="$SAVE_CXXFLAGS"
159LDFLAGS="$SAVE_LDFLAGS"
160LIBS="$SAVE_LIBS"
161
162# check if svnversion is installed
163AC_PATH_PROG([SVNVERSION], [svnversion], [no])
164
165# checking if we build in a subversion WC
166AC_CHECK_FILE([$srcdir/.svn], [wc_found="yes"], [wc_found="no"])
167AM_CONDITIONAL([HAVE_SVN_WC], [test "$wc_found" = "yes"])
168AC_SUBST([wc_found])
169
170# checking if we have test repo
171test_repo_filename=$srcdir/test/repo;
172AC_CHECK_FILE([$test_repo_filename], [test_repo_found="yes"],
173              [test_repo_found="no"])
174AM_CONDITIONAL([HAVE_TEST_REPO], [test "$test_repo_found" = "yes"])
175if (test "$test_repo_found" = "yes"); then
176   dnl test repo is not distributed
177   AC_CONFIG_FILES([test/test_repo.sh], [chmod +x test/test_repo.sh])
178   AC_CONFIG_FILES([test/check_repo_status.sh],
179                   [chmod +x test/check_repo_status.sh])   
180fi
181
182
183AC_CONFIG_FILES([Makefile
184                bin/Makefile
185                lib/Makefile
186                man/Makefile
187                test/environment.h
188                test/Makefile])
189
190# Print failure status information about selected items, and exit if
191# fatal errors were encountered. No output will be created if
192# configure is halted prematurely.
193
194# used to trigger exit before creation of output
195all_reqs_ok="true"
196
197if (test "$wc_found" = "yes"); then
198   if test x$HELP2MAN = xno; then
199     AC_MSG_WARN(m4_text_wrap(m4_normalize([
200       `help2man' is missing on your system.  You will not be
201       able to create the man page. A sound man page should be
202       included in a distribution, and since you will not able
203       to create a complete distribution `make dist' will fail.
204       ]),[                   ],
205          [                             ], 79))
206   fi
207   # svnversion is required when building from svn wc
208   if (test "$svnversion" = "no"); then
209      all_reqs_ok="false";
210      AC_MSG_WARN([dnl
211Cannot find svnversion, which is required when building from a
212subversion working copy. Please install svnversion and make sure it is
213in your search path.]);
214   fi
215   if (test "$test_repo_found" = "no"); then
216      all_reqs_ok="false";
217      AC_MSG_WARN([dnl
218Cannot find test repository (test_repo_filename), which should be
219available when building from a subversion working copy. Try svn
220update in top directory.]);
221   fi
222fi
223
224# Non-existing APR is fatal -- sub-sequent compilation will fail.
225if (test "$apr_found" = "no") ; then
226  AC_MSG_WARN([APR not found. The Apache Portable Runtime
227  (APR) library cannot be found. Please make sure APR is installed
228  and supply the appropriate --with-apr option to 'configure'.])
229  all_reqs_ok="false"
230fi
231
232# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
233if (test "$svn_found" = "no") ; then
234  svn_msg="Subversion API not found. Subversion API libraries cannot
235  be found. Make sure the APIs are installed and supply the
236  appropriate --with-svn option to 'configure'."
237  if (test "$apr_found" = "no") ; then
238    svn_msg="$svn_msg
239    Note, APR was not found. Failure to locate APR affects the search
240    of the subversion API. Please fix the APR problem before trying
241    to resolve the subversion related issues."
242  fi
243  AC_MSG_WARN([$svn_msg])
244  all_reqs_ok="false"
245fi
246
247if test $ac_cv_type_long_long_int != yes ; then
248  AC_MSG_WARN([Compiler $CXX does not support `long long'.
249  svndigest must be compiled with a compiler that supports `long long'.])
250  all_reqs_ok="false"
251fi
252
253if (test "$all_reqs_ok" = "false") ; then
254  AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
255  configure. Please consult the 'README' file for more information
256  about what is needed to compile svndigest and refer to above
257  warning messages. Needed files were NOT created.])
258fi
259
260# Create output.
261AC_OUTPUT
262
263# Some more messages.
264AC_MSG_NOTICE([])
265AC_MSG_NOTICE([   Ready to compile the executables of svndigest $VERSION])
266AC_MSG_NOTICE([   The following flags and libs will be used:])
267AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
268AC_MSG_NOTICE([    Compiler:           $CXX])
269AC_MSG_NOTICE([    Preprocessor flags: $SD_CPPFLAGS $CPPFLAGS])
270AC_MSG_NOTICE([    C++ flags:          $SD_CXXFLAGS $CXXFLAGS])
271AC_MSG_NOTICE([    Linker flags:       $SD_LDFLAGS $LDFLAGS])
272AC_MSG_NOTICE([    LIBS:               $SD_LIBS $LIBS])
273AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
274AC_MSG_NOTICE([])
275
276# Failure to locate gnuplot is not considered fatal
277if (test "x$GNUPLOT" = "xno") ; then
278  AC_MSG_WARN([Gnuplot was not found. svndigest will compile
279  without gnuplot but will throw an exception at run-time. Please
280  install gnuplot (available for a wide range of operating systems
281  at http://www.gnuplot.info).])
282  AC_MSG_NOTICE([])
283fi
284
285AC_MSG_NOTICE([Now type 'make ; make check'.])
Note: See TracBrowser for help on using the repository browser.