| 1 | ## Process this file with autoconf to produce a configure script. |
|---|
| 2 | ## |
|---|
| 3 | ## $Id: configure.ac 2042 2009-08-29 22:28:34Z peter $ |
|---|
| 4 | |
|---|
| 5 | # Copyright (C) 2003 Daniel Dalevi, Jari Häkkinen |
|---|
| 6 | # Copyright (C) 2004 Jari Häkkinen |
|---|
| 7 | # Copyright (C) 2005, 2006 Jari Häkkinen, Peter Johansson |
|---|
| 8 | # Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson, Markus Ringnér |
|---|
| 9 | # Copyright (C) 2009 Jari Häkkinen, Peter Johansson |
|---|
| 10 | # |
|---|
| 11 | # This file is part of the yat library, http://dev.thep.lu.se/yat |
|---|
| 12 | # |
|---|
| 13 | # The yat library is free software; you can redistribute it |
|---|
| 14 | # and/or modify it under the terms of the GNU General Public License as |
|---|
| 15 | # published by the Free Software Foundation; either version 3 of the |
|---|
| 16 | # License, or (at your option) any later version. |
|---|
| 17 | # |
|---|
| 18 | # The yat library is distributed in the hope that it will be useful, |
|---|
| 19 | # but WITHOUT ANY WARRANTY; without even the implied warranty of |
|---|
| 20 | # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
|---|
| 21 | # General Public License for more details. |
|---|
| 22 | # |
|---|
| 23 | # You should have received a copy of the GNU General Public License |
|---|
| 24 | # along with yat. If not, see <http://www.gnu.org/licenses/>. |
|---|
| 25 | # |
|---|
| 26 | # If you grabbed the source from the subversion repository you should, |
|---|
| 27 | # at top-level, execute: |
|---|
| 28 | # ./bootstrap |
|---|
| 29 | # To push subsequent changes of this file into the build scripts you |
|---|
| 30 | # must issue: |
|---|
| 31 | # autoreconf |
|---|
| 32 | |
|---|
| 33 | m4_include([m4/version.m4]) |
|---|
| 34 | AC_INIT([yat],[YAT_VERSION],[jari@thep.lu.se]) |
|---|
| 35 | AC_PREREQ(2.61) |
|---|
| 36 | AC_CONFIG_SRCDIR([yat/utility/Matrix.h]) |
|---|
| 37 | AC_CONFIG_AUX_DIR([autotools]) |
|---|
| 38 | dnl arg below should be the same as in Makefile.am |
|---|
| 39 | AC_CONFIG_MACRO_DIR([m4]) |
|---|
| 40 | AC_PREFIX_DEFAULT([/usr/local]) |
|---|
| 41 | |
|---|
| 42 | AC_SUBST([YAT_LT_VERSION], [YAT_LT_VERSION_INFO]) |
|---|
| 43 | AC_SUBST([YAT_MAJOR_VERSION], [MAJOR_VERSION]) |
|---|
| 44 | AC_SUBST([YAT_MINOR_VERSION], [MINOR_VERSION]) |
|---|
| 45 | AC_SUBST([YAT_PATCH_VERSION], [PATCH_VERSION]) |
|---|
| 46 | AC_SUBST([YAT_DEV_BUILD], [DEV_BUILD]) |
|---|
| 47 | |
|---|
| 48 | AC_CONFIG_HEADER([config.h]) |
|---|
| 49 | AM_INIT_AUTOMAKE([1.10 std-options]) |
|---|
| 50 | |
|---|
| 51 | # Set default programming language |
|---|
| 52 | AC_LANG(C++) |
|---|
| 53 | |
|---|
| 54 | # propagate selected configure variables to DISTCHECK_CONFIGURE_FLAGS |
|---|
| 55 | for var in CPPFLAGS CXX CXXFLAGS CXXCPP LDFLAGS LIBS; do |
|---|
| 56 | eval isset=\${$var+set} |
|---|
| 57 | if test "$isset" = 'set' ; then |
|---|
| 58 | eval val=$`echo $var` |
|---|
| 59 | DISTCHECK_CONFIGURE_FLAGS="${DISTCHECK_CONFIGURE_FLAGS}'${var}=${val}' " |
|---|
| 60 | fi |
|---|
| 61 | done |
|---|
| 62 | AC_SUBST(DISTCHECK_CONFIGURE_FLAGS) |
|---|
| 63 | |
|---|
| 64 | # Let user overide default CXXFLAGS |
|---|
| 65 | if test "${CXXFLAGS+set}" != set; then |
|---|
| 66 | CXXFLAGS="" # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX |
|---|
| 67 | fi |
|---|
| 68 | # Checks for programs. |
|---|
| 69 | AC_PROG_CXX |
|---|
| 70 | AC_PROG_INSTALL |
|---|
| 71 | AC_PROG_SED |
|---|
| 72 | AC_PROG_LIBTOOL |
|---|
| 73 | # fall back to echo unless ECHO not already set (by libtool) |
|---|
| 74 | AS_IF([test "x$ECHO" = x], [ECHO=echo]) |
|---|
| 75 | AC_SUBST(ECHO) |
|---|
| 76 | |
|---|
| 77 | AC_CHECK_PROGS([MD5], [md5sum md5 md5deep], [no]) |
|---|
| 78 | |
|---|
| 79 | AC_MSG_NOTICE(dnl |
|---|
| 80 | [checking whether tools for generating documentation are available]) |
|---|
| 81 | |
|---|
| 82 | have_doxygen=no |
|---|
| 83 | dx_enable_latex=no |
|---|
| 84 | dx_enable_dvi=no |
|---|
| 85 | dx_enable_ps=no |
|---|
| 86 | dx_enable_pdf=no |
|---|
| 87 | AC_PATH_PROG([DOXYGEN], [doxygen], [no]) |
|---|
| 88 | if test "$DOXYGEN" = "no"; then |
|---|
| 89 | AC_MSG_WARN([unable to find doxygen application]) |
|---|
| 90 | else |
|---|
| 91 | doxygen_min_version=1.5 |
|---|
| 92 | AC_MSG_CHECKING([if doxygen is at least $doxygen_min_version]) |
|---|
| 93 | doxygen_version=`$DOXYGEN --version` |
|---|
| 94 | AX_COMPARE_VERSION([$doxygen_version], [ge], [$doxygen_min_version], |
|---|
| 95 | [have_doxygen=yes]) |
|---|
| 96 | AC_MSG_RESULT([$doxygen_version]) |
|---|
| 97 | dx_enable_latex=yes |
|---|
| 98 | # doxygen 1.5.8 has a bug for latex output and enums |
|---|
| 99 | AS_IF([test $have_doxygen = yes], |
|---|
| 100 | [AX_COMPARE_VERSION([$doxygen_version], [eq], [1.5.8], |
|---|
| 101 | [dx_enable_latex=no])]) |
|---|
| 102 | fi |
|---|
| 103 | |
|---|
| 104 | # we need latex output to generate dvi, ps, and pdf |
|---|
| 105 | AS_IF([test $dx_enable_latex = yes], |
|---|
| 106 | [dx_enable_pdf=yes |
|---|
| 107 | ACLTX_PROG_PDFLATEX([dx_enable_pdf=no]) |
|---|
| 108 | ACLTX_PROG_MAKEINDEX([dx_enable_pdf=no]) |
|---|
| 109 | dx_enable_dvi=yes |
|---|
| 110 | ACLTX_PROG_LATEX([dx_enable_dvi=no]) |
|---|
| 111 | # ps needs dvi |
|---|
| 112 | dx_enable_ps=$dx_enable_dvi |
|---|
| 113 | ACLTX_PROG_DVIPS([dx_enable_ps=no]) |
|---|
| 114 | ] |
|---|
| 115 | ) |
|---|
| 116 | |
|---|
| 117 | AC_SUBST(have_doxygen) |
|---|
| 118 | AM_CONDITIONAL([DX_ENABLE_HTML], [test x$have_doxygen = xyes]) |
|---|
| 119 | AM_CONDITIONAL([DX_ENABLE_LATEX], [test x$dx_enable_latex = xyes]) |
|---|
| 120 | AM_CONDITIONAL([DX_ENABLE_DVI], [test x$dx_enable_dvi = xyes]) |
|---|
| 121 | AM_CONDITIONAL([DX_ENABLE_PS], [test x$dx_enable_ps = xyes]) |
|---|
| 122 | AM_CONDITIONAL([DX_ENABLE_PDF], [test x$dx_enable_pdf = xyes]) |
|---|
| 123 | AC_CONFIG_FILES([test/documentation_test.sh], |
|---|
| 124 | [chmod +x test/documentation_test.sh]) |
|---|
| 125 | |
|---|
| 126 | # check for quiet_NaN support in OS |
|---|
| 127 | # Check at run-time, but if we are cross-compiling fall back on a |
|---|
| 128 | # compilation test |
|---|
| 129 | AC_MSG_CHECKING([if std::numeric_limits<>::has_quiet_NaN is true]) |
|---|
| 130 | AC_RUN_IFELSE( |
|---|
| 131 | [AC_LANG_PROGRAM( |
|---|
| 132 | [@%:@include <limits>], |
|---|
| 133 | [return !std::numeric_limits<double>::has_quiet_NaN])], |
|---|
| 134 | [quiet_nan=yes |
|---|
| 135 | AC_MSG_RESULT($quiet_nan)], |
|---|
| 136 | [quiet_nan=no |
|---|
| 137 | AC_MSG_RESULT($quiet_nan)], |
|---|
| 138 | # if we are cross-compiling fall back on compilation test |
|---|
| 139 | [AC_MSG_RESULT(cross-compiling) |
|---|
| 140 | AC_MSG_CHECKING([for std::numeric_limits<>::quiet_NaN()]) |
|---|
| 141 | AC_COMPILE_IFELSE( |
|---|
| 142 | [AC_LANG_PROGRAM( |
|---|
| 143 | [@%:@include <limits> |
|---|
| 144 | extern void f(double);], |
|---|
| 145 | [f(std::numeric_limits<double>::quiet_NaN())])], |
|---|
| 146 | [quiet_nan=yes], |
|---|
| 147 | [quiet_nan=no]) |
|---|
| 148 | AC_MSG_RESULT($quiet_nan)]) |
|---|
| 149 | # Check for infinity support for doubles in OS |
|---|
| 150 | # Check at run-time, but if we are cross-compiling fall back on a |
|---|
| 151 | # compilation test |
|---|
| 152 | AC_MSG_CHECKING([if std::numeric_limits<>::has_infinity is true]) |
|---|
| 153 | AC_RUN_IFELSE( |
|---|
| 154 | [AC_LANG_PROGRAM( |
|---|
| 155 | [@%:@include <limits>], |
|---|
| 156 | [return !std::numeric_limits<double>::has_infinity])], |
|---|
| 157 | [has_infinity=yes |
|---|
| 158 | AC_MSG_RESULT($has_infinity)], |
|---|
| 159 | [has_infinity=no |
|---|
| 160 | AC_MSG_RESULT($has_infinity)], |
|---|
| 161 | # if we are cross-compiling fall back on compilation test |
|---|
| 162 | [AC_MSG_RESULT(cross-compiling) |
|---|
| 163 | AC_MSG_CHECKING([for std::numeric_limits<>::infinity()]) |
|---|
| 164 | AC_COMPILE_IFELSE( |
|---|
| 165 | [AC_LANG_PROGRAM( |
|---|
| 166 | [@%:@include <limits> |
|---|
| 167 | extern void f(double);], |
|---|
| 168 | [f(std::numeric_limits<double>::infinity())])], |
|---|
| 169 | [has_infinity=yes], |
|---|
| 170 | [has_infinity=no]) |
|---|
| 171 | AC_MSG_RESULT($has_infinity)]) |
|---|
| 172 | |
|---|
| 173 | AC_MSG_CHECKING([g++ deprecation attribute]) |
|---|
| 174 | AC_COMPILE_IFELSE( |
|---|
| 175 | [AC_LANG_PROGRAM([[void f() __attribute__ ((deprecated));]],)], |
|---|
| 176 | [AC_DEFINE([YAT_HAVE_GCC_DEPRECATED], [1], |
|---|
| 177 | [Define if compiler supports deprecated attribute, as in g++ 4.0]) |
|---|
| 178 | AC_MSG_RESULT([yes])], |
|---|
| 179 | [AC_MSG_RESULT([no])] ) |
|---|
| 180 | |
|---|
| 181 | AC_MSG_CHECKING([if std::multiset::iterator is mutable]) |
|---|
| 182 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@%:@include <set> |
|---|
| 183 | @%:@include <vector>]], |
|---|
| 184 | [[std::set<std::vector<double> > s; |
|---|
| 185 | std::vector<double> v; |
|---|
| 186 | s.insert(v); |
|---|
| 187 | s.begin()->reserve(100); |
|---|
| 188 | ]])], |
|---|
| 189 | [AC_DEFINE([MULTISET_ITERATOR_IS_MUTABLE], [1], |
|---|
| 190 | [Define if std::multiset::iterator is mutable]) |
|---|
| 191 | AC_MSG_RESULT([yes]) |
|---|
| 192 | ], |
|---|
| 193 | [AC_MSG_RESULT([no])] ) |
|---|
| 194 | |
|---|
| 195 | # Save user-defined environment settings for later restoration |
|---|
| 196 | APR_SAVE_THE_ENVIRONMENT(CPPFLAGS) |
|---|
| 197 | APR_SAVE_THE_ENVIRONMENT(CXXFLAGS) |
|---|
| 198 | APR_SAVE_THE_ENVIRONMENT(LDFLAGS) |
|---|
| 199 | |
|---|
| 200 | # Checks for libraries. |
|---|
| 201 | AC_MSG_NOTICE([checking for libraries]) |
|---|
| 202 | AC_CHECK_LIBM |
|---|
| 203 | AS_IF([test "x$LIBM" != x], [LIBS="$LIBM $LIBS"]) |
|---|
| 204 | # searching for cblas. Priority 1) find a cblas library, 2) find ATLAS |
|---|
| 205 | # generated cblas, and 3) fall back to GSL cblas implementation. If |
|---|
| 206 | # partial ATLAS is detected the configure script fails. |
|---|
| 207 | cblas_found="no" # cblas_found may get values yes or no |
|---|
| 208 | # atlas_found may get values yes, no, or partial. In some cases |
|---|
| 209 | # partial atlas may be installed |
|---|
| 210 | atlas_found="no" |
|---|
| 211 | gslcblas_found="no" # gslcblas_found may get values yes or no |
|---|
| 212 | AC_SEARCH_LIBS(cblas_sdsdot,cblas,cblas_found="yes", |
|---|
| 213 | AC_SEARCH_LIBS(ATL_sdsdot,atlas, |
|---|
| 214 | AC_SEARCH_LIBS(cblas_srot,cblas,atlas_found="yes", |
|---|
| 215 | atlas_found="partial",-m64), |
|---|
| 216 | [gslcblas_found="yes"],-m64),) |
|---|
| 217 | |
|---|
| 218 | # GNU Scientific Library, GSL http://www.gnu.org/software/gsl/, checks |
|---|
| 219 | # Including AX_PATH_GSL macro from gsl.m4 distributed by GSL |
|---|
| 220 | gsl_found="no" |
|---|
| 221 | gsl_version="1.8" |
|---|
| 222 | AC_SUBST(gsl_version) |
|---|
| 223 | AX_PATH_GSL([${gsl_version}],[gsl_found="yes"],[gsl_version_check="no"]) |
|---|
| 224 | if test "$gsl_found" = "yes"; then |
|---|
| 225 | if test "x$gslcblas_found" = "xyes"; then |
|---|
| 226 | LIBS="-lgslcblas $LIBS"; |
|---|
| 227 | fi |
|---|
| 228 | LIBS="-lgsl $LIBS" |
|---|
| 229 | # grep words starting with '-L' in other words LDFLAGS |
|---|
| 230 | for i in $GSL_LIBS; do |
|---|
| 231 | if test ${i:0:2} = "-L"; then |
|---|
| 232 | YAT_LD_ADD_FLAG([LDFLAGS], [$i]) |
|---|
| 233 | fi |
|---|
| 234 | done |
|---|
| 235 | YAT_CPP_ADD_FLAG([CPPFLAGS], [`$GSL_CONFIG --cflags`]) |
|---|
| 236 | else |
|---|
| 237 | gslcblas="no"; |
|---|
| 238 | fi |
|---|
| 239 | |
|---|
| 240 | # Boost http://www.boost.org |
|---|
| 241 | boost_version=1.33 |
|---|
| 242 | AC_SUBST(boost_version) |
|---|
| 243 | AX_BOOST_BASE(["$boost_version"]) |
|---|
| 244 | boost_version_check=$succeeded; |
|---|
| 245 | YAT_CPP_ADD_FLAG([CPPFLAGS], [$BOOST_CPPFLAGS]) |
|---|
| 246 | |
|---|
| 247 | #support for large files |
|---|
| 248 | AC_SYS_LARGEFILE |
|---|
| 249 | if test "$enable_largefile" = "no"; then |
|---|
| 250 | AC_DEFINE([YAT_LFS_DISABLED], 1, |
|---|
| 251 | [defined to 1 if large file support is disabled]) |
|---|
| 252 | fi |
|---|
| 253 | |
|---|
| 254 | # we use AM_* for variables that are solely needed for building yat, |
|---|
| 255 | # i.e., they are not needed for a user of yat and are not propagated |
|---|
| 256 | # to yat-config or yat.m4. |
|---|
| 257 | YAT_CXX_ADD_FLAG([AM_CXXFLAGS], [-Wall -pedantic]) |
|---|
| 258 | YAT_CPP_ADD_FLAG([AM_CPPFLAGS], [-DHAVE_INLINE=1]) |
|---|
| 259 | AC_ARG_ENABLE([debug], |
|---|
| 260 | [AS_HELP_STRING([--enable-debug],[turn on debug options and code])]) |
|---|
| 261 | if test "${enable_debug}" = "yes" ; then |
|---|
| 262 | YAT_CPP_ADD_FLAG([AM_CPPFLAGS], [-DYAT_DEBUG=1]) |
|---|
| 263 | YAT_CXX_ADD_FLAG([AM_CXXFLAGS], [-g -O]) |
|---|
| 264 | else |
|---|
| 265 | YAT_CPP_ADD_FLAG([AM_CPPFLAGS], [-DGSL_RANGE_CHECK_OFF -DNDEBUG]) |
|---|
| 266 | YAT_CXX_ADD_FLAG([AM_CXXFLAGS], [-O3]) |
|---|
| 267 | fi |
|---|
| 268 | |
|---|
| 269 | AC_ARG_ENABLE([svn-support], |
|---|
| 270 | [AS_HELP_STRING([--enable-svn-support], |
|---|
| 271 | [enable svn support - used by yat maintainer])]) |
|---|
| 272 | |
|---|
| 273 | if test "x$enable_svn-support" = "xyes"; then |
|---|
| 274 | svn_error_msg="svn support cannot be enabled:" |
|---|
| 275 | AS_IF([test "x$MD5" = "xno"], |
|---|
| 276 | [AC_MSG_ERROR([$svn_error_msg tool to create md5 file not found])]) |
|---|
| 277 | |
|---|
| 278 | AC_CHECK_FILE([$srcdir/.svn], , |
|---|
| 279 | AC_MSG_ERROR([$svn_error_msg `$srcdir' is not an svn wc.])) |
|---|
| 280 | AC_PATH_PROG([PERL], [perl], [no]) |
|---|
| 281 | if test "x$PERL" = "xno"; then |
|---|
| 282 | AC_MSG_ERROR([$svn_error_msg perl executable not found.]) |
|---|
| 283 | fi |
|---|
| 284 | AC_PROG_PERL_MODULES([strict Cwd File::Path Getopt::Long Pod::Usage], , |
|---|
| 285 | [AC_MSG_ERROR([$svn_error_msg missing some perl module.])]) |
|---|
| 286 | fi |
|---|
| 287 | AM_CONDITIONAL([ENABLE_SVN_SUPPORT], [test "x$enable_svn_support" = "xyes"]) |
|---|
| 288 | |
|---|
| 289 | |
|---|
| 290 | # yat specific settings |
|---|
| 291 | YAT_LIBNAME="yat" |
|---|
| 292 | YAT_LIB_LOCATION="yat" |
|---|
| 293 | AC_SUBST(YAT_LIBNAME) |
|---|
| 294 | AC_SUBST(YAT_LIB) |
|---|
| 295 | AC_SUBST(YAT_LIB_LOCATION) |
|---|
| 296 | |
|---|
| 297 | #doxygen stuff |
|---|
| 298 | DX_HTML_OUTPUT=html |
|---|
| 299 | DX_LATEX_OUTPUT=latex |
|---|
| 300 | AC_SUBST(DX_HTML_OUTPUT) |
|---|
| 301 | AC_SUBST(DX_LATEX_OUTPUT) |
|---|
| 302 | |
|---|
| 303 | |
|---|
| 304 | AC_CONFIG_FILES([test/create_yathello.sh], [chmod +x test/create_yathello.sh]) |
|---|
| 305 | AC_CONFIG_FILES([Makefile |
|---|
| 306 | build_support/Makefile |
|---|
| 307 | doc/Makefile |
|---|
| 308 | doc/doxygen.config |
|---|
| 309 | doc/first_page.doxygen |
|---|
| 310 | m4/Makefile |
|---|
| 311 | test/Makefile |
|---|
| 312 | test/environment.h |
|---|
| 313 | test/data/Makefile |
|---|
| 314 | yat/Makefile |
|---|
| 315 | yat/classifier/Makefile |
|---|
| 316 | yat/normalizer/Makefile |
|---|
| 317 | yat/random/Makefile |
|---|
| 318 | yat/regression/Makefile |
|---|
| 319 | yat/statistics/Makefile |
|---|
| 320 | yat/utility/version.h |
|---|
| 321 | yat/utility/Makefile]) |
|---|
| 322 | |
|---|
| 323 | AC_CONFIG_HEADER([yat/utility/config_public.h]) |
|---|
| 324 | |
|---|
| 325 | # Print failure status information about selected items, and exit if |
|---|
| 326 | # fatal errors were encountered. No output will be created if |
|---|
| 327 | # configure is halted prematurely. |
|---|
| 328 | |
|---|
| 329 | # used to trigger exit before creation of output |
|---|
| 330 | all_reqs_ok="true" |
|---|
| 331 | |
|---|
| 332 | # No support for quiet NAN is fatal -- sub-sequent compilation, or execution |
|---|
| 333 | # of created binary, will fail. |
|---|
| 334 | if test "${quiet_nan}" = "no" ; then |
|---|
| 335 | all_reqs_ok="false" |
|---|
| 336 | AC_MSG_WARN([ |
|---|
| 337 | Support for quiet NAN required. |
|---|
| 338 | Yat will not work on this system!]) |
|---|
| 339 | fi |
|---|
| 340 | |
|---|
| 341 | # No support for infinity is fatal -- sub-sequent compilation, or execution |
|---|
| 342 | # of created binary, will fail. |
|---|
| 343 | if test "${has_infinity}" = "no" ; then |
|---|
| 344 | all_reqs_ok="false" |
|---|
| 345 | AC_MSG_WARN([ |
|---|
| 346 | Support for infinity required. |
|---|
| 347 | Yat will not work on this system!]) |
|---|
| 348 | fi |
|---|
| 349 | |
|---|
| 350 | |
|---|
| 351 | # Non-existing BLAS is fatal -- sub-sequent compilation will fail. |
|---|
| 352 | if test "${cblas_found}" = "no" -a "${atlas_found}" = "no" -a "${gslcblas_found}" = "no"; then |
|---|
| 353 | all_reqs_ok="false" |
|---|
| 354 | AC_MSG_WARN([ |
|---|
| 355 | cBLAS not found. The C implementation of Basic Linear Algebra |
|---|
| 356 | Subprograms (cBLAS) library cannot be found. Please make sure |
|---|
| 357 | cBLAS is installed.]) |
|---|
| 358 | fi |
|---|
| 359 | if test "${atlas_found}" = "partial"; then |
|---|
| 360 | all_reqs_ok="false" |
|---|
| 361 | AC_MSG_WARN([ |
|---|
| 362 | Partial ATLAS BLAS library found. Please repair your installation.]) |
|---|
| 363 | fi |
|---|
| 364 | |
|---|
| 365 | # Non-existing GSL is fatal -- sub-sequent compilation will fail. |
|---|
| 366 | if test "${gsl_found}" = "no" ; then |
|---|
| 367 | all_reqs_ok="false" |
|---|
| 368 | if test "${gsl_version_check}" = "no" ; then |
|---|
| 369 | AC_MSG_WARN([ |
|---|
| 370 | GSL found but not the required version. Please install |
|---|
| 371 | GSL version ${gsl_version} or later]) |
|---|
| 372 | else |
|---|
| 373 | AC_MSG_WARN([ |
|---|
| 374 | GSL not found. The GNU Scientific Library (GSL) library cannot be |
|---|
| 375 | found. Please make sure GSL is installed.]) |
|---|
| 376 | fi |
|---|
| 377 | fi |
|---|
| 378 | |
|---|
| 379 | # Too old Boost is fatal -- sub-sequent compilation will fail. |
|---|
| 380 | if test "${boost_version_check}" != "yes" ; then |
|---|
| 381 | all_reqs_ok="false" |
|---|
| 382 | AC_MSG_WARN([ |
|---|
| 383 | Boost found but not the required version. Please install |
|---|
| 384 | Boost version ${boost_version} or later]) |
|---|
| 385 | fi |
|---|
| 386 | |
|---|
| 387 | if (test "$all_reqs_ok" = "false") ; then |
|---|
| 388 | AC_MSG_FAILURE([ |
|---|
| 389 | Some pre-requisites were not fulfilled, aborting configure. |
|---|
| 390 | Please consult the 'README' file for more information about what |
|---|
| 391 | is needed to compile yat and refer to above warning messages. |
|---|
| 392 | Needed files were NOT created.]) |
|---|
| 393 | fi |
|---|
| 394 | |
|---|
| 395 | # Reset flags |
|---|
| 396 | APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_) |
|---|
| 397 | APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_) |
|---|
| 398 | APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_) |
|---|
| 399 | |
|---|
| 400 | AM_CPPFLAGS="-I\$(top_srcdir) $AM_CPPFLAGS $EXTRA_CPPFLAGS" |
|---|
| 401 | AM_CXXFLAGS="$AM_CXXFLAGS $EXTRA_CXXFLAGS" |
|---|
| 402 | AM_LDFLAGS="$AM_LDFLAGS $EXTRA_LDFLAGS" |
|---|
| 403 | |
|---|
| 404 | AC_SUBST(AM_CPPFLAGS) |
|---|
| 405 | AC_SUBST(AM_CXXFLAGS) |
|---|
| 406 | AC_SUBST(AM_LDFLAGS) |
|---|
| 407 | |
|---|
| 408 | # Create output. |
|---|
| 409 | AC_OUTPUT |
|---|
| 410 | |
|---|
| 411 | # Some more messages. |
|---|
| 412 | AC_MSG_NOTICE([]) |
|---|
| 413 | AC_MSG_NOTICE([ Ready to compile the yat library]) |
|---|
| 414 | AS_IF([test x$have_doxygen = xyes], |
|---|
| 415 | [AC_MSG_NOTICE([ Documentation will be generated in the following formats:]) |
|---|
| 416 | AC_MSG_NOTICE([ html]) |
|---|
| 417 | AS_IF([test x$dx_enable_pdf = xyes], [AC_MSG_NOTICE([ pdf])]) |
|---|
| 418 | AS_IF([test x$dx_enable_ps = xyes], [AC_MSG_NOTICE([ ps])]) |
|---|
| 419 | AS_IF([test x$dx_enable_dvi = xyes], [AC_MSG_NOTICE([ dvi])]) |
|---|
| 420 | ], |
|---|
| 421 | [AC_MSG_NOTICE([Generation of documentation is disabled]) |
|---|
| 422 | AC_MSG_NOTICE([doxygen could not be found]) |
|---|
| 423 | ]) |
|---|
| 424 | AC_MSG_NOTICE() |
|---|
| 425 | AC_MSG_NOTICE([ The following flags and libraries will be used:]) |
|---|
| 426 | AC_MSG_NOTICE([ +++++++++++++++++++++++++++++++++++++++++++++++]) |
|---|
| 427 | AC_MSG_NOTICE([ CPPFLAGS=$CPPFLAGS]) |
|---|
| 428 | AC_MSG_NOTICE([ AM_CPPFLAGS=$AM_CPPFLAGS]) |
|---|
| 429 | AC_MSG_NOTICE([ CXXFLAGS=$CXXFLAGS]) |
|---|
| 430 | AC_MSG_NOTICE([ AM_CXXFLAGS=$AM_CXXFLAGS]) |
|---|
| 431 | AC_MSG_NOTICE([ LDFLAGS=$LDFLAGS]) |
|---|
| 432 | AC_MSG_NOTICE([ AM_LDFLAGS=$AM_LDFLAGS]) |
|---|
| 433 | AC_MSG_NOTICE([ LIBS=$LIBS]) |
|---|
| 434 | AC_MSG_NOTICE([ +++++++++++++++++++++++++++++++++++++++++++++++]) |
|---|
| 435 | AC_MSG_NOTICE([]) |
|---|
| 436 | if test "${gslcblas_found}" = "yes"; then |
|---|
| 437 | AC_MSG_NOTICE([ GSL BLAS found. This is a reference implementation only.]) |
|---|
| 438 | AC_MSG_NOTICE([ Consider using hardware optimized BLAS.]) |
|---|
| 439 | AC_MSG_NOTICE([ ATLAS (http://math-atlas.sourceforge.net/) provides an]) |
|---|
| 440 | AC_MSG_NOTICE([ optimized BLAS library. It is supported by yat!]) |
|---|
| 441 | AC_MSG_NOTICE([]) |
|---|
| 442 | fi |
|---|
| 443 | AC_MSG_NOTICE([ Now type 'make && make check'.]) |
|---|
