source: trunk/configure.ac @ 773

Last change on this file since 773 was 773, checked in by Peter Johansson, 13 years ago

fixes #377

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 10.4 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 773 2009-02-01 16:02:39Z peter $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson
15# Copyright (C) 2009 Peter Johansson
16#
17# This file is part of svndigest, http://dev.thep.lu.se/svndigest
18#
19# svndigest is free software; you can redistribute it and/or modify it
20# under the terms of the GNU General Public License as published by
21# the Free Software Foundation; either version 3 of the License, or
22# (at your option) any later version.
23#
24# svndigest is distributed in the hope that it will be useful, but
25# WITHOUT ANY WARRANTY; without even the implied warranty of
26# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
27# General Public License for more details.
28#
29# You should have received a copy of the GNU General Public License
30# along with svndigest. If not, see <http://www.gnu.org/licenses/>.
31
32AC_PREREQ(2.60)
33
34m4_include([build_support/version.m4])
35AC_INIT([svndigest],[SVNDIGEST_VERSION],[jari@thep.lu.se])
36AC_CONFIG_SRCDIR([lib/File.h])
37AC_CONFIG_AUX_DIR([autotools])
38dnl arg below should be the same as in Makefile.am
39AC_CONFIG_MACRO_DIR([build_support])
40AC_PREFIX_DEFAULT([/usr/local])
41test $prefix = NONE && prefix=/usr/local
42
43AC_SUBST([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION])
44AC_SUBST([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION])
45AC_SUBST([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION])
46
47AC_DEFINE([DEV_BUILD],[SVNDIGEST_DEV_BUILD],
48          [true if dev build (version ends with pre)])
49AC_DEFINE([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION],
50                    [Define to the svndigest major version])
51AC_DEFINE([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION],
52                    [Define to the svndigest minor version])
53AC_DEFINE([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION],
54                    [Define to the svndigest patch version])
55
56AC_CONFIG_HEADER([config.h])
57AM_INIT_AUTOMAKE([1.10 std-options check-news])
58
59# Set default programming language
60AC_LANG(C++)
61
62# propagate selected configure variables to DISTCHECK_CONFIGURE_FLAGS
63for var in CPPFLAGS CXX CXXFLAGS CXXCPP LDFLAGS LIBS; do
64  eval isset=\${$var+set}
65  if test "$isset" = 'set' ; then
66    eval val=$`echo $var`
67    DISTCHECK_CONFIGURE_FLAGS="${DISTCHECK_CONFIGURE_FLAGS}'${var}=${val}' "
68  fi
69done
70AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
71
72# Let user overide default CXXFLAGS
73if test "${CXXFLAGS+set}" != set; then
74  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
75fi
76
77# Checks for programs.
78AC_PROG_CXXCPP
79AC_PROG_CXX
80AC_PROG_INSTALL
81AC_PROG_RANLIB
82AC_PROG_SED
83AC_PATH_PROG([HELP2MAN], [help2man], [no])
84AM_CONDITIONAL([HAVE_HELP2MAN], [test x$HELP2MAN != xno])
85AC_PATH_PROG([GNUPLOT],[gnuplot],[no])
86AC_DEFINE_UNQUOTED([GNUPLOT_PATH], ["$GNUPLOT"],
87                   [defined to gnuplot path (or no if gnuplot was not found)])
88
89# Save FLAGS
90SAVE_CPPFLAGS="$CPPFLAGS"
91SAVE_CXXFLAGS="$CXXFLAGS"
92SAVE_LDFLAGS="$LDFLAGS"
93SAVE_LIBS="$LIBS"
94
95# -Wno-long-long is needed to suppress compiler diagnostics regarding
96# using extension beyond the C++ standard (usage of non C++ standard
97# 'long long' types).
98SD_CXXFLAGS="$SD_CXXFLAGS-Wall -pedantic -Wno-long-long"
99AC_TYPE_LONG_LONG_INT
100
101AC_ARG_ENABLE(debug,
102  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])],
103  [SD_CXXFLAGS="$SD_CXXFLAGS -g -O"],
104  [SD_CPPFLAGS="-DNDEBUG" SD_CXXFLAGS="$SD_CXXFLAGS -O3"])
105
106# enable svn-support
107AC_ARG_ENABLE([svn-support],
108   [AS_HELP_STRING([--enable-svn-support],
109                   [enable svn support - used by maintainer])],
110   [enable_svn_support=yes])
111AS_IF([test "x$enable_svn_support" = xyes],
112      [AC_CHECK_FILE([$srcdir/.svn],,
113                     [AC_MSG_ERROR([svn support cannot be enabled: `$srcdir' is not an svn wc.])])])
114AM_CONDITIONAL([ENABLE_SVN_SUPPORT], [test "x$enable_svn_support" = "xyes"])
115
116# Apache Portable Runtime (APR) API checks
117APR_FIND_APR(,,1,[1 0])
118AS_IF([test "${with_apr+set}" = set],
119    [DISTCHECK_CONFIGURE_FLAGS="$DISTCHECK_CONFIGURE_FLAGS --with-apr=$with_apr"]
120)
121if test "$apr_found" = "yes" ; then
122    SD_LIBS="`$apr_config --libs` $SD_LIBS"
123    SD_LDFLAGS="`$apr_config --link-ld` $SD_LDFLAGS"
124    SD_CPPFLAGS="`$apr_config --includes --cppflags` $SD_CPPFLAGS"
125fi
126
127# Subversion API checks
128svn_found="yes"
129AC_ARG_WITH(svn,
130  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
131  [ DISTCHECK_CONFIGURE_FLAGS="$DISTCHECK_CONFIGURE_FLAGS --with-svn=$withval"
132    SD_LDFLAGS="-L$withval/lib $SD_LDFLAGS"
133    SD_CPPFLAGS="-I$withval/include $SD_CPPFLAGS"])
134
135
136# Use SD_*FLAGS in tests
137CPPFLAGS="$SD_CPPFLAGS $CPPFLAGS"
138CXXFLAGS="$SD_CXXFLAGS $CXXFLAGS"
139LDFLAGS="$SD_LDFLAGS $LDFLAGS"
140LIBS="$SD_LIBS $LIBS"
141
142AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
143AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
144AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],
145               [SD_LIBS="-lsvn_subr-1 $SD_LIBS"],svn_found="no")
146AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],
147               [SD_LIBS="-lsvn_ra-1 $SD_LIBS"],svn_found="no")
148AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],
149               [SD_LIBS="-lsvn_wc-1 $SD_LIBS"],svn_found="no")
150AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],
151               [SD_LIBS="-lsvn_diff-1 $SD_LIBS"],svn_found="no")
152AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],
153               [SD_LIBS="-lsvn_client-1 $SD_LIBS"],svn_found="no")
154
155# Export flags
156AC_SUBST([SVNDIGEST_CPPFLAGS], $SD_CPPFLAGS)
157AC_SUBST([SVNDIGEST_CXXFLAGS], $SD_CXXFLAGS)
158AC_SUBST([SVNDIGEST_LDFLAGS], $SD_LDFLAGS)
159AC_SUBST([SVNDIGEST_LIBS], $SD_LIBS)
160
161# Reset FLAGS
162CPPFLAGS="$SAVE_CPPFLAGS"
163CXXFLAGS="$SAVE_CXXFLAGS"
164LDFLAGS="$SAVE_LDFLAGS"
165LIBS="$SAVE_LIBS"
166
167# check if svnversion is installed
168AC_PATH_PROG([SVNVERSION], [svnversion], [no])
169
170# checking if we build in a subversion WC
171AC_CHECK_FILE([$srcdir/.svn], [wc_found="yes"], [wc_found="no"])
172AM_CONDITIONAL([HAVE_SVN_WC], [test "$wc_found" = "yes"])
173AC_SUBST([wc_found])
174
175# checking if we have test repo
176test_repo_filename=$srcdir/test/repo;
177AC_CHECK_FILE([$test_repo_filename],
178              [AC_DEFINE([HAVE_TEST_REPO],[1],[define if test repo is available])
179               test_repo_found="yes"],
180              [test_repo_found="no"])
181AC_SUBST([test_repo_found])
182AS_IF([test "x$test_repo_found" = xyes],
183      [abs_test_repo=`cd $test_repo_filename && pwd`;
184       AC_SUBST(abs_test_repo)]
185     )
186AC_CONFIG_FILES([test/test_repo.sh], [chmod +x test/test_repo.sh])
187AC_CONFIG_FILES([test/svn_update.sh], [chmod +x test/svn_update.sh])
188AC_CONFIG_FILES([test/check_repo_status.sh],
189                [chmod +x test/check_repo_status.sh])   
190
191
192AC_CONFIG_FILES([Makefile
193                bin/Makefile
194                lib/Makefile
195                man/Makefile
196                test/environment.h
197                test/Makefile])
198
199# Print failure status information about selected items, and exit if
200# fatal errors were encountered. No output will be created if
201# configure is halted prematurely.
202
203# used to trigger exit before creation of output
204all_reqs_ok="true"
205
206if (test "$wc_found" = "yes"); then
207   if test x$HELP2MAN = xno; then
208     AC_MSG_WARN(m4_text_wrap(m4_normalize([
209       `help2man' is missing on your system.  You will not be
210       able to create the man page. A sound man page should be
211       included in a distribution, and since you will not able
212       to create a complete distribution `make dist' will fail.
213       ]),[                   ],
214          [                             ], 79))
215   fi
216   # svnversion is required when building from svn wc
217   if (test "$svnversion" = "no"); then
218      all_reqs_ok="false";
219      AC_MSG_WARN([dnl
220Cannot find svnversion, which is required when building from a
221subversion working copy. Please install svnversion and make sure it is
222in your search path.]);
223   fi
224   if (test "$test_repo_found" = "no"); then
225      all_reqs_ok="false";
226      AC_MSG_WARN([dnl
227Cannot find test repository (test_repo_filename), which should be
228available when building from a subversion working copy. Try svn
229update in top directory.]);
230   fi
231fi
232
233# Non-existing APR is fatal -- sub-sequent compilation will fail.
234if (test "$apr_found" = "no") ; then
235  AC_MSG_WARN([APR not found. The Apache Portable Runtime
236  (APR) library cannot be found. Please make sure APR is installed
237  and supply the appropriate --with-apr option to 'configure'.])
238  all_reqs_ok="false"
239fi
240
241# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
242if (test "$svn_found" = "no") ; then
243  svn_msg="Subversion API not found. Subversion API libraries cannot
244  be found. Make sure the APIs are installed and supply the
245  appropriate --with-svn option to 'configure'."
246  if (test "$apr_found" = "no") ; then
247    svn_msg="$svn_msg
248    Note, APR was not found. Failure to locate APR affects the search
249    of the subversion API. Please fix the APR problem before trying
250    to resolve the subversion related issues."
251  fi
252  AC_MSG_WARN([$svn_msg])
253  all_reqs_ok="false"
254fi
255
256if test $ac_cv_type_long_long_int != yes ; then
257  AC_MSG_WARN([Compiler $CXX does not support `long long'.
258  svndigest must be compiled with a compiler that supports `long long'.])
259  all_reqs_ok="false"
260fi
261
262if (test "$all_reqs_ok" = "false") ; then
263  AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
264  configure. Please consult the 'README' file for more information
265  about what is needed to compile svndigest and refer to above
266  warning messages. Needed files were NOT created.])
267fi
268
269# Create output.
270AC_OUTPUT
271
272# Some more messages.
273AC_MSG_NOTICE([])
274AC_MSG_NOTICE([   Ready to compile the executables of svndigest $VERSION])
275AC_MSG_NOTICE([   The following flags and libs will be used:])
276AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
277AC_MSG_NOTICE([    Compiler:           $CXX])
278AC_MSG_NOTICE([    Preprocessor flags: $SD_CPPFLAGS $CPPFLAGS])
279AC_MSG_NOTICE([    C++ flags:          $SD_CXXFLAGS $CXXFLAGS])
280AC_MSG_NOTICE([    Linker flags:       $SD_LDFLAGS $LDFLAGS])
281AC_MSG_NOTICE([    LIBS:               $SD_LIBS $LIBS])
282AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
283AC_MSG_NOTICE([])
284
285# Failure to locate gnuplot is not considered fatal
286if (test "x$GNUPLOT" = "xno") ; then
287  AC_MSG_WARN([Gnuplot was not found. svndigest will compile
288  without gnuplot but will throw an exception at run-time. Please
289  install gnuplot (available for a wide range of operating systems
290  at http://www.gnuplot.info).])
291  AC_MSG_NOTICE([])
292fi
293
294AC_MSG_NOTICE([Now type 'make ; make check'.])
Note: See TracBrowser for help on using the repository browser.