source: trunk/configure.ac @ 778

Last change on this file since 778 was 778, checked in by Peter Johansson, 12 years ago

Removing obsolete line, which set aside argument given in
AC_PREFIX_DEFAULT. If something like this is needed, see
http://autoconf-archive.cryp.to/ax_expand_prefix.html on how to do it.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 10.5 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 778 2009-02-13 17:18:24Z peter $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson
15# Copyright (C) 2009 Peter Johansson
16#
17# This file is part of svndigest, http://dev.thep.lu.se/svndigest
18#
19# svndigest is free software; you can redistribute it and/or modify it
20# under the terms of the GNU General Public License as published by
21# the Free Software Foundation; either version 3 of the License, or
22# (at your option) any later version.
23#
24# svndigest is distributed in the hope that it will be useful, but
25# WITHOUT ANY WARRANTY; without even the implied warranty of
26# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
27# General Public License for more details.
28#
29# You should have received a copy of the GNU General Public License
30# along with svndigest. If not, see <http://www.gnu.org/licenses/>.
31
32AC_PREREQ(2.61)
33
34m4_include([m4/version.m4])
35AC_INIT([svndigest],[SVNDIGEST_VERSION],[jari@thep.lu.se])
36AC_CONFIG_SRCDIR([lib/File.h])
37AC_CONFIG_AUX_DIR([autotools])
38dnl arg below should be the same as in Makefile.am
39AC_CONFIG_MACRO_DIR([m4])
40AC_PREFIX_DEFAULT([/usr/local])
41
42AC_SUBST([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION])
43AC_SUBST([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION])
44AC_SUBST([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION])
45
46AC_DEFINE([DEV_BUILD],[SVNDIGEST_DEV_BUILD],
47          [true if dev build (version ends with pre)])
48AC_DEFINE([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION],
49                    [Define to the svndigest major version])
50AC_DEFINE([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION],
51                    [Define to the svndigest minor version])
52AC_DEFINE([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION],
53                    [Define to the svndigest patch version])
54
55AC_CONFIG_HEADER([config.h])
56AM_INIT_AUTOMAKE([1.10 std-options check-news])
57
58# Set default programming language
59AC_LANG(C++)
60
61# propagate selected configure variables to DISTCHECK_CONFIGURE_FLAGS
62for var in CPPFLAGS CXX CXXFLAGS CXXCPP LDFLAGS LIBS; do
63  eval isset=\${$var+set}
64  if test "$isset" = 'set' ; then
65    eval val=$`echo $var`
66    DISTCHECK_CONFIGURE_FLAGS="${DISTCHECK_CONFIGURE_FLAGS}'${var}=${val}' "
67  fi
68done
69AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
70
71# Let user overide default CXXFLAGS
72if test "${CXXFLAGS+set}" != set; then
73  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
74fi
75
76# Checks for programs.
77AC_PROG_CXXCPP
78AC_PROG_CXX
79AC_PROG_INSTALL
80AC_PROG_RANLIB
81AC_PROG_SED
82AC_PATH_PROG([HELP2MAN], [help2man], [no])
83AM_CONDITIONAL([HAVE_HELP2MAN], [test x$HELP2MAN != xno])
84AC_PATH_PROG([GNUPLOT],[gnuplot],[no])
85AC_DEFINE_UNQUOTED([GNUPLOT_PATH], ["$GNUPLOT"],
86                   [defined to gnuplot path (or no if gnuplot was not found)])
87
88# Save FLAGS
89SAVE_CPPFLAGS="$CPPFLAGS"
90SAVE_CXXFLAGS="$CXXFLAGS"
91SAVE_LDFLAGS="$LDFLAGS"
92SAVE_LIBS="$LIBS"
93
94# -Wno-long-long is needed to suppress compiler diagnostics regarding
95# using extension beyond the C++ standard (usage of non C++ standard
96# 'long long' types).
97YAT_CXX_ADD_FLAG([SD_CXXFLAGS],[-pedantic -Wno-long-long])
98AC_TYPE_LONG_LONG_INT
99
100AC_ARG_ENABLE(debug,
101  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])],
102  [YAT_CXX_ADD_FLAG([SD_CXXFLAGS],[-g -O])],
103  [YAT_CPP_ADD_FLAG([SD_CPPFLAGS],[-DNDEBUG])
104   YAT_CXX_ADD_FLAG([SD_CXXFLAGS],[-O3])])
105
106# enable svn-support
107AC_ARG_ENABLE([svn-support],
108   [AS_HELP_STRING([--enable-svn-support],
109                   [enable svn support - used by maintainer])],
110   [enable_svn_support=yes])
111AS_IF([test "x$enable_svn_support" = xyes],
112      [AC_CHECK_FILE([$srcdir/.svn],,
113                     [AC_MSG_ERROR([svn support cannot be enabled: `$srcdir' is not an svn wc.])])])
114AM_CONDITIONAL([ENABLE_SVN_SUPPORT], [test "x$enable_svn_support" = "xyes"])
115
116# Apache Portable Runtime (APR) API checks
117APR_FIND_APR(,,1,[1 0])
118AS_IF([test "${with_apr+set}" = set],
119    [DISTCHECK_CONFIGURE_FLAGS="$DISTCHECK_CONFIGURE_FLAGS --with-apr=$with_apr"]
120)
121if test "$apr_found" = "yes" ; then
122    SD_LIBS="`$apr_config --libs` $SD_LIBS"
123    apr_link_ld=`$apr_config --link-ld`
124    for i in $apr_link_ld; do
125      AS_IF([test ${i:0:2} = "-l"],[SD_LIBS="$i $SD_LIBS"],
126            [YAT_LD_ADD_FLAG([SD_LDFLAGS], [$i])])
127    done
128    YAT_CPP_ADD_FLAG([SD_CPPFLAGS],[`$apr_config --includes --cppflags`])
129fi
130
131# Subversion API checks
132svn_found="yes"
133AC_ARG_WITH(svn,
134  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
135  [ DISTCHECK_CONFIGURE_FLAGS="$DISTCHECK_CONFIGURE_FLAGS --with-svn=$withval"
136    YAT_LD_ADD_FLAG([SD_LDFLAGS], [-L$withval/lib])
137    YAT_CPP_ADD_FLAG([SD_CPPFLAGS], [-L$withval/include])
138  ])
139
140
141
142# Use SD_*FLAGS in tests
143CPPFLAGS="$SD_CPPFLAGS $CPPFLAGS"
144CXXFLAGS="$SD_CXXFLAGS $CXXFLAGS"
145LDFLAGS="$SD_LDFLAGS $LDFLAGS"
146LIBS="$SD_LIBS $LIBS"
147
148AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
149AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
150AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],
151               [SD_LIBS="-lsvn_subr-1 $SD_LIBS"],svn_found="no")
152AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],
153               [SD_LIBS="-lsvn_ra-1 $SD_LIBS"],svn_found="no")
154AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],
155               [SD_LIBS="-lsvn_wc-1 $SD_LIBS"],svn_found="no")
156AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],
157               [SD_LIBS="-lsvn_diff-1 $SD_LIBS"],svn_found="no")
158AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],
159               [SD_LIBS="-lsvn_client-1 $SD_LIBS"],svn_found="no")
160
161# Export flags
162AC_SUBST([SVNDIGEST_CPPFLAGS], $SD_CPPFLAGS)
163AC_SUBST([SVNDIGEST_CXXFLAGS], $SD_CXXFLAGS)
164AC_SUBST([SVNDIGEST_LDFLAGS], $SD_LDFLAGS)
165AC_SUBST([SVNDIGEST_LIBS], $SD_LIBS)
166
167# Reset FLAGS
168CPPFLAGS="$SAVE_CPPFLAGS"
169CXXFLAGS="$SAVE_CXXFLAGS"
170LDFLAGS="$SAVE_LDFLAGS"
171LIBS="$SAVE_LIBS"
172
173# check if svnversion is installed
174AC_PATH_PROG([SVNVERSION], [svnversion], [no])
175
176# checking if we build in a subversion WC
177AC_CHECK_FILE([$srcdir/.svn], [wc_found="yes"], [wc_found="no"])
178AM_CONDITIONAL([HAVE_SVN_WC], [test "$wc_found" = "yes"])
179AC_SUBST([wc_found])
180
181# checking if we have test repo
182test_repo_filename=$srcdir/test/repo;
183AC_CHECK_FILE([$test_repo_filename],
184              [AC_DEFINE([HAVE_TEST_REPO],[1],[define if test repo is available])
185               test_repo_found="yes"],
186              [test_repo_found="no"])
187AC_SUBST([test_repo_found])
188AS_IF([test "x$test_repo_found" = xyes],
189      [abs_test_repo=`cd $test_repo_filename && pwd`;
190       AC_SUBST(abs_test_repo)]
191     )
192AC_CONFIG_FILES([test/test_repo.sh], [chmod +x test/test_repo.sh])
193AC_CONFIG_FILES([test/svn_update.sh], [chmod +x test/svn_update.sh])
194AC_CONFIG_FILES([test/check_repo_status.sh],
195                [chmod +x test/check_repo_status.sh])   
196
197
198AC_CONFIG_FILES([Makefile
199                bin/Makefile
200                lib/Makefile
201                man/Makefile
202                test/environment.h
203                test/Makefile])
204
205# Print failure status information about selected items, and exit if
206# fatal errors were encountered. No output will be created if
207# configure is halted prematurely.
208
209# used to trigger exit before creation of output
210all_reqs_ok="true"
211
212if (test "$wc_found" = "yes"); then
213   if test x$HELP2MAN = xno; then
214     AC_MSG_WARN(m4_text_wrap(m4_normalize([
215       `help2man' is missing on your system.  You will not be
216       able to create the man page. A sound man page should be
217       included in a distribution, and since you will not able
218       to create a complete distribution `make dist' will fail.
219       ]),[                   ],
220          [                             ], 79))
221   fi
222   # svnversion is required when building from svn wc
223   if (test "$svnversion" = "no"); then
224      all_reqs_ok="false";
225      AC_MSG_WARN([dnl
226Cannot find svnversion, which is required when building from a
227subversion working copy. Please install svnversion and make sure it is
228in your search path.]);
229   fi
230   if (test "$test_repo_found" = "no"); then
231      all_reqs_ok="false";
232      AC_MSG_WARN([dnl
233Cannot find test repository (test_repo_filename), which should be
234available when building from a subversion working copy. Try svn
235update in top directory.]);
236   fi
237fi
238
239# Non-existing APR is fatal -- sub-sequent compilation will fail.
240if (test "$apr_found" = "no") ; then
241  AC_MSG_WARN([APR not found. The Apache Portable Runtime
242  (APR) library cannot be found. Please make sure APR is installed
243  and supply the appropriate --with-apr option to 'configure'.])
244  all_reqs_ok="false"
245fi
246
247# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
248if (test "$svn_found" = "no") ; then
249  svn_msg="Subversion API not found. Subversion API libraries cannot
250  be found. Make sure the APIs are installed and supply the
251  appropriate --with-svn option to 'configure'."
252  if (test "$apr_found" = "no") ; then
253    svn_msg="$svn_msg
254    Note, APR was not found. Failure to locate APR affects the search
255    of the subversion API. Please fix the APR problem before trying
256    to resolve the subversion related issues."
257  fi
258  AC_MSG_WARN([$svn_msg])
259  all_reqs_ok="false"
260fi
261
262if test $ac_cv_type_long_long_int != yes ; then
263  AC_MSG_WARN([Compiler $CXX does not support `long long'.
264  svndigest must be compiled with a compiler that supports `long long'.])
265  all_reqs_ok="false"
266fi
267
268if (test "$all_reqs_ok" = "false") ; then
269  AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
270  configure. Please consult the 'README' file for more information
271  about what is needed to compile svndigest and refer to above
272  warning messages. Needed files were NOT created.])
273fi
274
275# Create output.
276AC_OUTPUT
277
278# Some more messages.
279AC_MSG_NOTICE([])
280AC_MSG_NOTICE([   Ready to compile the executables of svndigest $VERSION])
281AC_MSG_NOTICE([   The following flags and libs will be used:])
282AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
283AC_MSG_NOTICE([    Compiler:           $CXX])
284AC_MSG_NOTICE([    Preprocessor flags: $SD_CPPFLAGS $CPPFLAGS])
285AC_MSG_NOTICE([    C++ flags:          $SD_CXXFLAGS $CXXFLAGS])
286AC_MSG_NOTICE([    Linker flags:       $SD_LDFLAGS $LDFLAGS])
287AC_MSG_NOTICE([    LIBS:               $SD_LIBS $LIBS])
288AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
289AC_MSG_NOTICE([])
290
291# Failure to locate gnuplot is not considered fatal
292if (test "x$GNUPLOT" = "xno") ; then
293  AC_MSG_WARN([Gnuplot was not found. svndigest will compile
294  without gnuplot but will throw an exception at run-time. Please
295  install gnuplot (available for a wide range of operating systems
296  at http://www.gnuplot.info).])
297  AC_MSG_NOTICE([])
298fi
299
300AC_MSG_NOTICE([Now type 'make ; make check'.])
Note: See TracBrowser for help on using the repository browser.