source: trunk/build_support/yat.m4 @ 1412

## $Id: yat.m4 1412 2008-08-15 19:54:44Z peter $

# SYNOPSIS
#
#   YAT_CHECK_YAT([MINIMUM-VERSION], [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
#
# DESCRIPTION
#
#   Test yat library of a particular version
#
#   This macro file can be used by applications to find and use the
#   yat library.
#   
#   This macro calls:
#   
#     AC_SUBST(YAT_CPPFLAGS)
#     AC_SUBST(YAT_CXXFLAGS)
#     AC_SUBST(YAT_LDFLAGS)
#     AC_SUBST(YAT_LIBS)
#     AC_SUBST(YAT_LA_FILE)
#
#   defines:
#
#     HAVE_YAT
#
#   and sets the following variable:
#
#     yat_config:    If yat-config exists, $yat_config refers to it,
#                    otherwise $yat_config is set to "no".
#
#
#   YAT_CHECK_YAT is split into sub-macros:
#
#     YAT_FIND_YAT()
#     YAT_CHECK_VERSION([MINIMUM-VERSION])
#     YAT_CHECK_HEADER()
#     YAT_CHECK_LIB()
#
#   so when preferable, you can call any of these instead.
#
#
#   YAT_FIND_YAT([ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
#
#     Finds the yat-config scripts. If there is no --with-yat
#     specified, it will look in the PATH. Sets a shell variable
#     $yat_config. $yat_config is required for the other macros and
#     therefore if YAT_FIND_YAT has not been called, they will call
#     YAT_FIND_YAT.
#
#
#   YAT_CHECK_VERSION([MINIMUM-VERSION],[ACTION-IF-FOUND],[ACTION-IF-NOT-FOUND])
#
#     If the version of yat is at least MINIMUM-VERSION, execute
#     ACTION-IF-FOUND, otherwise execute ACTION-IF-NOT-FOUND.
#
#
#   YAT_CHECK_HEADER([ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
#
#     If yat hearders are found and compilable, call
#     AC_SUBST(YAT_CPPFLAGS) and AC_SUBST(YAT_CXXFLAGS), define
#     HAVE_YAT, execute ACTION-IF-FOUND. If test compilation failed
#     execute ACTION-IF-NOT-FOUND.
#
#
#   YAT_CHECK_LIB([ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
#
#     Compile a small program and link it to yat. On success call
#     AC_SUBST(YAT_LDFLAGS), AC_SUBST(YAT_LIBS), and
#     AC_SUBST(YAT_LA_FILE), and define HAVE_YAT, and execute
#     ACTION-IF-FOUND. On failure execute ACTION-IF-NOT-FOUND.
#
#
#
# LAST MODIFICATION
#
#   $Date: 2008-08-15 19:54:44 +0000 (Fri, 15 Aug 2008) $
#
# COPYLEFT
#
#   Copyright (C) 2008 Peter Johansson
#
#   This file is part of the yat library, http://dev.thep.lu.se/yat
#
#   The yat library is free software; you can redistribute it and/or
#   modify it under the terms of the GNU General Public License as
#   published by the Free Software Foundation; either version 2 of the
#   License, or (at your option) any later version.
#
#   The yat library is distributed in the hope that it will be useful,
#   but WITHOUT ANY WARRANTY; without even the implied warranty of
#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
#   General Public License for more details.
#
#   You should have received a copy of the GNU General Public License
#   along with this program; if not, write to the Free Software
#   Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
#   02111-1307, USA.
#

#
# serial 0  # version number of yat.m4
#
# see http://www.gnu.org/software/automake/manual/automake.html#Serials

AC_DEFUN([YAT_CHECK_YAT],
[
ac_yat_check_yat_res="yes"
AC_REQUIRE([YAT_FIND_YAT])  dnl
YAT_CHECK_VERSION([$1],,[ac_yat_check_yat_res="no"])
YAT_CHECK_HEADER(,[ac_yat_check_yat_res="no"])
YAT_CHECK_LIB(,[ac_yat_check_yat_res="no"])
# ACTION
if test "$ac_yat_check_yat_res" != "no" ; then
  ifelse([$2], , :, [$2])
else
  ifelse([$3], , :, [$3])
fi  

]) # YAT_CHECK_YAT


AC_DEFUN([YAT_FIND_YAT],
[
  AC_ARG_WITH(yat, 
              AC_HELP_STRING([--with-yat=DIR],
                [prefix for installed yat library or full path to yat-config]),
    [ yat_config=no;
      AC_MSG_NOTICE([looking for yat-config])
      for p in $withval $withval/yat-config $withval/bin/yat-config ; do  
        if test "$yat_config" = "no" ; then 
          AC_MSG_CHECKING([$p]);
          if test -f "$p" && $p --help > /dev/null 2>&1 ; then
            yat_config=$p;
            AC_MSG_RESULT([yes]);
          else
            AC_MSG_RESULT([no]);
          fi
        fi
      done     
      if test "$yat_config" = "no" ; then 
        AC_MSG_WARN(dnl
[the --with-yat parameter is incorrect. It must
specify an install prefix, or an yat-config file."])
      fi
    ],
    [ AC_PATH_PROG([yat_config], [yat-config], [no])
      if test "$yat_config" = "no" ; then 
        AC_MSG_WARN(dnl
[the yat-config script installed by yat could not be found. If yat was
 installed in PREFIX, make sure PREFIX/bin is in your path, or supply
 the appropriate --with-yat option"]) 
      fi 
    ])

  # ACTION
  if test "$yat_config" != "no" ; then
    ifelse([$2], , :, [$2])
  else
    ifelse([$3], , :, [$3])
  fi  

]) # YAT_FIND_YAT



AC_DEFUN([YAT_CHECK_VERSION],
[
  AC_REQUIRE([YAT_FIND_YAT])  dnl
  if test "$yat_config" != "no"; then
    ac_yat_min_version=ifelse([$1], , [0.5], [$1])
    AC_MSG_CHECKING(if version of yat is at least $ac_yat_min_version)

    if $yat_config --atleast-version=$ac_yat_min_version; then
      ac_yat_version_ok=yes;
    else
      ac_yat_version=`$yat_config --version`
      AC_MSG_WARN(dnl
['$yat_config --version' returned $ac_yat_version, but the minimum
required version is $ac_yat_min_version."])
      ac_yat_version_ok=no;
    fi
    AC_MSG_RESULT([$ac_yat_version_ok])
  fi

  # ACTION
  if test "$ac_yat_version_ok" = "yes" ; then
    ifelse([$2], , :, [$2])
  else
    ifelse([$3], , :, [$3])
  fi  

]) # YAT_CHECK_VERSION



AC_DEFUN([YAT_CHECK_HEADER],
[
  AC_REQUIRE([YAT_FIND_YAT])  dnl
  if test "$yat_config" != "no"; then
    ac_yat_save_CPPFLAGS=$CPPFLAGS
    ac_yat_save_CXXFLAGS=$CXXFLAGS
    YAT_CPPFLAGS=`$yat_config --cppflags`
    YAT_CXXFLAGS=`$yat_config --cxxflags`
    CPPFLAGS="$CPPFLAGS $YAT_CPPFLAGS"
    CXXFLAGS="$CXXFLAGS $YAT_CXXFLAGS"
    AC_LANG_PUSH(C++)
    # checking for Vector, which uses both GSL and Boost
    AC_CHECK_HEADER([yat/utility/Vector.h], 
                    [ac_yat_ok="yes"], 
                    [ac_yat_ok="no"])
    
    # checking that version in yat-config and version.h agree
    AC_MSG_CHECKING([version in $yat_config])
    yat_config_version=`$yat_config --version`
    AC_MSG_RESULT([$yat_config_version])
    AC_MSG_CHECKING([YAT_VERSION in <yat/utility/version.h>])
    AC_COMPILE_IFELSE(
      [AC_LANG_PROGRAM([@%:@include <yat/utility/version.h>], 
        [ #if YAT_VERSION_AT_LEAST(`$yat_config --version-major`,\
                                   `$yat_config --version-minor`,\
                                   `$yat_config --version-patch`)          
          // Versions agree
          #else
          # error yat versions disagree
          #endif
        ])
      ],
      [AC_MSG_RESULT([ok]); 
       ac_yat_ok="yes";
       AC_SUBST(YAT_CPPFLAGS)
       AC_SUBST(YAT_CXXFLAGS)
       AC_DEFINE(HAVE_YAT,,[define if yat library is available])],
      [AC_MSG_RESULT([incorrect]); 
       AC_MSG_WARN(dnl
[version declared in included yat/utility/version.h is not equal to
the one given from yat-config script: $yat_config."])
       ac_yat_ok="no"; 
      ])

    # restore FLAGS
    CPPFLAGS=$ac_yat_save_CPPFLAGS
    CXXFLAGS=$ac_yat_save_CXXFLAGS
    AC_LANG_POP(C++)
  fi

  # ACTION
  if test "$ac_yat_ok" = "yes" ; then
    ifelse([$1], , :, [$1])
  else
    ifelse([$2], , :, [$2])
  fi  

]) # YAT_CHECK_HEADER



AC_DEFUN([YAT_CHECK_LIB],
[
  AC_REQUIRE([YAT_FIND_YAT])  dnl
  if test "$yat_config" != "no"; then
    ac_yat_save_LDFLAGS=$LDFLAGS
    ac_yat_save_LIBS=$LIBS
    YAT_LDFLAGS=`$yat_config --ldflags`
    YAT_LIBS=`$yat_config --libs`
    LDFLAGS="$LDFLAGS $YAT_LDFLAGS"
    LIBS="$LIBS $YAT_LIBS"
    AC_LANG_PUSH(C++)
    AC_MSG_CHECKING([for utility::version(void) in yat])
    AC_LINK_IFELSE([AC_LANG_PROGRAM([[@%:@include <string>
                                      namespace theplu{
                                      namespace yat{
                                      namespace utility {
                                      std::string version(void);
                                      }}}
                                    ]], 
                                    [using namespace theplu::yat::utility;
                                     std::string s=version();])],
                   [ac_yat_ok="yes";
                    AC_SUBST(YAT_LDFLAGS)
                    AC_SUBST(YAT_LIBS)
                    YAT_LA_FILE=`$yat_config --link-libtool`;
                    AC_SUBST(YAT_LA_FILE)],
                   [ac_yat_ok="no"; 
                    AC_MSG_WARN(dnl
[the test program failed to link (or compile). See file config.log for
details on what occured."])
                   ])
    AC_MSG_RESULT([$ac_yat_ok])
    # restore FLAGS
    LDFLAGS=$ac_yat_save_LDFLAGS
    LIBS=$ac_yat_save_LIBS
    AC_LANG_POP(C++)
  fi

  # ACTION
  if test "$ac_yat_ok" = "yes" ; then
    ifelse([$1], , :, [$1])
  else
    ifelse([$2], , :, [$2])
  fi  
]) # YAT_CHECK_LIB