source: tags/0.5.2/configure.ac @ 1872

Last change on this file since 1872 was 1799, checked in by Peter, 13 years ago

corrected handling of --disable-svn-support

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 14.4 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 1799 2009-02-17 17:16:21Z peter $
4
5# Copyright (C) 2003 Daniel Dalevi, Jari Häkkinen
6# Copyright (C) 2004 Jari Häkkinen
7# Copyright (C) 2005, 2006 Jari Häkkinen, Peter Johansson
8# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson, Markus Ringnér
9# Copyright (C) 2009 Jari Häkkinen, Peter Johansson
10#
11# This file is part of the yat library, http://dev.thep.lu.se/yat
12#
13# The yat library is free software; you can redistribute it
14# and/or modify it under the terms of the GNU General Public License as
15# published by the Free Software Foundation; either version 3 of the
16# License, or (at your option) any later version.
17#
18# The yat library is distributed in the hope that it will be useful,
19# but WITHOUT ANY WARRANTY; without even the implied warranty of
20# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
21# General Public License for more details.
22#
23# You should have received a copy of the GNU General Public License
24# along with yat. If not, see <http://www.gnu.org/licenses/>.
25#
26# If you grabbed the source from the subversion repository you should,
27# at top-level, execute:
28#     ./bootstrap
29# To push subsequent changes of this file into the build scripts you
30# must issue:
31#     autoreconf
32
33m4_include([m4/version.m4])
34AC_INIT([yat],[YAT_VERSION],[jari@thep.lu.se])
35AC_PREREQ(2.61)
36AC_CONFIG_SRCDIR([yat/utility/Matrix.h])
37AC_CONFIG_AUX_DIR([autotools])
38dnl arg below should be the same as in Makefile.am
39AC_CONFIG_MACRO_DIR([m4])
40AC_PREFIX_DEFAULT([/usr/local])
41
42AC_SUBST([YAT_LT_VERSION], [YAT_LT_VERSION_INFO])
43AC_SUBST([YAT_MAJOR_VERSION], [MAJOR_VERSION])
44AC_SUBST([YAT_MINOR_VERSION], [MINOR_VERSION])
45AC_SUBST([YAT_PATCH_VERSION], [PATCH_VERSION])
46AC_SUBST([YAT_DEV_BUILD], [DEV_BUILD])
47
48AC_CONFIG_HEADER([config.h])
49AM_INIT_AUTOMAKE([1.10 std-options])
50
51# Set default programming language
52AC_LANG(C++)
53
54# propagate selected configure variables to DISTCHECK_CONFIGURE_FLAGS
55for var in CPPFLAGS CXX CXXFLAGS CXXCPP LDFLAGS LIBS; do
56  eval isset=\${$var+set}
57  if test "$isset" = 'set' ; then
58    eval val=$`echo $var`
59    DISTCHECK_CONFIGURE_FLAGS="${DISTCHECK_CONFIGURE_FLAGS}'${var}=${val}' "
60  fi
61done
62AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
63
64# Let user overide default CXXFLAGS
65if test "${CXXFLAGS+set}" != set; then
66  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
67fi
68# Checks for programs.
69AC_PROG_CXX
70AC_PROG_INSTALL
71AC_PROG_SED
72AC_PROG_LIBTOOL
73# fall back to echo unless ECHO not already set (by libtool)
74AS_IF([test "x$ECHO" = x], [ECHO=echo])
75AC_SUBST(ECHO)
76
77AC_MSG_NOTICE(dnl
78[checking whether tools for generating documentation are available])
79
80have_dox_tools="yes"
81AC_PATH_PROG([DOXYGEN], [doxygen], [no])
82if test "$DOXYGEN" = "no"; then
83   AC_MSG_WARN([unable to find doxygen application])
84   have_dox_tools=no
85else
86   doxygen_min_version=1.5
87   AC_MSG_CHECKING([if doxygen is at least $doxygen_min_version])
88   doxygen_version=`$DOXYGEN --version`
89   AX_COMPARE_VERSION([$doxygen_version], [ge], [$doxygen_min_version], ,
90                      [have_dox_tools=no])
91   AC_MSG_RESULT([$doxygen_version])
92fi
93AC_CHECK_PROG([have_epstopdf], [epstopdf], [yes], [no])
94if test "$have_epstopdf" != "yes"; then
95   AC_MSG_WARN([unable to find epstopdf application])
96   have_dox_tools=no
97fi
98AC_CHECK_PROG([have_latex], [latex], [yes], [no])
99if test "$have_latex" != "yes"; then
100   AC_MSG_WARN([unable to find latex application])
101fi
102AC_CHECK_PROG([have_makeindex], [makeindex], [yes], [no])
103if test "$have_makeindex" != "yes"; then
104   AC_MSG_WARN([unable to find makeindex application])
105   have_dox_tools=no
106fi
107AC_CHECK_PROG([have_pdflatex], [pdflatex], [yes], [no])
108if test "$have_pdflatex" != "yes"; then
109   AC_MSG_WARN([unable to find pdflatex application])
110   have_dox_tools=no
111fi
112
113AC_SUBST(have_dox_tools)
114AM_CONDITIONAL([HAVE_DOXYGEN], [test "$have_dox_tools" = "yes"])
115AC_CONFIG_FILES([test/documentation_test.sh],
116                [chmod +x test/documentation_test.sh])
117
118# Save user-defined environment settings for later restoration
119APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
120APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
121APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
122
123# Checks for libraries.
124AC_MSG_NOTICE([checking for libraries])
125AC_CHECK_LIBM
126AS_IF([test "x$LIBM" != x], [LIBS="$LIBM $LIBS"])
127# searching for cblas. Priority 1) find a cblas library, 2) find ATLAS
128# generated cblas, and 3) fall back to GSL cblas implementation. If
129# partial ATLAS is detected the configure script fails.
130cblas_found="no"  # cblas_found may get values yes or no
131# atlas_found may get values yes, no, or partial. In some cases
132# partial atlas may be installed
133atlas_found="no"
134gslcblas_found="no" # gslcblas_found may get values yes or no
135AC_SEARCH_LIBS(cblas_sdsdot,cblas,cblas_found="yes",
136  AC_SEARCH_LIBS(ATL_sdsdot,atlas,
137    AC_SEARCH_LIBS(cblas_sdsdot,cblas,atlas_found="yes",
138                   atlas_found="partial",-m64),
139      AC_SEARCH_LIBS(cblas_dswap,gslcblas,gslcblas_found="yes"),-m64),)
140# CBLAS used in test of GSL
141gsl_cblas_lib=-lgslcblas
142if test ${cblas_found} = "yes"; then
143  gsl_cblas_lib=-lcblas
144fi
145if test ${atlas_found} = "yes"; then
146  YAT_CXX_ADD_FLAG([CXXFLAGS], [-m64])
147  YAT_LD_ADD_FLAG([LDFLAGS], [-m64])
148  gsl_cblas_lib=-latlas
149fi
150export GSL_CBLAS_LIB=${gsl_cblas_lib}
151
152# GNU Scientific Library, GSL http://www.gnu.org/software/gsl/, checks
153# Including AX_PATH_GSL macro from gsl.m4 distributed by GSL
154gsl_found="no"
155gsl_version="1.8"
156AC_SUBST(gsl_version)
157AX_PATH_GSL([${gsl_version}],[gsl_found="yes"],[gsl_version_check="no"])
158if test "$gsl_found" = "yes"; then
159   LIBS="-lgsl $LIBS"
160   # grep words starting with '-L' in other words LDFLAGS
161   for i in $GSL_LIBS; do
162     if test ${i:0:2} = "-L"; then
163       YAT_LD_ADD_FLAG([LDFLAGS], [$i])
164     fi
165   done
166fi
167
168# Boost http://www.boost.org
169boost_version=1.33
170AC_SUBST(boost_version)
171AX_BOOST_BASE(["$boost_version"])
172boost_version_check=$succeeded;
173YAT_CPP_ADD_FLAG([CPPFLAGS], [$BOOST_CPPFLAGS])
174
175#support for large files
176AC_SYS_LARGEFILE
177if test "$enable_largefile" = "no"; then
178  AC_DEFINE([YAT_LFS_DISABLED], 1,
179            [defined to 1 if large file support is disabled])
180fi
181
182# we use AM_* for variables that are solely needed for building yat,
183# i.e., they are not needed for a user of yat and are not propagated
184# to yat-config or yat.m4.
185YAT_CXX_ADD_FLAG([AM_CXXFLAGS], [-Wall -pedantic])
186YAT_CPP_ADD_FLAG([AM_CPPFLAGS], [-DHAVE_INLINE=1])
187AC_ARG_ENABLE([debug],
188  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])])
189if test "${enable_debug}" = "yes" ; then
190  YAT_CPP_ADD_FLAG([AM_CPPFLAGS], [-DYAT_DEBUG=1])
191  YAT_CXX_ADD_FLAG([AM_CXXFLAGS], [-g -O])
192else
193  YAT_CPP_ADD_FLAG([AM_CPPFLAGS], [-DGSL_RANGE_CHECK_OFF -DNDEBUG])
194  YAT_CXX_ADD_FLAG([AM_CXXFLAGS], [-O3])
195fi
196
197AC_ARG_ENABLE([svn-support],
198              [AS_HELP_STRING([--enable-svn-support],
199                              [enable svn support - used by yat maintainer])])
200
201if test "x$enable_svn-support" = "xyes"; then
202  svn_error_msg="svn support cannot be enabled:"
203  AC_CHECK_FILE([$srcdir/.svn], ,
204                AC_MSG_ERROR([$svn_error_msg `$srcdir' is not an svn wc.]))
205  AC_PATH_PROG([PERL], [perl], [no])
206  if test "x$PERL" = "xno"; then
207    AC_MSG_ERROR([$svn_error_msg perl executable not found.])
208  fi
209  AC_PROG_PERL_MODULES([strict Cwd File::Path Getopt::Long Pod::Usage], ,
210         [AC_MSG_ERROR([$svn_error_msg missing some perl module.])])
211fi
212AM_CONDITIONAL([ENABLE_SVN_SUPPORT], [test "x$enable_svn_support" = "xyes"])
213
214
215# check for quiet_NaN support in OS
216# Check at run-time, but if we are cross-compiling fall back on a
217# compilation test
218AC_MSG_CHECKING([if std::numeric_limits<>::has_quiet_NaN is true])
219AC_RUN_IFELSE(
220  [AC_LANG_PROGRAM(
221    [@%:@include <limits>],
222    [return !std::numeric_limits<double>::has_quiet_NaN])],
223  [quiet_nan=yes
224   AC_MSG_RESULT($quiet_nan)],
225  [quiet_nan=no
226   AC_MSG_RESULT($quiet_nan)],
227  # if we are cross-compiling fall back on compilation test
228  [AC_MSG_RESULT(cross-compiling)
229   AC_MSG_CHECKING([for std::numeric_limits<>::quiet_NaN()])
230    AC_COMPILE_IFELSE(
231     [AC_LANG_PROGRAM(
232        [@%:@include <limits>
233         extern void f(double);],
234        [f(std::numeric_limits<double>::quiet_NaN())])],
235     [quiet_nan=yes],
236     [quiet_nan=no])
237   AC_MSG_RESULT($quiet_nan)])
238# Check for infinity support for doubles in OS
239# Check at run-time, but if we are cross-compiling fall back on a
240# compilation test
241AC_MSG_CHECKING([if std::numeric_limits<>::has_infinity is true])
242AC_RUN_IFELSE(
243  [AC_LANG_PROGRAM(
244    [@%:@include <limits>],
245    [return !std::numeric_limits<double>::has_infinity])],
246  [has_infinity=yes
247   AC_MSG_RESULT($has_infinity)],
248  [has_infinity=no
249   AC_MSG_RESULT($has_infinity)],
250  # if we are cross-compiling fall back on compilation test
251  [AC_MSG_RESULT(cross-compiling)
252   AC_MSG_CHECKING([for std::numeric_limits<>::infinity()])
253    AC_COMPILE_IFELSE(
254     [AC_LANG_PROGRAM(
255        [@%:@include <limits>
256         extern void f(double);],
257        [f(std::numeric_limits<double>::infinity())])],
258     [has_infinity=yes],
259     [has_infinity=no])
260   AC_MSG_RESULT($has_infinity)])
261
262AC_MSG_CHECKING([g++ deprecation attribute])
263AC_COMPILE_IFELSE(
264   [AC_LANG_PROGRAM([[void f() __attribute__ ((deprecated));]],)], 
265   [AC_DEFINE([YAT_HAVE_GCC_DEPRECATED], [1],
266              [Define if compiler supports deprecated attribute, as in g++ 4.0])
267    AC_MSG_RESULT([yes])],
268   [AC_MSG_RESULT([no])] )
269
270AC_MSG_CHECKING([if std::multiset::iterator is mutable])
271AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@%:@include <set>
272                                     @%:@include <vector>]],
273                                   [[std::set<std::vector<double> > s;
274                                     std::vector<double> v;
275                                     s.insert(v);
276                                     s.begin()->reserve(100);
277                                   ]])],
278                  [AC_DEFINE([MULTISET_ITERATOR_IS_MUTABLE], [1],
279                             [Define if std::multiset::iterator is mutable])
280                   AC_MSG_RESULT([yes])
281                  ],
282                  [AC_MSG_RESULT([no])] )
283
284# yat specific settings
285YAT_LIBNAME="yat"
286YAT_LIB_LOCATION="yat"
287AC_SUBST(YAT_LIBNAME)
288AC_SUBST(YAT_LIB)
289AC_SUBST(YAT_LIB_LOCATION)
290
291#doxygen stuff
292DX_HTML_OUTPUT=html
293DX_LATEX_OUTPUT=latex
294AC_SUBST(DX_HTML_OUTPUT)
295AC_SUBST(DX_LATEX_OUTPUT)
296
297
298AC_CONFIG_FILES([test/create_yathello.sh], [chmod +x test/create_yathello.sh])
299AC_CONFIG_FILES([Makefile
300     build_support/Makefile
301     doc/Makefile
302     doc/doxygen.config
303     doc/first_page.doxygen
304     m4/Makefile
305     test/Makefile
306     test/environment.h
307     test/data/Makefile
308     yat/Makefile
309     yat/classifier/Makefile
310     yat/normalizer/Makefile
311     yat/random/Makefile
312     yat/regression/Makefile
313     yat/statistics/Makefile
314     yat/utility/version.h
315     yat/utility/Makefile])
316
317AC_CONFIG_HEADER([yat/utility/config_public.h])
318
319# warning about missing doxygen
320if (test "$have_dox_tools" != "yes") ; then
321  AC_MSG_WARN([
322  Some pre-requisites for generating documentation were not
323  fulfilled. The build will not create any documentation.
324  Please consult the 'README' file for more information about
325  what is needed to generate documentation and refer to above
326  warning messages.
327  ])
328fi
329
330# Print failure status information about selected items, and exit if
331# fatal errors were encountered. No output will be created if
332# configure is halted prematurely.
333
334# used to trigger exit before creation of output
335all_reqs_ok="true"
336
337# No support for quiet NAN is fatal -- sub-sequent compilation, or execution
338# of created binary, will fail.
339if test "${quiet_nan}" = "no" ; then
340  all_reqs_ok="false"
341  AC_MSG_WARN([
342  Support for quiet NAN required.
343  Yat will not work on this system!])
344fi
345
346# No support for infinity is fatal -- sub-sequent compilation, or execution
347# of created binary, will fail.
348if test "${has_infinity}" = "no" ; then
349  all_reqs_ok="false"
350  AC_MSG_WARN([
351  Support for infinity required.
352  Yat will not work on this system!])
353fi
354
355
356# Non-existing BLAS is fatal -- sub-sequent compilation will fail.
357if test "${cblas_found}" = "no" -a "${atlas_found}" = "no" -a "${gslcblas_found}" = "no"; then
358  all_reqs_ok="false"
359  AC_MSG_WARN([
360  cBLAS not found. The C implementation of Basic Linear Algebra
361  Subprograms (cBLAS) library cannot be found. Please make sure
362  cBLAS is installed.])
363fi
364if test "${atlas_found}" = "partial"; then
365  all_reqs_ok="false"
366  AC_MSG_WARN([
367  Partial ATLAS BLAS library found. Please repair your installation.])
368fi
369
370# Non-existing GSL is fatal -- sub-sequent compilation will fail.
371if test "${gsl_found}" = "no" ; then
372  all_reqs_ok="false"
373  if test "${gsl_version_check}" = "no" ; then
374  AC_MSG_WARN([
375  GSL found but not the required version. Please install
376  GSL version ${gsl_version} or later])
377  else
378  AC_MSG_WARN([
379  GSL not found. The GNU Scientific Library (GSL) library cannot be
380  found. Please make sure GSL is installed.])
381  fi
382fi
383
384# Too old Boost is fatal -- sub-sequent compilation will fail.
385if test "${boost_version_check}" != "yes" ; then
386  all_reqs_ok="false"
387  AC_MSG_WARN([
388  Boost found but not the required version. Please install
389  Boost version ${boost_version} or later])
390fi
391
392if (test "$all_reqs_ok" = "false") ; then
393  AC_MSG_FAILURE([
394  Some pre-requisites were not fulfilled, aborting configure.
395  Please consult the 'README' file for more information about what
396  is needed to compile yat and refer to above warning messages.
397  Needed files were NOT created.])
398fi
399
400# Reset flags
401APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
402APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
403APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
404
405AM_CPPFLAGS="-I\$(top_srcdir) $AM_CPPFLAGS $EXTRA_CPPFLAGS"
406AM_CXXFLAGS="$AM_CXXFLAGS $EXTRA_CXXFLAGS"
407AM_LDFLAGS="$AM_LDFLAGS $EXTRA_LDFLAGS"
408
409AC_SUBST(AM_CPPFLAGS)
410AC_SUBST(AM_CXXFLAGS)
411AC_SUBST(AM_LDFLAGS)
412
413# Create output.
414AC_OUTPUT
415
416# Some more messages.
417AC_MSG_NOTICE([])
418AC_MSG_NOTICE([ Ready to compile the yat library])
419AC_MSG_NOTICE([ The following flags and libraries will be used:])
420AC_MSG_NOTICE([ +++++++++++++++++++++++++++++++++++++++++++++++])
421AC_MSG_NOTICE([  CPPFLAGS=$CPPFLAGS])
422AC_MSG_NOTICE([  AM_CPPFLAGS=$AM_CPPFLAGS])
423AC_MSG_NOTICE([  CXXFLAGS=$CXXFLAGS])
424AC_MSG_NOTICE([  AM_CXXFLAGS=$AM_CXXFLAGS])
425AC_MSG_NOTICE([  LDFLAGS=$LDFLAGS])
426AC_MSG_NOTICE([  AM_LDFLAGS=$AM_LDFLAGS])
427AC_MSG_NOTICE([  LIBS=$LIBS])
428AC_MSG_NOTICE([ +++++++++++++++++++++++++++++++++++++++++++++++])
429AC_MSG_NOTICE([])
430if test "${gslcblas_found}" = "yes"; then
431AC_MSG_NOTICE([ GSL BLAS found. This is a reference implementation only.])
432AC_MSG_NOTICE([ Consider using hardware optimized BLAS.])
433AC_MSG_NOTICE([ ATLAS (http://math-atlas.sourceforge.net/) provides an])
434AC_MSG_NOTICE([ optimized BLAS library. It is supported by yat!])
435AC_MSG_NOTICE([])
436fi
437AC_MSG_NOTICE([ Now type 'make && make check'.])
Note: See TracBrowser for help on using the repository browser.