source: trunk/configure.ac @ 798

Last change on this file since 798 was 795, checked in by Peter Johansson, 12 years ago

refs #388

Create a sub-directory 'lib/yat' in which files from yat are
placed. The files may be updated via 'make fetch', see file README for
more details on how to change which files are updated/copied through
this mechanism.

The reason we do not use subversion's external mechanism is that we
don't want the files to be synchronised with yat automatically. We
want the update to be moderated by some developer.

I chose to fetch files using the svn client rather than wget because
the svn allows us to get an Id string with information from the yat
repository. 'wget' would just download the file as it appears on the
server that is the string is not expanded.

The file 'config_public.h' is created by configure just as in
yat. This implies that automake adds $(top_builddir)/lib/yat to the
include path so unless in a VPATH build $(top_srcdir)/lib/yat is in
the include path. As we have already added $(top_srcdir)/lib to the
include path, and there are both a lib/utility.h and a
lib/yat/utility.h it is not obvious which file is included when having
'include "utility.h"'. For this reason, when being in bin/ and test/
it is needed to include "../lib/utility.h" rather than "utility.h"
when we want to include 'lib/utility.h'.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 10.7 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 795 2009-06-30 03:57:27Z peter $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson
15# Copyright (C) 2009 Peter Johansson
16#
17# This file is part of svndigest, http://dev.thep.lu.se/svndigest
18#
19# svndigest is free software; you can redistribute it and/or modify it
20# under the terms of the GNU General Public License as published by
21# the Free Software Foundation; either version 3 of the License, or
22# (at your option) any later version.
23#
24# svndigest is distributed in the hope that it will be useful, but
25# WITHOUT ANY WARRANTY; without even the implied warranty of
26# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
27# General Public License for more details.
28#
29# You should have received a copy of the GNU General Public License
30# along with svndigest. If not, see <http://www.gnu.org/licenses/>.
31
32AC_PREREQ(2.61)
33
34m4_include([m4/version.m4])
35AC_INIT([svndigest],[SVNDIGEST_VERSION],[jari@thep.lu.se])
36AC_CONFIG_SRCDIR([lib/File.h])
37AC_CONFIG_AUX_DIR([autotools])
38dnl arg below should be the same as in Makefile.am
39AC_CONFIG_MACRO_DIR([m4])
40AC_PREFIX_DEFAULT([/usr/local])
41
42AC_SUBST([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION])
43AC_SUBST([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION])
44AC_SUBST([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION])
45
46AC_DEFINE([DEV_BUILD],[SVNDIGEST_DEV_BUILD],
47          [true if dev build (version ends with pre)])
48AC_DEFINE([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION],
49                    [Define to the svndigest major version])
50AC_DEFINE([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION],
51                    [Define to the svndigest minor version])
52AC_DEFINE([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION],
53                    [Define to the svndigest patch version])
54
55AC_CONFIG_HEADER([config.h])
56AM_INIT_AUTOMAKE([1.10 std-options check-news])
57
58# Set default programming language
59AC_LANG(C++)
60
61# propagate selected configure variables to DISTCHECK_CONFIGURE_FLAGS
62for var in CPPFLAGS CXX CXXFLAGS CXXCPP LDFLAGS LIBS; do
63  eval isset=\${$var+set}
64  if test "$isset" = 'set' ; then
65    eval val=$`echo $var`
66    DISTCHECK_CONFIGURE_FLAGS="${DISTCHECK_CONFIGURE_FLAGS}'${var}=${val}' "
67  fi
68done
69AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
70
71# Let user overide default CXXFLAGS
72if test "${CXXFLAGS+set}" != set; then
73  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
74fi
75
76# Checks for programs.
77AC_PROG_CXXCPP
78AC_PROG_CXX
79AC_PROG_INSTALL
80AC_PROG_RANLIB
81AC_PROG_SED
82AC_PATH_PROG([HELP2MAN], [help2man], [no])
83AM_CONDITIONAL([HAVE_HELP2MAN], [test x$HELP2MAN != xno])
84AC_PATH_PROG([GNUPLOT],[gnuplot],[no])
85AC_DEFINE_UNQUOTED([GNUPLOT_PATH], ["$GNUPLOT"],
86                   [defined to gnuplot path (or no if gnuplot was not found)])
87
88# Save FLAGS
89SAVE_CPPFLAGS="$CPPFLAGS"
90SAVE_CXXFLAGS="$CXXFLAGS"
91SAVE_LDFLAGS="$LDFLAGS"
92SAVE_LIBS="$LIBS"
93
94# -Wno-long-long is needed to suppress compiler diagnostics regarding
95# using extension beyond the C++ standard (usage of non C++ standard
96# 'long long' types).
97YAT_CXX_ADD_FLAG([SD_CXXFLAGS],[-pedantic -Wno-long-long])
98AC_TYPE_LONG_LONG_INT
99AS_IF([test x$ac_cv_type_long_long_int = xno],
100      [AC_MSG_ERROR([compiler does not support long long int])]
101     )
102
103AC_ARG_ENABLE([debug],
104  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])],
105  [YAT_CXX_ADD_FLAG([SD_CXXFLAGS],[-g -O])],
106  [YAT_CPP_ADD_FLAG([SD_CPPFLAGS],[-DNDEBUG])
107   YAT_CXX_ADD_FLAG([SD_CXXFLAGS],[-O3])])
108
109# enable svn-support
110AC_ARG_ENABLE([svn-support],
111              [AS_HELP_STRING([--enable-svn-support],
112                              [enable svn support - used by maintainer])])
113
114AS_IF([test "x$enable_svn-support" = xyes],
115      [AC_CHECK_FILE([$srcdir/.svn],,
116                     [AC_MSG_ERROR([svn support cannot be enabled: `$srcdir' is not an svn wc.])])])
117AM_CONDITIONAL([ENABLE_SVN_SUPPORT], [test "x$enable_svn-support" = "xyes"])
118
119# Apache Portable Runtime (APR) API checks
120APR_FIND_APR(,,1,[1 0])
121AS_IF([test "${with_apr+set}" = set],
122    [DISTCHECK_CONFIGURE_FLAGS="$DISTCHECK_CONFIGURE_FLAGS --with-apr=$with_apr"]
123)
124if test "$apr_found" = "yes" ; then
125    SD_LIBS="`$apr_config --libs` $SD_LIBS"
126    apr_link_ld=`$apr_config --link-ld`
127    for i in $apr_link_ld; do
128      AS_IF([test ${i:0:2} = "-l"],[SD_LIBS="$i $SD_LIBS"],
129            [YAT_LD_ADD_FLAG([SD_LDFLAGS], [$i])])
130    done
131    YAT_CPP_ADD_FLAG([SD_CPPFLAGS],[`$apr_config --includes --cppflags`])
132fi
133
134# Subversion API checks
135svn_found="yes"
136AC_ARG_WITH(svn,
137  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
138  [ DISTCHECK_CONFIGURE_FLAGS="$DISTCHECK_CONFIGURE_FLAGS --with-svn=$withval"
139    YAT_LD_ADD_FLAG([SD_LDFLAGS], [-L$withval/lib])
140    YAT_CPP_ADD_FLAG([SD_CPPFLAGS], [-I$withval/include])
141  ])
142
143
144
145# Use SD_*FLAGS in tests
146CPPFLAGS="$SD_CPPFLAGS $CPPFLAGS"
147CXXFLAGS="$SD_CXXFLAGS $CXXFLAGS"
148LDFLAGS="$SD_LDFLAGS $LDFLAGS"
149LIBS="$SD_LIBS $LIBS"
150
151AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
152AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
153AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],
154               [SD_LIBS="-lsvn_subr-1 $SD_LIBS"],svn_found="no")
155AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],
156               [SD_LIBS="-lsvn_ra-1 $SD_LIBS"],svn_found="no")
157AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],
158               [SD_LIBS="-lsvn_wc-1 $SD_LIBS"],svn_found="no")
159AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],
160               [SD_LIBS="-lsvn_diff-1 $SD_LIBS"],svn_found="no")
161AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],
162               [SD_LIBS="-lsvn_client-1 $SD_LIBS"],svn_found="no")
163
164# Export flags
165AC_SUBST([SVNDIGEST_CPPFLAGS], $SD_CPPFLAGS)
166AC_SUBST([SVNDIGEST_CXXFLAGS], $SD_CXXFLAGS)
167AC_SUBST([SVNDIGEST_LDFLAGS], $SD_LDFLAGS)
168AC_SUBST([SVNDIGEST_LIBS], $SD_LIBS)
169
170# Reset FLAGS
171CPPFLAGS="$SAVE_CPPFLAGS"
172CXXFLAGS="$SAVE_CXXFLAGS"
173LDFLAGS="$SAVE_LDFLAGS"
174LIBS="$SAVE_LIBS"
175
176# check if svnversion is installed
177AC_PATH_PROG([SVNVERSION], [svnversion], [no])
178
179# checking if we build in a subversion WC
180AC_CHECK_FILE([$srcdir/.svn], [wc_found="yes"], [wc_found="no"])
181AM_CONDITIONAL([HAVE_SVN_WC], [test "$wc_found" = "yes"])
182AC_SUBST([wc_found])
183
184# checking if we have test repo
185test_repo_filename=$srcdir/test/repo;
186AC_CHECK_FILE([$test_repo_filename],
187              [AC_DEFINE([HAVE_TEST_REPO],[1],[define if test repo is available])
188               test_repo_found="yes"],
189              [test_repo_found="no"])
190AC_SUBST([test_repo_found])
191AS_IF([test "x$test_repo_found" = xyes],
192      [abs_test_repo=`cd $test_repo_filename && pwd`;
193       AC_SUBST(abs_test_repo)]
194     )
195AC_CONFIG_FILES([test/test_repo.sh], [chmod +x test/test_repo.sh])
196AC_CONFIG_FILES([test/svn_update.sh], [chmod +x test/svn_update.sh])
197AC_CONFIG_FILES([test/check_repo_status.sh],
198                [chmod +x test/check_repo_status.sh])   
199
200
201AC_CONFIG_FILES([Makefile
202                bin/Makefile
203                lib/Makefile
204                lib/yat/Makefile
205                man/Makefile
206                test/environment.h
207                test/Makefile])
208
209AC_CONFIG_HEADER([lib/yat/config_public.h])
210
211# Print failure status information about selected items, and exit if
212# fatal errors were encountered. No output will be created if
213# configure is halted prematurely.
214
215# used to trigger exit before creation of output
216all_reqs_ok="true"
217
218if (test "$wc_found" = "yes"); then
219   if test x$HELP2MAN = xno; then
220     AC_MSG_WARN(m4_text_wrap(m4_normalize([
221       `help2man' is missing on your system.  You will not be
222       able to create the man page. A sound man page should be
223       included in a distribution, and since you will not able
224       to create a complete distribution `make dist' will fail.
225       ]),[                   ],
226          [                             ], 79))
227   fi
228   # svnversion is required when building from svn wc
229   if (test "$svnversion" = "no"); then
230      all_reqs_ok="false";
231      AC_MSG_WARN([dnl
232Cannot find svnversion, which is required when building from a
233subversion working copy. Please install svnversion and make sure it is
234in your search path.]);
235   fi
236   if (test "$test_repo_found" = "no"); then
237      all_reqs_ok="false";
238      AC_MSG_WARN([dnl
239Cannot find test repository (test_repo_filename), which should be
240available when building from a subversion working copy. Try svn
241update in top directory.]);
242   fi
243fi
244
245# Non-existing APR is fatal -- sub-sequent compilation will fail.
246if (test "$apr_found" = "no") ; then
247  AC_MSG_WARN([APR not found. The Apache Portable Runtime
248  (APR) library cannot be found. Please make sure APR is installed
249  and supply the appropriate --with-apr option to 'configure'.])
250  all_reqs_ok="false"
251fi
252
253# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
254if (test "$svn_found" = "no") ; then
255  svn_msg="Subversion API not found. Subversion API libraries cannot
256  be found. Make sure the APIs are installed and supply the
257  appropriate --with-svn option to 'configure'."
258  if (test "$apr_found" = "no") ; then
259    svn_msg="$svn_msg
260    Note, APR was not found. Failure to locate APR affects the search
261    of the subversion API. Please fix the APR problem before trying
262    to resolve the subversion related issues."
263  fi
264  AC_MSG_WARN([$svn_msg])
265  all_reqs_ok="false"
266fi
267
268if test $ac_cv_type_long_long_int != yes ; then
269  AC_MSG_WARN([Compiler $CXX does not support `long long'.
270  svndigest must be compiled with a compiler that supports `long long'.])
271  all_reqs_ok="false"
272fi
273
274if (test "$all_reqs_ok" = "false") ; then
275  AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
276  configure. Please consult the 'README' file for more information
277  about what is needed to compile svndigest and refer to above
278  warning messages. Needed files were NOT created.])
279fi
280
281# Create output.
282AC_OUTPUT
283
284# Some more messages.
285AC_MSG_NOTICE([])
286AC_MSG_NOTICE([   Ready to compile the executables of svndigest $VERSION])
287AC_MSG_NOTICE([   The following flags and libs will be used:])
288AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
289AC_MSG_NOTICE([    Compiler:           $CXX])
290AC_MSG_NOTICE([    Preprocessor flags: $SD_CPPFLAGS $CPPFLAGS])
291AC_MSG_NOTICE([    C++ flags:          $SD_CXXFLAGS $CXXFLAGS])
292AC_MSG_NOTICE([    Linker flags:       $SD_LDFLAGS $LDFLAGS])
293AC_MSG_NOTICE([    LIBS:               $SD_LIBS $LIBS])
294AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
295AC_MSG_NOTICE([])
296
297# Failure to locate gnuplot is not considered fatal
298if (test "x$GNUPLOT" = "xno") ; then
299  AC_MSG_WARN([Gnuplot was not found. svndigest will compile
300  without gnuplot but will throw an exception at run-time. Please
301  install gnuplot (available for a wide range of operating systems
302  at http://www.gnuplot.info).])
303  AC_MSG_NOTICE([])
304fi
305
306AC_MSG_NOTICE([Now type 'make && make check'.])
Note: See TracBrowser for help on using the repository browser.