source: trunk/configure.ac @ 874

Last change on this file since 874 was 874, checked in by Peter Johansson, 12 years ago

merging release 0.7. Delta /tags/0.7 - /branches/0.7-stable@848

Due to problems with 'svn merge' (skipping added files?), I've copied
added files manually.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 10.8 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 874 2009-11-22 22:53:21Z peter $
4##
5## If you grabbed the source from subversion you should, at top-level,
6## execute:
7##          ./bootstrap
8## To push subsequent changes of this file into the build scripts you
9## must issue:
10##          autoreconf
11
12# Copyright (C) 2005 Jari Häkkinen, Peter Johansson
13# Copyright (C) 2006 Jari Häkkinen
14# Copyright (C) 2007, 2008, 2009 Jari Häkkinen, Peter Johansson
15#
16# This file is part of svndigest, http://dev.thep.lu.se/svndigest
17#
18# svndigest is free software; you can redistribute it and/or modify it
19# under the terms of the GNU General Public License as published by
20# the Free Software Foundation; either version 3 of the License, or
21# (at your option) any later version.
22#
23# svndigest is distributed in the hope that it will be useful, but
24# WITHOUT ANY WARRANTY; without even the implied warranty of
25# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
26# General Public License for more details.
27#
28# You should have received a copy of the GNU General Public License
29# along with svndigest. If not, see <http://www.gnu.org/licenses/>.
30
31AC_PREREQ(2.61)
32
33m4_include([m4/version.m4])
34AC_INIT([svndigest],[SVNDIGEST_VERSION],[jari@thep.lu.se],,
35        [http://dev.thep.lu.se/svndigest])
36AC_CONFIG_SRCDIR([lib/File.h])
37AC_CONFIG_AUX_DIR([autotools])
38dnl arg below should be the same as in Makefile.am
39AC_CONFIG_MACRO_DIR([m4])
40AC_PREFIX_DEFAULT([/usr/local])
41
42AC_SUBST([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION])
43AC_SUBST([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION])
44AC_SUBST([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION])
45
46AC_DEFINE([DEV_BUILD],[SVNDIGEST_DEV_BUILD],
47          [true if dev build (version ends with pre)])
48AC_DEFINE([SVNDIGEST_MAJOR_VERSION], [MAJOR_VERSION],
49                    [Define to the svndigest major version])
50AC_DEFINE([SVNDIGEST_MINOR_VERSION], [MINOR_VERSION],
51                    [Define to the svndigest minor version])
52AC_DEFINE([SVNDIGEST_PATCH_VERSION], [PATCH_VERSION],
53                    [Define to the svndigest patch version])
54
55AC_CONFIG_HEADER([config.h])
56AM_INIT_AUTOMAKE([1.10 std-options])
57
58# Set default programming language
59AC_LANG(C++)
60
61# propagate selected configure variables to DISTCHECK_CONFIGURE_FLAGS
62for var in CPPFLAGS CXX CXXFLAGS CXXCPP LDFLAGS LIBS; do
63  eval isset=\${$var+set}
64  if test "$isset" = 'set' ; then
65    eval val=$`echo $var`
66    DISTCHECK_CONFIGURE_FLAGS="${DISTCHECK_CONFIGURE_FLAGS}'${var}=${val}' "
67  fi
68done
69AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
70
71# Let user overide default CXXFLAGS
72if test "${CXXFLAGS+set}" != set; then
73  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
74fi
75
76# Checks for programs.
77AC_PROG_CXXCPP
78AC_PROG_CXX
79AC_PROG_INSTALL
80AC_PROG_RANLIB
81AC_PROG_SED
82AC_PATH_PROG([HELP2MAN], [help2man], [no])
83AM_CONDITIONAL([HAVE_HELP2MAN], [test x$HELP2MAN != xno])
84PKG_PROG_PKG_CONFIG([0.23]) # look for pkg-config
85
86# Save FLAGS
87SAVE_CPPFLAGS="$CPPFLAGS"
88SAVE_CXXFLAGS="$CXXFLAGS"
89SAVE_LDFLAGS="$LDFLAGS"
90SAVE_LIBS="$LIBS"
91
92# -Wno-long-long is needed to suppress compiler diagnostics regarding
93# using extension beyond the C++ standard (usage of non C++ standard
94# 'long long' types).
95YAT_CXX_ADD_FLAG([SD_CXXFLAGS],[-pedantic -Wno-long-long])
96AC_TYPE_LONG_LONG_INT
97AS_IF([test x$ac_cv_type_long_long_int = xno],
98      [AC_MSG_ERROR([compiler does not support long long int])]
99     )
100
101AC_ARG_ENABLE([debug],
102  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])])
103
104AS_IF([test x$enable_debug = xyes],
105  [YAT_CXX_ADD_FLAG([SD_CXXFLAGS],[-g -O])],
106  [YAT_CPP_ADD_FLAG([SD_CPPFLAGS],[-DNDEBUG])
107   YAT_CXX_ADD_FLAG([SD_CXXFLAGS],[-O3])])
108
109# Apache Portable Runtime (APR) API checks
110APR_FIND_APR(,,1,[1 0])
111AS_IF([test "${with_apr+set}" = set],
112    [DISTCHECK_CONFIGURE_FLAGS="$DISTCHECK_CONFIGURE_FLAGS --with-apr=$with_apr"]
113)
114if test "$apr_found" = "yes" ; then
115    SD_LIBS="`$apr_config --libs` $SD_LIBS"
116    apr_link_ld=`$apr_config --link-ld`
117    for i in $apr_link_ld; do
118      AS_IF([test ${i:0:2} = "-l"],[SD_LIBS="$i $SD_LIBS"],
119            [YAT_LD_ADD_FLAG([SD_LDFLAGS], [$i])])
120    done
121    YAT_CPP_ADD_FLAG([SD_CPPFLAGS],[`$apr_config --includes --cppflags`])
122fi
123
124# Subversion API checks
125svn_found="yes"
126AC_ARG_WITH(svn,
127  [AS_HELP_STRING([--with-svn=DIR],[prefix for svn developer files [[PREFIX]]])],
128  [ DISTCHECK_CONFIGURE_FLAGS="$DISTCHECK_CONFIGURE_FLAGS --with-svn=$withval"
129    YAT_LD_ADD_FLAG([SD_LDFLAGS], [-L$withval/lib])
130    YAT_CPP_ADD_FLAG([SD_CPPFLAGS], [-I$withval/include])
131  ])
132
133
134
135# Use SD_*FLAGS in tests
136CPPFLAGS="$SD_CPPFLAGS $CPPFLAGS"
137CXXFLAGS="$SD_CXXFLAGS $CXXFLAGS"
138LDFLAGS="$SD_LDFLAGS $LDFLAGS"
139LIBS="$SD_LIBS $LIBS"
140
141AC_CHECK_HEADER([apr_allocator.h],,apr_found="no")
142AC_CHECK_HEADER([subversion-1/svn_types.h],,svn_found="no")
143AC_SEARCH_LIBS([svn_cmdline_setup_auth_baton],[svn_subr-1],
144               [SD_LIBS="-lsvn_subr-1 $SD_LIBS"],svn_found="no")
145AC_SEARCH_LIBS([svn_ra_initialize],[svn_ra-1],
146               [SD_LIBS="-lsvn_ra-1 $SD_LIBS"],svn_found="no")
147AC_SEARCH_LIBS([svn_wc_adm_open3],[svn_wc-1],
148               [SD_LIBS="-lsvn_wc-1 $SD_LIBS"],svn_found="no")
149AC_SEARCH_LIBS([svn_diff_file_options_create],[svn_diff-1],
150               [SD_LIBS="-lsvn_diff-1 $SD_LIBS"],svn_found="no")
151AC_SEARCH_LIBS([svn_client_log3],[svn_client-1],
152               [SD_LIBS="-lsvn_client-1 $SD_LIBS"],svn_found="no")
153
154# Export flags
155AC_SUBST([SVNDIGEST_CPPFLAGS], $SD_CPPFLAGS)
156AC_SUBST([SVNDIGEST_CXXFLAGS], $SD_CXXFLAGS)
157AC_SUBST([SVNDIGEST_LDFLAGS], $SD_LDFLAGS)
158AC_SUBST([SVNDIGEST_LIBS], $SD_LIBS)
159
160# Reset FLAGS
161CPPFLAGS="$SAVE_CPPFLAGS"
162CXXFLAGS="$SAVE_CXXFLAGS"
163LDFLAGS="$SAVE_LDFLAGS"
164LIBS="$SAVE_LIBS"
165
166# check if svnversion is installed
167AC_PATH_PROG([SVNVERSION], [svnversion], [no])
168
169# PLplot API checks
170plplot_found="yes"
171plplot_version=5.9
172AC_CHECK_HEADER([plplot/plstream.h],
173                [if $PKG_CONFIG --atleast-version=$plplot_version plplotd-c++; then
174                  PLPLOT_LDFLAGS=`$PKG_CONFIG --libs plplotd-c++`
175                  AC_SUBST([PLPLOT_LDFLAGS])
176                else
177                  plplot_found="nolib"
178                fi],
179                plplot_found="noheader")
180
181# checking if we build in a subversion WC
182AS_IF([test -d $srcdir/.svn], [wc_found="yes"], [wc_found="no"])
183AM_CONDITIONAL([HAVE_SVN_WC], [test "$wc_found" = "yes"])
184AC_SUBST([wc_found])
185
186# checking if we have test repo
187test_repo_filename=$srcdir/test/repo;
188AS_IF([test -r $test_repo_filename],
189              [AC_DEFINE([HAVE_TEST_REPO],[1],[define if test repo is available])
190               test_repo_found="yes"],
191              [test_repo_found="no"])
192AC_SUBST([test_repo_found])
193AS_IF([test "x$test_repo_found" = xyes],
194      [abs_test_repo=`cd $test_repo_filename && pwd`;
195       AC_SUBST(abs_test_repo)]
196     )
197AC_CONFIG_FILES([test/test_repo.sh], [chmod +x test/test_repo.sh])
198AC_CONFIG_FILES([test/svn_update.sh], [chmod +x test/svn_update.sh])
199AC_CONFIG_FILES([test/check_repo_status.sh],
200                [chmod +x test/check_repo_status.sh])   
201
202# maintainer make rukes from yat project
203YAT_SVN_RELEASE
204
205AC_CONFIG_FILES([Makefile
206                bin/Makefile
207                lib/Makefile
208                lib/yat/Makefile
209                man/Makefile
210                test/environment.h
211                test/Makefile])
212
213AC_CONFIG_HEADER([lib/yat/config_public.h])
214
215# Print failure status information about selected items, and exit if
216# fatal errors were encountered. No output will be created if
217# configure is halted prematurely.
218
219# used to trigger exit before creation of output
220all_reqs_ok="true"
221
222if (test "$wc_found" = "yes"); then
223   if test x$HELP2MAN = xno; then
224     AC_MSG_WARN(m4_text_wrap(m4_normalize([
225       `help2man' is missing on your system.  You will not be
226       able to create the man page. A sound man page should be
227       included in a distribution, and since you will not able
228       to create a complete distribution `make dist' will fail.
229       ]),[                   ],
230          [                             ], 79))
231   fi
232   # svnversion is required when building from svn wc
233   if (test "$svnversion" = "no"); then
234      all_reqs_ok="false";
235      AC_MSG_WARN([dnl
236Cannot find svnversion, which is required when building from a
237subversion working copy. Please install svnversion and make sure it is
238in your search path.]);
239   fi
240   if (test "$test_repo_found" = "no"); then
241      all_reqs_ok="false";
242      AC_MSG_WARN([dnl
243Cannot find test repository (test_repo_filename), which should be
244available when building from a subversion working copy. Try svn
245update in top directory.]);
246   fi
247fi
248
249# Non-existing APR is fatal -- sub-sequent compilation will fail.
250if (test "$apr_found" = "no") ; then
251  AC_MSG_WARN([APR not found. The Apache Portable Runtime
252  (APR) library cannot be found. Please make sure APR is installed
253  and supply the appropriate --with-apr option to 'configure'.])
254  all_reqs_ok="false"
255fi
256
257# Non-existing subversion API is fatal -- sub-sequent compilation will fail.
258if (test "$svn_found" = "no") ; then
259  svn_msg="Subversion API not found. Subversion API libraries cannot
260  be found. Make sure the APIs are installed and supply the
261  appropriate --with-svn option to 'configure'."
262  if (test "$apr_found" = "no") ; then
263    svn_msg="$svn_msg
264    Note, APR was not found. Failure to locate APR affects the search
265    of the subversion API. Please fix the APR problem before trying
266    to resolve the subversion related issues."
267  fi
268  AC_MSG_WARN([$svn_msg])
269  all_reqs_ok="false"
270fi
271
272# Non-existing PLplot API is fatal -- sub-sequent compilation will fail.
273if (test "$plplot_found" = "noheader") ; then
274  AC_MSG_WARN([PLplot developer files cannot be found. Make sure PLplot
275  is installed.])
276  all_reqs_ok="false"
277elif (test "$plplot_found" = "nolib") ; then
278  AC_MSG_WARN([PLplot developer files found but not required API version.
279  Version at least $plplot_version is required. Please upgrade PLplot.])
280  all_reqs_ok="false"
281fi
282
283if test $ac_cv_type_long_long_int != yes ; then
284  AC_MSG_WARN([Compiler $CXX does not support `long long'.
285  svndigest must be compiled with a compiler that supports `long long'.])
286  all_reqs_ok="false"
287fi
288
289if (test "$all_reqs_ok" = "false") ; then
290  AC_MSG_ERROR([Some pre-requisites were not fulfilled, aborting
291  configure. Please consult the 'README' file for more information
292  about what is needed to compile svndigest and refer to above
293  warning messages. Needed files were NOT created.])
294fi
295
296# Create output.
297AC_OUTPUT
298
299# Some more messages.
300AC_MSG_NOTICE([])
301AC_MSG_NOTICE([   Ready to compile the executables of svndigest $VERSION])
302AC_MSG_NOTICE([   The following flags and libs will be used:])
303AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
304AC_MSG_NOTICE([    Compiler:           $CXX])
305AC_MSG_NOTICE([    Preprocessor flags: $SD_CPPFLAGS $CPPFLAGS])
306AC_MSG_NOTICE([    C++ flags:          $SD_CXXFLAGS $CXXFLAGS])
307AC_MSG_NOTICE([    Linker flags:       $SD_LDFLAGS $LDFLAGS])
308AC_MSG_NOTICE([    LIBS:               $SD_LIBS $LIBS])
309AC_MSG_NOTICE([    PLPLOT_LDFLAGS:     $PLPLOT_LDFLAGS])
310AC_MSG_NOTICE([   +++++++++++++++++++++++++++++++++++++++++++++++])
311AC_MSG_NOTICE([])
312
313AC_MSG_NOTICE([Now type 'make && make check'.])
Note: See TracBrowser for help on using the repository browser.