source: branches/0.10-stable/configure.ac @ 2957

Last change on this file since 2957 was 2957, checked in by Peter, 10 years ago

update copyright years

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 16.4 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 2957 2013-01-17 01:17:51Z peter $
4
5# Copyright (C) 2003 Daniel Dalevi, Jari Häkkinen
6# Copyright (C) 2004 Jari Häkkinen
7# Copyright (C) 2005, 2006 Jari Häkkinen, Peter Johansson
8# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson, Markus Ringnér
9# Copyright (C) 2009 Jari Häkkinen, Peter Johansson
10# Copyright (C) 2010, 2011 Peter Johansson
11# Copyright (C) 2012 Jari Häkkinen, Peter Johansson
12# Copyright (C) 2013 Peter Johansson
13#
14# This file is part of the yat library, http://dev.thep.lu.se/yat
15#
16# The yat library is free software; you can redistribute it
17# and/or modify it under the terms of the GNU General Public License as
18# published by the Free Software Foundation; either version 3 of the
19# License, or (at your option) any later version.
20#
21# The yat library is distributed in the hope that it will be useful,
22# but WITHOUT ANY WARRANTY; without even the implied warranty of
23# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
24# General Public License for more details.
25#
26# You should have received a copy of the GNU General Public License
27# along with yat. If not, see <http://www.gnu.org/licenses/>.
28#
29# If you grabbed the source from the subversion repository you should,
30# at top-level, execute:
31#     ./bootstrap
32# To push subsequent changes of this file into the build scripts you
33# must issue:
34#     autoreconf
35
36
37m4_include([m4/version.m4])
38AC_INIT([yat],[my_VERSION],[libyat-users@lists.sourceforge.net],,
39        [http://dev.thep.lu.se/yat])
40MY_VERSION
41AC_PREREQ(2.63)
42AC_CONFIG_SRCDIR([yat/utility/Matrix.h])
43AC_CONFIG_AUX_DIR([autotools])
44dnl arg below should be the same as in Makefile.am
45AC_CONFIG_MACRO_DIR([m4])
46AC_PREFIX_DEFAULT([/usr/local])
47
48# Set default htmldir to ${docdir}/html
49AS_IF([test $htmldir = '${docdir}'], [htmldir='${docdir}/html'])
50
51dnl FIXME remove when we assume autoconf 2.64
52m4_ifndef([AC_PACKAGE_URL],
53          [AC_DEFINE([PACKAGE_URL], ["http://dev.thep.lu.se/yat"],
54                     [Define to home page for this package])
55           AC_SUBST([PACKAGE_URL], ["http://dev.thep.lu.se/yat"])])
56
57AC_SUBST([YAT_LT_VERSION], [YAT_LT_VERSION_INFO])
58AC_DEFINE([YAT_VERSION], ["my_VERSION"], [version])
59
60AC_CONFIG_HEADERS([config.h])
61AM_INIT_AUTOMAKE([1.11 std-options color-tests parallel-tests
62                  silent-rules subdir-objects])
63
64dnl When fatal error are detected we use macro YAT_MSG_ERROR that
65dnl collects all error messages and aborts configure [just] before
66dnl creating output files with this message below plus collected
67dnl messages from YAT_MSG_ERROR calls.
68YAT_MSG_ERROR_PREPARE([
69        Some pre-requisites were not fulfilled, aborting configure.
70        Please consult the 'README' file for more information about what
71        is needed to compile yat and refer to messages below.
72])
73
74
75# Set default programming language
76AC_LANG(C++)
77
78# propagate selected configure variables to DISTCHECK_CONFIGURE_FLAGS
79for var in CPPFLAGS CXX CXXFLAGS CXXCPP LDFLAGS LIBS; do
80  eval isset=\${$var+set}
81  if test "$isset" = 'set' ; then
82    eval val=$`echo $var`
83    DISTCHECK_CONFIGURE_FLAGS="${DISTCHECK_CONFIGURE_FLAGS}'${var}=${val}' "
84  fi
85done
86AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
87
88# record if CXXFLAGS was set by user for further use below
89AS_IF([test "${CXXFLAGS+set}" = set], [
90  CXXFLAGS_set_by_user=yes
91],[
92  CXXFLAGS_set_by_user=no
93  # set CXXFLAGS to avoid expansion in AC_PROG_CXX
94  CXXFLAGS=
95])
96
97# Checks for programs.
98AC_PROG_CXX
99AC_PROG_SED
100AC_PROG_LIBTOOL
101
102# find the compiler vendor: gnu, intel, etc
103AX_COMPILER_VENDOR
104
105have_doxygen=no
106AC_PATH_PROG([DOXYGEN], [doxygen], [no])
107if test "$DOXYGEN" = "no"; then
108   AC_MSG_WARN([unable to find doxygen application])
109else
110   doxygen_min_version=1.5
111   AC_MSG_CHECKING([if doxygen is at least $doxygen_min_version])
112   doxygen_version=`$DOXYGEN --version`
113   AX_COMPARE_VERSION([$doxygen_version], [ge], [$doxygen_min_version],
114                      [have_doxygen=yes], [have_doxygen=old])
115   AC_MSG_RESULT([$doxygen_version])
116fi
117
118AC_SUBST(have_doxygen)
119AM_CONDITIONAL([DX_ENABLE_HTML], [test x$have_doxygen = xyes])
120
121# check for quiet_NaN support in OS
122# Check at run-time, but if we are cross-compiling fall back on a
123# compilation test
124AC_MSG_CHECKING([if std::numeric_limits<>::has_quiet_NaN is true])
125AC_RUN_IFELSE(
126  [AC_LANG_PROGRAM(
127    [@%:@include <limits>],
128    [return !std::numeric_limits<double>::has_quiet_NaN])],
129  [quiet_nan=yes
130   AC_MSG_RESULT($quiet_nan)],
131  [quiet_nan=no
132   AC_MSG_RESULT($quiet_nan)],
133  # if we are cross-compiling fall back on compilation test
134  [AC_MSG_RESULT(cross-compiling)
135   AC_MSG_CHECKING([for std::numeric_limits<>::quiet_NaN()])
136    AC_COMPILE_IFELSE(
137     [AC_LANG_PROGRAM(
138        [@%:@include <limits>
139         extern void f(double);],
140        [f(std::numeric_limits<double>::quiet_NaN())])],
141     [quiet_nan=yes],
142     [quiet_nan=no])
143   AC_MSG_RESULT($quiet_nan)])
144# No support for quiet NAN is fatal -- sub-sequent compilation, or execution
145# of created binary, will fail.
146AS_IF([test x"$quiet_nan" = x"no"], [
147  YAT_MSG_ERROR([dnl
148Support for quiet NAN required. yat will not work on this system!])
149])
150
151# Check for infinity support for doubles in OS
152# Check at run-time, but if we are cross-compiling fall back on a
153# compilation test
154AC_MSG_CHECKING([if std::numeric_limits<>::has_infinity is true])
155AC_RUN_IFELSE(
156  [AC_LANG_PROGRAM(
157    [@%:@include <limits>],
158    [return !std::numeric_limits<double>::has_infinity])],
159  [has_infinity=yes
160   AC_MSG_RESULT($has_infinity)],
161  [has_infinity=no
162   AC_MSG_RESULT($has_infinity)],
163  # if we are cross-compiling fall back on compilation test
164  [AC_MSG_RESULT(cross-compiling)
165   AC_MSG_CHECKING([for std::numeric_limits<>::infinity()])
166    AC_COMPILE_IFELSE(
167     [AC_LANG_PROGRAM(
168        [@%:@include <limits>
169         extern void f(double);],
170        [f(std::numeric_limits<double>::infinity())])],
171     [has_infinity=yes],
172     [has_infinity=no])
173   AC_MSG_RESULT($has_infinity)])
174# No support for infinity is fatal -- sub-sequent compilation, or execution
175# of created binary, will fail.
176AS_IF([test x"${has_infinity}" = x"no"], [
177YAT_MSG_ERROR([dnl
178Support for infinity required. yat will not work on this system!])
179])
180
181
182AC_MSG_CHECKING([g++ deprecation attribute])
183AC_COMPILE_IFELSE(
184   [AC_LANG_PROGRAM([[void f() __attribute__ ((deprecated));]],)],
185   [AC_DEFINE([YAT_HAVE_GCC_DEPRECATED], [1],
186              [Define if compiler supports deprecated attribute, as in g++ 4.0])
187    AC_MSG_RESULT([yes])],
188   [AC_MSG_RESULT([no])] )
189
190AC_MSG_CHECKING([if std::multiset::iterator is mutable])
191AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@%:@include <set>
192                                     @%:@include <vector>]],
193                                   [[std::set<std::vector<double> > s;
194                                     std::vector<double> v;
195                                     s.insert(v);
196                                     s.begin()->reserve(100);
197                                   ]])],
198                  [AC_DEFINE([MULTISET_ITERATOR_IS_MUTABLE], [1],
199                             [Define if std::multiset::iterator is mutable])
200                   AC_MSG_RESULT([yes])
201                  ],
202                  [AC_MSG_RESULT([no])] )
203
204# Save user-defined environment settings for later restoration
205APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
206APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
207APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
208APR_SAVE_THE_ENVIRONMENT(LIBS)
209
210# Checks for libraries.
211AC_MSG_NOTICE([checking for libraries])
212AC_CHECK_LIBM
213LIBS="$LIBM $LIBS"
214
215# find library implementing BLAS C API, or use gslcblas
216YAT_LIB_CBLAS([YAT_CBLAS_LIB=$CBLAS_LIB], [YAT_CBLAS_LIB=-lgslcblas])
217LIBS="$YAT_CBLAS_LIB $LIBS"
218
219# GNU Scientific Library, GSL http://www.gnu.org/software/gsl/, checks
220# Including AX_PATH_GSL macro from gsl.m4 distributed by GSL
221gsl_version="1.8"
222AC_SUBST(gsl_version)
223YAT_CHECK_GSL([$gsl_version],[LIBS="-lgsl $LIBS"],[YAT_MSG_ERROR([dnl
224GSL $gsl_version (or newer) not found. The GNU Scientific Library
225(GSL) library cannot be found. Please make sure GSL is
226installed. Please refer to warnings above for more details])
227])
228
229# Boost http://www.boost.org
230boost_version=1.35
231AC_SUBST(boost_version)
232AX_BOOST_BASE(["$boost_version"], [], [YAT_MSG_ERROR([dnl
233Boost ${boost_version} (or newer) not found. Please install boost, or provide
234CPPFLAGS=-I/path/to/boost])
235])
236# skip boost link tests if boost is not wanted (--without-boost)
237AS_IF([test x"$want_boost" = x"yes"],[
238  AX_BOOST_THREAD
239  AX_BOOST_SYSTEM
240  YAT_CPP_ADD_FLAG([CPPFLAGS], [$BOOST_CPPFLAGS])
241  YAT_LD_ADD_FLAG([LDFLAGS], [$BOOST_LDFLAGS])
242  # boost tests above only test compilation, so let's try link in the libs
243  LIBS="$LIBS $BOOST_THREAD_LIB $BOOST_SYSTEM_LIB"
244  AC_MSG_CHECKING([for thread_specific_ptr])
245  AC_LINK_IFELSE([AC_LANG_PROGRAM([@%:@include <boost/thread/tss.hpp>],
246                                  [boost::thread_specific_ptr<int> x;
247                                   x.reset(new int(1));])],
248                 [AC_MSG_RESULT([yes])],
249                 [AC_MSG_RESULT([no])
250                  YAT_MSG_ERROR([Boost thread library not found. Please install library boost-thread.])
251                 ])
252])
253
254# see tickets #648 #687
255AC_MSG_CHECKING([whether constructor in boost concept is supported])
256AC_COMPILE_IFELSE([
257  AC_LANG_PROGRAM(
258    [
259     @%:@include <boost/concept_check.hpp>
260     template <typename T>
261     class MyConcept
262     {
263     public:
264       MyConcept(void) {}
265       BOOST_CONCEPT_USAGE(MyConcept){}
266     };
267    ],[
268     MyConcept<double> x;
269     x = x;
270    ])
271  ],
272  [AC_MSG_RESULT([yes])
273   AC_DEFINE([YAT_HAVE_BOOST_CONCEPT_WITH_CONSTRUCTOR],[1],
274             [define if compiler supports boost concept with constructor])
275  ],
276  [AC_MSG_RESULT([no])]
277)
278
279
280# samtools API from http://samtools.sourceforge.net
281AC_ARG_WITH([samtools],
282            [AS_HELP_STRING([--without-samtools],
283                            [disable samtools support])],
284            [],
285            [with_samtools=yes])
286
287AS_IF([test x"$with_samtools" != x"no"], [
288  AC_CHECK_HEADER([zlib.h], [],
289    [YAT_MSG_ERROR([Header file 'zlib.h' was not found])])
290  AC_CHECK_LIB([z], [inflateEnd], [],
291    [YAT_MSG_ERROR([Library 'libz' was not found])])
292  YAT_CHECK_HEADER_BAM([],[YAT_MSG_ERROR([Header file 'bam.h' was not found])])
293  # try link against libbam
294  YAT_CHECK_LIBBAM([LIBS="$BAM_LIBS $LIBS"
295                    AC_DEFINE([HAVE_LIBBAM], [1],
296                              [Define to 1 if libbam is available])],
297    [YAT_MSG_ERROR([Library 'libbam' was not found])])
298  AC_PATH_PROG([SAMTOOLS], [samtools], [false])
299  AC_ARG_VAR([SAMTOOLS], [Tools for alignment in the SAM format])
300], [
301  SAMTOOLS=false
302])
303AM_CONDITIONAL([HAVE_LIBBAM], [test x"$with_samtools" = x"yes"])
304AM_CONDITIONAL([HAVE_SAMTOOLS], [test x"$SAMTOOLS" != x"false"])
305AC_SUBST([SAMTOOLS])
306AS_IF([test x"$SAMTOOLS" = x"false"], [], [
307  AC_DEFINE([HAVE_SAMTOOLS], [1], [Define if samtools executable is available])
308])
309
310#support for large files
311AC_SYS_LARGEFILE
312if test "$enable_largefile" = "no"; then
313  AC_DEFINE([YAT_LFS_DISABLED], 1,
314            [defined to 1 if large file support is disabled])
315fi
316
317AC_DEFINE([HAVE_INLINE], [1], [Define if inline is available on system])
318AC_ARG_ENABLE([debug],
319  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])])
320
321# If neither --enable-assert nor --disable-assert, set enable_assert
322# to same as enable_debug
323AC_ARG_ENABLE([assert],
324              [AS_HELP_STRING([--enable-assert], [turn on assertions])],
325              [], [enable_assert=$enable_debug])
326
327# we use prefix INTERNAL_ for variables that are solely needed for
328# building yat, i.e., they are not needed for a user of yat and are
329# not propagated to yat-config or yat.m4.
330AS_IF([test "${enable_debug}" = "yes"], [
331  AC_DEFINE([YAT_DEBUG], [1], [Define to activate yat assertioons])
332  YAT_CXX_ADD_FLAG([INTERNAL_CXXFLAGS], [-Wall -pedantic -g -O])
333], [
334  # avoid defining GSL_RANGE_CHECK_OFF if GSL_RANGE_CHECK is already defined
335  AC_CHECK_DECL([GSL_RANGE_CHECK],[],
336                [AC_DEFINE([GSL_RANGE_CHECK_OFF], [1],
337                           [Define to turn off GSL range checks])])
338  # If CXXFLAGS not set by user, set it to default value
339  AS_IF([test x$CXXFLAGS_set_by_user != xyes], [
340    YAT_CXX_ADD_FLAG([INTERNAL_CXXFLAGS],[-O3])
341  ])
342])
343
344AS_IF([test x"$enable_assert" = x"no"], [
345  AC_DEFINE([NDEBUG], [1], [Define to turn off assertions])
346])
347
348# turn off compiler warning #654 from intel compiler
349AS_IF([test x"$ax_cv_cxx_compiler_vendor" = x"intel"], [
350  YAT_CXX_ADD_FLAG([CXXFLAGS], ['-diag-disable 654'])
351])
352
353# Turns warnings to errors in compilation tests. Only put tests that
354# should be warning sensitive below this point. Can't find any
355# mechanism to revert AC_LANG_WERROR
356AC_LANG_WERROR
357
358# GCC 4.0.1 on OSX complains about -pthread (issue #713)
359AS_IF([AS_ECHO(["$CPPFLAGS"]) | $GREP '\-pthread' > /dev/null],
360  [AX_CHECK_PREPROC_FLAG([-pthread], [],
361     [CPPFLAGS=`AS_ECHO(["$CPPFLAGS"]) | $SED 's%-pthread%%'`],
362     [$INTERNAL_CPPFLAGS])
363])
364
365AS_IF([test x$enable_debug = xyes], [
366  # some versions of boost uses long long - turn off compiler warnings
367  # with -Wno-long-long
368  yat_save_CXXFLAGS=$CXXFLAGS
369  AC_MSG_CHECKING([whether boost uses long long])
370  CXXFLAGS="$INTERNAL_CXXFLAGS $CXXFLAGS"
371  AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
372    [
373      @%:@include <boost/iterator/transform_iterator.hpp>
374      @%:@include <boost/thread.hpp>
375      @%:@include <cmath>
376      @%:@include <functional>
377      @%:@include <vector>
378    ],[
379      using namespace boost;
380      typedef std::pointer_to_unary_function<double, double> F;
381      std::vector<double> vec;
382      transform_iterator<F, std::vector<double>::iterator>
383        i(vec.begin(), std::ptr_fun(fabs));
384      int x = boost::thread::hardware_concurrency();
385      ++x;
386    ])],
387  [AC_MSG_RESULT([no])],
388  [AC_MSG_RESULT([yes])
389   YAT_CXX_ADD_FLAG([INTERNAL_CXXFLAGS], [-Wno-long-long])
390  ])
391  # restore CXXFLAGS
392  CXXFLAGS=$yat_save_CXXFLAGS
393])
394
395#doxygen stuff
396DX_HTML_OUTPUT=html
397AC_SUBST(DX_HTML_OUTPUT)
398
399AC_CONFIG_FILES([build_support/gen_yat_pc.sh],
400                [chmod +x build_support/gen_yat_pc.sh])
401AC_CONFIG_FILES([build_support/tag_and_release.sh],
402                [chmod +x-w build_support/tag_and_release.sh])
403AC_CONFIG_FILES([Makefile
404     doc/doxygen.config
405     doc/first_page.doxygen
406     test/common_defs.sh
407])
408
409AC_CONFIG_HEADERS([yat/utility/config_public.h])
410# for the test suite
411yat_abs_top_srcdir=`cd $srcdir && pwd`
412AC_DEFINE_UNQUOTED([YAT_ABS_TOP_SRCDIR], ["$yat_abs_top_srcdir"],
413                   [Define to absolute path to top yat src dir])
414
415# Reset flags
416APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, YAT_)
417APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, YAT_)
418APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, YAT_)
419APR_RESTORE_THE_ENVIRONMENT(LIBS, YAT_)
420
421# YAT_LIBS minus cblas and math libraries
422YAT_PRIMARY_LIBS=
423for lib in $YAT_LIBS; do
424  AS_CASE([$lib], [$YAT_CBLAS_LIB], [],
425          [$LIBM], [],
426          [YAT_PRIMARY_LIBS="$YAT_PRIMARY_LIBS $lib"])
427done
428# workaround for ticket #736
429for lib in $BAM_LIBS; do
430  APR_REMOVEFROM([YAT_PRIMARY_LIBS], [$lib])
431done
432AC_SUBST(BAM_LIBS)
433AC_SUBST(YAT_PRIMARY_LIBS)
434AC_SUBST(YAT_LIBS)
435AC_SUBST(YAT_CBLAS_LIB)
436
437# set and AC_SUBST variables that are interpreted by Automake
438AM_CPPFLAGS="$INTERNAL_CPPFLAGS $YAT_CPPFLAGS"
439AM_CXXFLAGS="$INTERNAL_CXXFLAGS $YAT_CXXFLAGS"
440AM_LDFLAGS="$INTERNAL_LDFLAGS $YAT_LDFLAGS"
441
442AC_SUBST(AM_CPPFLAGS)
443AC_SUBST(AM_CXXFLAGS)
444AC_SUBST(AM_LDFLAGS)
445AC_SUBST(enable_static)
446
447YAT_SVN_RELEASE([am/maintainer.am])
448
449# set some variable for final message
450AS_CASE([$have_doxygen],
451        [yes], [doxygen_message=yes],
452        [no], [doxygen_message="no (doxygen not found)"],
453        [old], [doxygen_message="no (\`$DOXYGEN' too old)"],
454        [AC_MSG_WARN([unexpected value \$have_doxygen: '$have_doxygen'])
455         AS_BOX([Report this to ]AC_PACKAGE_BUGREPORT)
456        ])
457
458yat_gslcblas_message=
459AS_IF([test "x$YAT_CBLAS_LIB" = "x-lgslcblas"], [
460yat_gslcblas_message='
461  GSL CBLAS found. This is a reference implementation only.
462  Consider using hardware optimized BLAS.
463  ATLAS (http://math-atlas.sourceforge.net/) provides an
464  optimized BLAS library. It is supported by yat!
465'
466])
467
468# Create output.
469AC_OUTPUT
470
471
472# Some more messages.
473AC_MSG_RESULT([
474yat is configured as follows:
475
476  Build Shared Library: $enable_shared
477  Build Static Library: $enable_static
478  Build Documentation:  $doxygen_message
479  With Bam Support:     $with_samtools
480
481Options used to compile and link:
482  VERSION     = $VERSION
483  CXX         = $CXX
484  CPPFLAGS    = $CPPFLAGS
485  YAT_CPPFLAGS= $AM_CPPFLAGS
486  CXXFLAGS    = $CXXFLAGS
487  YAT_CXXFLAGS= $AM_CXXFLAGS
488  LD          = $LD
489  LDFLAGS     = $LDFLAGS
490  YAT_LDFLAGS = $AM_LDFLAGS
491  LIBS        = $LIBS
492  YAT_LIBS    = $YAT_LIBS
493${yat_gslcblas_message}dnl
494----------------------------------------------------------------
495Now type `make'. dnl
496])
Note: See TracBrowser for help on using the repository browser.