Changeset 901 for trunk

Timestamp:

Nov 27, 2009, 1:47:36 AM (13 years ago)

Author:

Peter Johansson

Message:

refs #401 fixes #408

Modifications of detection of plplot;

• detection of plplot will not fail due to absent pkg-config
• if pkg-config is available and it finds pc file for plplot, then we use it to retrieve compiler/linker flags, otherwise we guess.
• new AC_DEFINE(HAVE_PLPLOT)
• configure now accepts --without-plplot (or --with-plplot=no) and tests are skipped (following build will currently not work)
• added a test linking against plplot library

File:

• trunk/configure.ac (modified) (6 diffs)

trunk/configure.ac

@@ -171 +171 @@
 
 # PLplot API checks
+# plplot_found can get values: skip, noheader, old, or nolib if an
+# error is detected.
 plplot_found="yes"
 plplot_version=5.9
@@ -177 +179 @@
   [AS_HELP_STRING([--with-plplot=DIR],[prefix for plplot developer files])],
   [DISTCHECK_CONFIGURE_FLAGS="$DISTCHECK_CONFIGURE_FLAGS --with-plplot=$withval"
-   PKG_CONFIG_PATH=${withval}/lib/pkgconfig${PATH_SEPARATOR}${PKG_CONFIG_PATH}
-   export PKG_CONFIG_PATH
+   AS_IF([test "x$withval" = "xno"], [ dnl
+     plplot_found=skip;
+   ], [ dnl
+     # help pkg-config find .pc file
+     PKG_CONFIG_PATH=${withval}/lib/pkgconfig${PATH_SEPARATOR}${PKG_CONFIG_PATH}
+     export PKG_CONFIG_PATH 
+   ])
   ])
 
-# copy flags if pkg-config finds plplot
-PKG_CHECK_EXISTS([plplotd-c++], [
-  YAT_CPP_ADD_FLAG([PLPLOT_CPPFLAGS], [`$PKG_CONFIG plplotd-c++ --cflags`])
-  YAT_LD_ADD_FLAG([PLPLOT_LDFLAGS], [`$PKG_CONFIG plplotd-c++ --libs-only-L`])
-  PLPLOT_LIBS="`$PKG_CONFIG plplotd-c++ --libs-only-l --libs-only-other`"
-],[
-  plplot_found=no-pkg-config
+use_plplot_pc="no"
+AS_IF([test "x$plplot_found" = "xyes" && test -n "$PKG_CONFIG"], [
+  AC_MSG_CHECKING([for plplotd-c++.pc])
+  AS_IF([$PKG_CONFIG --exists plplotd-c++], [
+    AC_MSG_RESULT([yes])
+    use_plplot_pc="yes"
+  ],[
+    AC_MSG_RESULT([no])
+    AC_MSG_WARN([cannot find plplotd-c++; 
+      please use --with-plplot with appropriate argument to get more accurate 
+      configuration.])
+  ])
+])
+
+AS_IF([test "x$plplot_found" = "xyes"], [
+  # copy flags if we have found pc file
+  AS_IF([test "$use_plplot_pc" = "yes"], [
+    YAT_CPP_ADD_FLAG([PLPLOT_CPPFLAGS], [`$PKG_CONFIG plplotd-c++ --cflags`])
+    YAT_LD_ADD_FLAG([PLPLOT_LDFLAGS], [`$PKG_CONFIG plplotd-c++ --libs-only-L`])
+    PLPLOT_LIBS="`$PKG_CONFIG plplotd-c++ --libs-only-l --libs-only-other`"
+  ],[
+    # otherwise guess
+    PLPLOT_LIBS="-lplplotcxxd -lplplotd";
+    AS_IF([test -n "$with_plplot" && test "x$with_plplot" != "xyes"], [
+      YAT_CPP_ADD_FLAG([PLPLOT_CPPFLAGS], [$with_plplot/include])
+      YAT_LD_ADD_FLAG([PLPLOT_LDFLAGS], [$with_plplot/libs])
+    ])
+  ])
 ])
                   
@@ -197 +225 @@
 ])
 
-AS_IF([test "x$plplot_found" = "xyes"], [
-  AS_IF([$PKG_CONFIG --atleast-version=$plplot_version plplotd-c++], [],[
-    plplot_found="nolib"
+
+AS_IF([test "x$plplot_found" = "xyes" && test -n "$PKG_CONFIG"], [
+  AC_MSG_CHECKING([plplot version >= $plplot_version])
+  AS_IF([$PKG_CONFIG --atleast-version=$plplot_version plplotd-c++], [
+    AC_MSG_RESULT([yes])
+  ],[
+    AC_MSG_RESULT([`$PKG_CONFIG --modversion= plplotd-c++`])
+    plplot_found="old"
   ])
 ])
+
+AS_IF([test "x$plplot_found" = "xyes" && test -n "$PKG_CONFIG"], [
+  save_LDFLAGS=$LDFLAGS
+  LDFLAGS="$PLPLOT_LDFLAGS $LDFLAGS"
+  save_LIBS=$LIBS
+  LIBS="$PLPLOT_LIBS $LIBS"
+  AC_MSG_CHECKING([for library containing plstream])
+  AC_LINK_IFELSE([AC_LANG_PROGRAM([@%:@include <plplot/plstream.h>],
+                                  [plstream pls(1,1,"svg", "conftest.svg")])], 
+                 [AC_MSG_RESULT([yes]);
+                  AC_DEFINE([HAVE_PLPLOT], [1], 
+                            [Define to 1 if you have plplot])], 
+                 [AC_MSG_RESULT([no])
+                  plplot_found=nolib;])
+])
 # restore variable
+LDFLAGS=$save_LDFLAGS
+LIBS=$save_LIBS
 export PKG_CONFIG_PATH=$save_PKG_CONFIG_PATH
 AC_SUBST(PLPLOT_CPPFLAGS)
@@ -212 +262 @@
 AM_CONDITIONAL([HAVE_SVN_WC], [test "$wc_found" = "yes"])
 AC_SUBST([wc_found])
-
-# Reset FLAGS
-APR_RESTORE_THE_ENVIRONMENT([CPPFLAGS], [DEFAULT_])
-APR_RESTORE_THE_ENVIRONMENT([CXXFLAGS], [DEFAULT_])
 
 # checking if we have test repo
@@ -235 +281 @@
 dnl maintainer make rukes from yat project
 YAT_SVN_RELEASE
+
+# Restore FLAGS
+APR_RESTORE_THE_ENVIRONMENT([CPPFLAGS], [DEFAULT_])
+APR_RESTORE_THE_ENVIRONMENT([CXXFLAGS], [DEFAULT_])
 
 AC_CONFIG_FILES([Makefile
@@ -304 +354 @@
 
 # Non-existing PLplot API is fatal -- sub-sequent compilation will fail.
-if (test "$plplot_found" = "noheader") ; then
-  AC_MSG_WARN([PLplot developer files cannot be found. Make sure PLplot
-  is installed.])
-  all_reqs_ok="false"
-elif (test "$plplot_found" = "nolib") ; then
-  AC_MSG_WARN([PLplot developer files found but not required API version.
-  Version at least $plplot_version is required. Please upgrade PLplot.])
-  all_reqs_ok="false"
-elif (test "$plplot_found" = "no-pkg-config") ; then
-  AC_MSG_WARN([cannot find pkg-config])
-  all_reqs_ok="false"
-fi
+AS_CASE([$plplot], 
+  [noheader],
+    [AC_MSG_WARN([
+    PLplot developer files cannot be found. Make sure PLplot is installed.])
+    all_reqs_ok="false"],
+  [old],
+    [AC_MSG_WARN([
+    PLplot developer files found but not required API version.
+    Version at least $plplot_version is required. Please upgrade PLplot.])
+    all_reqs_ok="false"],
+  [nolib],
+    [AC_MSG_WARN([
+    PLplot developer files found but linking against plplot library failed.])
+    all_reqs_ok="false"])
 
 if test $ac_cv_type_long_long_int != yes ; then