source: trunk/configure.ac @ 843

Last change on this file since 843 was 843, checked in by Peter Johansson, 12 years ago

Merge patch release 0.6.8 into trunk. Delta 0.6.8 - 0.6.7.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 10.8 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 843 2009-11-12 11:47:56Z peter $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson
15# Copyright (C) 2009 Peter Johansson
16#
17# This file is part of svndigest, http://dev.thep.lu.se/svndigest
18#
19# svndigest is free software; you can redistribute it and/or modify it
20# under the terms of the GNU General Public License as published by
21# the Free Software Foundation; either version 3 of the License, or
22# (at your option) any later version.
23#
24# svndigest is distributed in the hope that it will be useful, but
25# WITHOUT ANY WARRANTY; without even the implied warranty of
26# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
27# General Public License for more details.
28#
29# You should have received a copy of the GNU General Public License
30# along with svndigest. If not, see <http://www.gnu.org/licenses/>.
31
32AC_PREREQ(2.61)
33
34m4_include([m4/version.m4])
35AC_INIT([svndigest],[SVNDIGEST_VERSION],[jari@thep.lu.se],,
36        [http://dev.thep.lu.se/svndigest])
37AC_CONFIG_SRCDIR([lib/File.h])
38AC_CONFIG_AUX_DIR([autotools])
39dnl arg below should be the same as in Makefile.am
40AC_CONFIG_MACRO_DIR([m4])
41AC_PREFIX_DEFAULT([/usr/local])
42
43AC_SUBST([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION])
44AC_SUBST([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION])
45AC_SUBST([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION])
46
47AC_DEFINE([DEV_BUILD],[SVNDIGEST_DEV_BUILD],
48          [true if dev build (version ends with pre)])
49AC_DEFINE([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION],
50                    [Define to the svndigest major version])
51AC_DEFINE([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION],
52                    [Define to the svndigest minor version])
53AC_DEFINE([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION],
54                    [Define to the svndigest patch version])
55
56AC_CONFIG_HEADER([config.h])
57AM_INIT_AUTOMAKE([1.10 std-options check-news])
58
59# Set default programming language
60AC_LANG(C++)
61
62# propagate selected configure variables to DISTCHECK_CONFIGURE_FLAGS
63for var in CPPFLAGS CXX CXXFLAGS CXXCPP LDFLAGS LIBS; do
64  eval isset=\${$var+set}
65  if test "$isset" = 'set' ; then
66    eval val=$`echo $var`
67    DISTCHECK_CONFIGURE_FLAGS="${DISTCHECK_CONFIGURE_FLAGS}'${var}=${val}' "
68  fi
69done
70AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
71
72# Let user overide default CXXFLAGS
73if test "${CXXFLAGS+set}" != set; then
74  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
75fi
76
77# Checks for programs.
78AC_PROG_CXXCPP
79AC_PROG_CXX
80AC_PROG_INSTALL
81AC_PROG_RANLIB
82AC_PROG_SED
83AC_PATH_PROG([HELP2MAN], [help2man], [no])
84AM_CONDITIONAL([HAVE_HELP2MAN], [test x$HELP2MAN != xno])
85AC_PATH_PROG([GNUPLOT],[gnuplot],[no])
86AC_DEFINE_UNQUOTED([GNUPLOT_PATH], ["$GNUPLOT"],
87                   [defined to gnuplot path (or no if gnuplot was not found)])
88
89# Save FLAGS
90SAVE_CPPFLAGS="$CPPFLAGS"
91SAVE_CXXFLAGS="$CXXFLAGS"
92SAVE_LDFLAGS="$LDFLAGS"
93SAVE_LIBS="$LIBS"
94
95# -Wno-long-long is needed to suppress compiler diagnostics regarding
96# using extension beyond the C++ standard (usage of non C++ standard
97# 'long long' types).
98YAT_CXX_ADD_FLAG([SD_CXXFLAGS],[-pedantic -Wno-long-long])
99AC_TYPE_LONG_LONG_INT
100AS_IF([test x$ac_cv_type_long_long_int = xno],
101      [AC_MSG_ERROR([compiler does not support long long int])]
102     )
103
104AC_ARG_ENABLE([debug],
105  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])])
106
107AS_IF([test x$enable_debug = xyes],
108  [YAT_CXX_ADD_FLAG([SD_CXXFLAGS],[-g -O])],
109  [YAT_CPP_ADD_FLAG([SD_CPPFLAGS],[-DNDEBUG])
110   YAT_CXX_ADD_FLAG([SD_CXXFLAGS],[-O3])])
111
112# enable svn-support
113AC_ARG_ENABLE([svn-support],
114              [AS_HELP_STRING([--enable-svn-support],
115                              [enable svn support - used by maintainer])])
116
117AS_IF([test "x$enable_svn_support" = xyes],
118      [AS_IF([test -d $srcdir/.svn], [],
119             [AC_MSG_ERROR([svn support cannot be enabled: `$srcdir' is not an svn wc.])])])
120AM_CONDITIONAL([ENABLE_SVN_SUPPORT], [test "x$enable_svn_support" = "xyes"])
121
122# Apache Portable Runtime (APR) API checks
123APR_FIND_APR(,,1,[1 0])
124AS_IF([test "${with_apr+set}" = set],
125    [DISTCHECK_CONFIGURE_FLAGS="$DISTCHECK_CONFIGURE_FLAGS --with-apr=$with_apr"]
126)
127if test "$apr_found" = "yes" ; then
128    SD_LIBS="`$apr_config --libs` $SD_LIBS"
129    apr_link_ld=`$apr_config --link-ld`
130    for i in $apr_link_ld; do
131      AS_IF([test ${i:0:2} = "-l"],[SD_LIBS="$i $SD_LIBS"],
132            [YAT_LD_ADD_FLAG([SD_LDFLAGS], [$i])])
133    done
134    YAT_CPP_ADD_FLAG([SD_CPPFLAGS],[`$apr_config --includes --cppflags`])
135fi
136
137# Subversion API checks
138svn_found="yes"
139AC_ARG_WITH(svn,
140  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
141  [ DISTCHECK_CONFIGURE_FLAGS="$DISTCHECK_CONFIGURE_FLAGS --with-svn=$withval"
142    YAT_LD_ADD_FLAG([SD_LDFLAGS], [-L$withval/lib])
143    YAT_CPP_ADD_FLAG([SD_CPPFLAGS], [-I$withval/include])
144  ])
145
146
147
148# Use SD_*FLAGS in tests
149CPPFLAGS="$SD_CPPFLAGS $CPPFLAGS"
150CXXFLAGS="$SD_CXXFLAGS $CXXFLAGS"
151LDFLAGS="$SD_LDFLAGS $LDFLAGS"
152LIBS="$SD_LIBS $LIBS"
153
154AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
155AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
156AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],
157               [SD_LIBS="-lsvn_subr-1 $SD_LIBS"],svn_found="no")
158AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],
159               [SD_LIBS="-lsvn_ra-1 $SD_LIBS"],svn_found="no")
160AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],
161               [SD_LIBS="-lsvn_wc-1 $SD_LIBS"],svn_found="no")
162AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],
163               [SD_LIBS="-lsvn_diff-1 $SD_LIBS"],svn_found="no")
164AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],
165               [SD_LIBS="-lsvn_client-1 $SD_LIBS"],svn_found="no")
166
167# Export flags
168AC_SUBST([SVNDIGEST_CPPFLAGS], $SD_CPPFLAGS)
169AC_SUBST([SVNDIGEST_CXXFLAGS], $SD_CXXFLAGS)
170AC_SUBST([SVNDIGEST_LDFLAGS], $SD_LDFLAGS)
171AC_SUBST([SVNDIGEST_LIBS], $SD_LIBS)
172
173# Reset FLAGS
174CPPFLAGS="$SAVE_CPPFLAGS"
175CXXFLAGS="$SAVE_CXXFLAGS"
176LDFLAGS="$SAVE_LDFLAGS"
177LIBS="$SAVE_LIBS"
178
179# check if svnversion is installed
180AC_PATH_PROG([SVNVERSION], [svnversion], [no])
181
182# checking if we build in a subversion WC
183AS_IF([test -d $srcdir/.svn], [wc_found="yes"], [wc_found="no"])
184AM_CONDITIONAL([HAVE_SVN_WC], [test "$wc_found" = "yes"])
185AC_SUBST([wc_found])
186
187# checking if we have test repo
188test_repo_filename=$srcdir/test/repo;
189AS_IF([test -r $test_repo_filename],
190              [AC_DEFINE([HAVE_TEST_REPO],[1],[define if test repo is available])
191               test_repo_found="yes"],
192              [test_repo_found="no"])
193AC_SUBST([test_repo_found])
194AS_IF([test "x$test_repo_found" = xyes],
195      [abs_test_repo=`cd $test_repo_filename && pwd`;
196       AC_SUBST(abs_test_repo)]
197     )
198AC_CONFIG_FILES([test/test_repo.sh], [chmod +x test/test_repo.sh])
199AC_CONFIG_FILES([test/svn_update.sh], [chmod +x test/svn_update.sh])
200AC_CONFIG_FILES([test/check_repo_status.sh],
201                [chmod +x test/check_repo_status.sh])   
202
203
204AC_CONFIG_FILES([Makefile
205                bin/Makefile
206                lib/Makefile
207                lib/yat/Makefile
208                man/Makefile
209                test/environment.h
210                test/Makefile])
211
212AC_CONFIG_HEADER([lib/yat/config_public.h])
213
214# Print failure status information about selected items, and exit if
215# fatal errors were encountered. No output will be created if
216# configure is halted prematurely.
217
218# used to trigger exit before creation of output
219all_reqs_ok="true"
220
221if (test "$wc_found" = "yes"); then
222   if test x$HELP2MAN = xno; then
223     AC_MSG_WARN(m4_text_wrap(m4_normalize([
224       `help2man' is missing on your system.  You will not be
225       able to create the man page. A sound man page should be
226       included in a distribution, and since you will not able
227       to create a complete distribution `make dist' will fail.
228       ]),[                   ],
229          [                             ], 79))
230   fi
231   # svnversion is required when building from svn wc
232   if (test "$svnversion" = "no"); then
233      all_reqs_ok="false";
234      AC_MSG_WARN([dnl
235Cannot find svnversion, which is required when building from a
236subversion working copy. Please install svnversion and make sure it is
237in your search path.]);
238   fi
239   if (test "$test_repo_found" = "no"); then
240      all_reqs_ok="false";
241      AC_MSG_WARN([dnl
242Cannot find test repository (test_repo_filename), which should be
243available when building from a subversion working copy. Try svn
244update in top directory.]);
245   fi
246fi
247
248# Non-existing APR is fatal -- sub-sequent compilation will fail.
249if (test "$apr_found" = "no") ; then
250  AC_MSG_WARN([APR not found. The Apache Portable Runtime
251  (APR) library cannot be found. Please make sure APR is installed
252  and supply the appropriate --with-apr option to 'configure'.])
253  all_reqs_ok="false"
254fi
255
256# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
257if (test "$svn_found" = "no") ; then
258  svn_msg="Subversion API not found. Subversion API libraries cannot
259  be found. Make sure the APIs are installed and supply the
260  appropriate --with-svn option to 'configure'."
261  if (test "$apr_found" = "no") ; then
262    svn_msg="$svn_msg
263    Note, APR was not found. Failure to locate APR affects the search
264    of the subversion API. Please fix the APR problem before trying
265    to resolve the subversion related issues."
266  fi
267  AC_MSG_WARN([$svn_msg])
268  all_reqs_ok="false"
269fi
270
271if test $ac_cv_type_long_long_int != yes ; then
272  AC_MSG_WARN([Compiler $CXX does not support `long long'.
273  svndigest must be compiled with a compiler that supports `long long'.])
274  all_reqs_ok="false"
275fi
276
277if (test "$all_reqs_ok" = "false") ; then
278  AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
279  configure. Please consult the 'README' file for more information
280  about what is needed to compile svndigest and refer to above
281  warning messages. Needed files were NOT created.])
282fi
283
284# Create output.
285AC_OUTPUT
286
287# Some more messages.
288AC_MSG_NOTICE([])
289AC_MSG_NOTICE([   Ready to compile the executables of svndigest $VERSION])
290AC_MSG_NOTICE([   The following flags and libs will be used:])
291AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
292AC_MSG_NOTICE([    Compiler:           $CXX])
293AC_MSG_NOTICE([    Preprocessor flags: $SD_CPPFLAGS $CPPFLAGS])
294AC_MSG_NOTICE([    C++ flags:          $SD_CXXFLAGS $CXXFLAGS])
295AC_MSG_NOTICE([    Linker flags:       $SD_LDFLAGS $LDFLAGS])
296AC_MSG_NOTICE([    LIBS:               $SD_LIBS $LIBS])
297AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
298AC_MSG_NOTICE([])
299
300# Failure to locate gnuplot is not considered fatal
301if (test "x$GNUPLOT" = "xno") ; then
302  AC_MSG_WARN([Gnuplot was not found. svndigest will compile
303  without gnuplot but will throw an exception at run-time. Please
304  install gnuplot (available for a wide range of operating systems
305  at http://www.gnuplot.info).])
306  AC_MSG_NOTICE([])
307fi
308
309AC_MSG_NOTICE([Now type 'make && make check'.])
Note: See TracBrowser for help on using the repository browser.