source: trunk/configure.ac @ 772

Last change on this file since 772 was 772, checked in by Peter Johansson, 13 years ago

fixes #379

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 10.2 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 772 2009-02-01 14:29:03Z peter $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson
15# Copyright (C) 2009 Peter Johansson
16#
17# This file is part of svndigest, http://dev.thep.lu.se/svndigest
18#
19# svndigest is free software; you can redistribute it and/or modify it
20# under the terms of the GNU General Public License as published by
21# the Free Software Foundation; either version 3 of the License, or
22# (at your option) any later version.
23#
24# svndigest is distributed in the hope that it will be useful, but
25# WITHOUT ANY WARRANTY; without even the implied warranty of
26# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
27# General Public License for more details.
28#
29# You should have received a copy of the GNU General Public License
30# along with svndigest. If not, see <http://www.gnu.org/licenses/>.
31
32AC_PREREQ(2.60)
33
34m4_include([build_support/version.m4])
35AC_INIT([svndigest],[SVNDIGEST_VERSION],[jari@thep.lu.se])
36AC_CONFIG_SRCDIR([lib/File.h])
37AC_CONFIG_AUX_DIR([autotools])
38dnl arg below should be the same as in Makefile.am
39AC_CONFIG_MACRO_DIR([build_support])
40AC_PREFIX_DEFAULT([/usr/local])
41test $prefix = NONE && prefix=/usr/local
42
43AC_SUBST([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION])
44AC_SUBST([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION])
45AC_SUBST([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION])
46
47AC_DEFINE([DEV_BUILD],[SVNDIGEST_DEV_BUILD],
48          [true if dev build (version ends with pre)])
49AC_DEFINE([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION],
50                    [Define to the svndigest major version])
51AC_DEFINE([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION],
52                    [Define to the svndigest minor version])
53AC_DEFINE([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION],
54                    [Define to the svndigest patch version])
55
56AC_CONFIG_HEADER([config.h])
57AM_INIT_AUTOMAKE([1.10 std-options check-news])
58
59# Set default programming language
60AC_LANG(C++)
61
62# propagate selected configure variables to DISTCHECK_CONFIGURE_FLAGS
63for var in CPPFLAGS CXX CXXFLAGS CXXCPP LDFLAGS LIBS; do
64  eval isset=\${$var+set}
65  if test "$isset" = 'set' ; then
66    eval val=$`echo $var`
67    DISTCHECK_CONFIGURE_FLAGS="${DISTCHECK_CONFIGURE_FLAGS}'${var}=${val}' "
68  fi
69done
70AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
71
72# Let user overide default CXXFLAGS
73if test "${CXXFLAGS+set}" != set; then
74  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
75fi
76
77# Checks for programs.
78AC_PROG_CXXCPP
79AC_PROG_CXX
80AC_PROG_INSTALL
81AC_PROG_RANLIB
82AC_PROG_SED
83AC_PATH_PROG([HELP2MAN], [help2man], [no])
84AM_CONDITIONAL([HAVE_HELP2MAN], [test x$HELP2MAN != xno])
85AC_PATH_PROG([GNUPLOT],[gnuplot],[no])
86AC_DEFINE_UNQUOTED([GNUPLOT_PATH], ["$GNUPLOT"],
87                   [defined to gnuplot path (or no if gnuplot was not found)])
88
89# Save FLAGS
90SAVE_CPPFLAGS="$CPPFLAGS"
91SAVE_CXXFLAGS="$CXXFLAGS"
92SAVE_LDFLAGS="$LDFLAGS"
93SAVE_LIBS="$LIBS"
94
95# -Wno-long-long is needed to suppress compiler diagnostics regarding
96# using extension beyond the C++ standard (usage of non C++ standard
97# 'long long' types).
98SD_CXXFLAGS="$SD_CXXFLAGS-Wall -pedantic -Wno-long-long"
99AC_TYPE_LONG_LONG_INT
100
101AC_ARG_ENABLE(debug,
102  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])],
103  [SD_CXXFLAGS="$SD_CXXFLAGS -g -O"],
104  [SD_CPPFLAGS="-DNDEBUG" SD_CXXFLAGS="$SD_CXXFLAGS -O3"])
105
106# enable svn-support
107AC_ARG_ENABLE([svn-support],
108   [AS_HELP_STRING([--enable-svn-support],
109                   [enable svn support - used by maintainer])],
110   [enable_svn_support=yes])
111AS_IF([test "x$enable_svn_support" = xyes],
112      [AC_CHECK_FILE([$srcdir/.svn],,
113                     [AC_MSG_ERROR([svn support cannot be enabled: `$srcdir' is not an svn wc.])])])
114AM_CONDITIONAL([ENABLE_SVN_SUPPORT], [test "x$enable_svn_support" = "xyes"])
115
116# Apache Portable Runtime (APR) API checks
117APR_FIND_APR(,,1,[1 0])
118if test "$apr_found" = "yes" ; then
119    SD_LIBS="`$apr_config --libs` $SD_LIBS"
120    SD_LDFLAGS="`$apr_config --link-ld` $SD_LDFLAGS"
121    SD_CPPFLAGS="`$apr_config --includes --cppflags` $SD_CPPFLAGS"
122fi
123
124# Subversion API checks
125svn_found="yes"
126AC_ARG_WITH(svn,
127  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
128  [ SD_LDFLAGS="-L$withval/lib $SD_LDFLAGS"
129    SD_CPPFLAGS="-I$withval/include $SD_CPPFLAGS"])
130
131
132# Use SD_*FLAGS in tests
133CPPFLAGS="$SD_CPPFLAGS $CPPFLAGS"
134CXXFLAGS="$SD_CXXFLAGS $CXXFLAGS"
135LDFLAGS="$SD_LDFLAGS $LDFLAGS"
136LIBS="$SD_LIBS $LIBS"
137
138AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
139AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
140AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],
141               [SD_LIBS="-lsvn_subr-1 $SD_LIBS"],svn_found="no")
142AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],
143               [SD_LIBS="-lsvn_ra-1 $SD_LIBS"],svn_found="no")
144AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],
145               [SD_LIBS="-lsvn_wc-1 $SD_LIBS"],svn_found="no")
146AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],
147               [SD_LIBS="-lsvn_diff-1 $SD_LIBS"],svn_found="no")
148AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],
149               [SD_LIBS="-lsvn_client-1 $SD_LIBS"],svn_found="no")
150
151# Export flags
152AC_SUBST([SVNDIGEST_CPPFLAGS], $SD_CPPFLAGS)
153AC_SUBST([SVNDIGEST_CXXFLAGS], $SD_CXXFLAGS)
154AC_SUBST([SVNDIGEST_LDFLAGS], $SD_LDFLAGS)
155AC_SUBST([SVNDIGEST_LIBS], $SD_LIBS)
156
157# Reset FLAGS
158CPPFLAGS="$SAVE_CPPFLAGS"
159CXXFLAGS="$SAVE_CXXFLAGS"
160LDFLAGS="$SAVE_LDFLAGS"
161LIBS="$SAVE_LIBS"
162
163# check if svnversion is installed
164AC_PATH_PROG([SVNVERSION], [svnversion], [no])
165
166# checking if we build in a subversion WC
167AC_CHECK_FILE([$srcdir/.svn], [wc_found="yes"], [wc_found="no"])
168AM_CONDITIONAL([HAVE_SVN_WC], [test "$wc_found" = "yes"])
169AC_SUBST([wc_found])
170
171# checking if we have test repo
172test_repo_filename=$srcdir/test/repo;
173AC_CHECK_FILE([$test_repo_filename],
174              [AC_DEFINE([HAVE_TEST_REPO],[1],[define if test repo is available])
175               test_repo_found="yes"],
176              [test_repo_found="no"])
177AC_SUBST([test_repo_found])
178AS_IF([test "x$test_repo_found" = xyes],
179      [abs_test_repo=`cd $test_repo_filename && pwd`;
180       AC_SUBST(abs_test_repo)]
181     )
182AC_CONFIG_FILES([test/test_repo.sh], [chmod +x test/test_repo.sh])
183AC_CONFIG_FILES([test/svn_update.sh], [chmod +x test/svn_update.sh])
184AC_CONFIG_FILES([test/check_repo_status.sh],
185                [chmod +x test/check_repo_status.sh])   
186
187
188AC_CONFIG_FILES([Makefile
189                bin/Makefile
190                lib/Makefile
191                man/Makefile
192                test/environment.h
193                test/Makefile])
194
195# Print failure status information about selected items, and exit if
196# fatal errors were encountered. No output will be created if
197# configure is halted prematurely.
198
199# used to trigger exit before creation of output
200all_reqs_ok="true"
201
202if (test "$wc_found" = "yes"); then
203   if test x$HELP2MAN = xno; then
204     AC_MSG_WARN(m4_text_wrap(m4_normalize([
205       `help2man' is missing on your system.  You will not be
206       able to create the man page. A sound man page should be
207       included in a distribution, and since you will not able
208       to create a complete distribution `make dist' will fail.
209       ]),[                   ],
210          [                             ], 79))
211   fi
212   # svnversion is required when building from svn wc
213   if (test "$svnversion" = "no"); then
214      all_reqs_ok="false";
215      AC_MSG_WARN([dnl
216Cannot find svnversion, which is required when building from a
217subversion working copy. Please install svnversion and make sure it is
218in your search path.]);
219   fi
220   if (test "$test_repo_found" = "no"); then
221      all_reqs_ok="false";
222      AC_MSG_WARN([dnl
223Cannot find test repository (test_repo_filename), which should be
224available when building from a subversion working copy. Try svn
225update in top directory.]);
226   fi
227fi
228
229# Non-existing APR is fatal -- sub-sequent compilation will fail.
230if (test "$apr_found" = "no") ; then
231  AC_MSG_WARN([APR not found. The Apache Portable Runtime
232  (APR) library cannot be found. Please make sure APR is installed
233  and supply the appropriate --with-apr option to 'configure'.])
234  all_reqs_ok="false"
235fi
236
237# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
238if (test "$svn_found" = "no") ; then
239  svn_msg="Subversion API not found. Subversion API libraries cannot
240  be found. Make sure the APIs are installed and supply the
241  appropriate --with-svn option to 'configure'."
242  if (test "$apr_found" = "no") ; then
243    svn_msg="$svn_msg
244    Note, APR was not found. Failure to locate APR affects the search
245    of the subversion API. Please fix the APR problem before trying
246    to resolve the subversion related issues."
247  fi
248  AC_MSG_WARN([$svn_msg])
249  all_reqs_ok="false"
250fi
251
252if test $ac_cv_type_long_long_int != yes ; then
253  AC_MSG_WARN([Compiler $CXX does not support `long long'.
254  svndigest must be compiled with a compiler that supports `long long'.])
255  all_reqs_ok="false"
256fi
257
258if (test "$all_reqs_ok" = "false") ; then
259  AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
260  configure. Please consult the 'README' file for more information
261  about what is needed to compile svndigest and refer to above
262  warning messages. Needed files were NOT created.])
263fi
264
265# Create output.
266AC_OUTPUT
267
268# Some more messages.
269AC_MSG_NOTICE([])
270AC_MSG_NOTICE([   Ready to compile the executables of svndigest $VERSION])
271AC_MSG_NOTICE([   The following flags and libs will be used:])
272AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
273AC_MSG_NOTICE([    Compiler:           $CXX])
274AC_MSG_NOTICE([    Preprocessor flags: $SD_CPPFLAGS $CPPFLAGS])
275AC_MSG_NOTICE([    C++ flags:          $SD_CXXFLAGS $CXXFLAGS])
276AC_MSG_NOTICE([    Linker flags:       $SD_LDFLAGS $LDFLAGS])
277AC_MSG_NOTICE([    LIBS:               $SD_LIBS $LIBS])
278AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
279AC_MSG_NOTICE([])
280
281# Failure to locate gnuplot is not considered fatal
282if (test "x$GNUPLOT" = "xno") ; then
283  AC_MSG_WARN([Gnuplot was not found. svndigest will compile
284  without gnuplot but will throw an exception at run-time. Please
285  install gnuplot (available for a wide range of operating systems
286  at http://www.gnuplot.info).])
287  AC_MSG_NOTICE([])
288fi
289
290AC_MSG_NOTICE([Now type 'make ; make check'.])
Note: See TracBrowser for help on using the repository browser.