source: trunk/configure.ac @ 1105

## Process this file with autoconf to produce a configure script.
##
## $Id: configure.ac 1097 2008-02-17 22:41:33Z jari $

# Copyright (C) 2003 Daniel Dalevi, Jari Häkkinen
# Copyright (C) 2004 Jari Häkkinen
# Copyright (C) 2005, 2006, 2007 Jari Häkkinen, Peter Johansson
# Copyright (C) 2008 Jari Häkkinen
#
# This file is part of the yat library, http://trac.thep.lu.se/yat
#
# The yat library is free software; you can redistribute it
# and/or modify it under the terms of the GNU General Public License as
# published by the Free Software Foundation; either version 2 of the
# License, or (at your option) any later version.
#
# The yat library is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
# 02111-1307, USA.
#
# If you grabbed the source from the subversion repository you should,
# at top-level, execute:
#     ./bootstrap
# To push subsequent changes of this file into the build scripts you
# must issue:
#     autoreconf

AC_INIT([yat],[0.4pre],[jari@thep.lu.se])
AC_PREREQ(2.60)
AC_CONFIG_SRCDIR([yat/utility/matrix.h])
AC_CONFIG_AUX_DIR([autotools])
AC_PREFIX_DEFAULT([/usr/local])

# Library versioning (current:revision:age)
# See the libtool manual for an explanation of the numbers
#
# yat-0.3    undefined
# yat-0.4    1:0:0
YAT_LT_VERSION="1:0:0"
AC_SUBST(YAT_LT_VERSION)

AM_CONFIG_HEADER([config.h])
AM_INIT_AUTOMAKE()

# Set default programming language
AC_LANG(C++)

# Checks for programs.
AC_PROG_CXX
AC_PROG_INSTALL
AC_PROG_SED
AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [true], [false])
AC_CHECK_PROG([HAVE_DVIPDFM], [dvipdfm], [true], [false])
AC_CHECK_PROG([HAVE_LATEX], [latex], [true], [false])
AC_CHECK_PROG([HAVE_LATEX2HTML], [latex2html], [true], [false])

# Checks for libraries.
AC_CHECK_LIB(m,main)
# searching for cblas. Priority 1) find a cblas library, 2) find ATLAS
# generated cblas, and 3) fall back to GSL cblas implementation. If
# partial ATLAS is detected the configure script fails.
cblas_found="no"  # cblas_found may get values yes or no
# atlas_found may get values yes, no, or partial. In some cases
# partial atlas may be installed
atlas_found="no"
gslcblas_found="no" # gslcblas_found may get values yes or no
AC_SEARCH_LIBS(cblas_sdsdot,cblas,cblas_found="yes",
  AC_SEARCH_LIBS(ATL_sdsdot,atlas,
    AC_SEARCH_LIBS(cblas_sdsdot,cblas,atlas_found="yes",
                   atlas_found="partial",-m64),
      AC_SEARCH_LIBS(cblas_dswap,gslcblas,gslcblas_found="yes"),-m64),)
if test ${atlas_found} = "yes"; then
  CXXFLAGS="$CXXFLAGS -m64" LDFLAGS="$LDFLAGS -m64"
fi

# GNU Scientific Library, GSL http://www.gnu.org/software/gsl/, checks
# Including AM_PATH_GSL macro from gsl.m4 distributed by GSL
gsl_found="no"
gsl_version="1.6"
sinclude(./build_support/gsl.m4)
AM_PATH_GSL(${gsl_version},gsl_found="yes",gsl_version_check="no")
if test "$gsl_found" = "yes"; then
  # Needed to set -lgsl
  AC_CHECK_LIB(gsl,main)
fi

# Checks for header files.
AC_CHECK_HEADERS([unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_HEADER_STDBOOL
AC_C_CONST
AC_C_INLINE
AC_TYPE_SIZE_T

# Checks for library functions.
AC_PROG_LIBTOOL
AC_FUNC_ERROR_AT_LINE
AC_HEADER_STDC
AC_CHECK_FUNCS([pow sqrt])

CXXFLAGS="$CXXFLAGS -Wall -pedantic"
CPPFLAGS="$CPPFLAGS -DHAVE_INLINE=1"
AC_ARG_ENABLE(debug,
  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])])
if test "${enable_debug}" = "yes" ; then
  CXXFLAGS="$CXXFLAGS -g -O"
  CPPFLAGS="$CPPFLAGS -DYAT_DEBUG=1"
else
  CXXFLAGS="$CXXFLAGS -O3"
  CPPFLAGS="$CPPFLAGS -DNDEBUG -DGSL_RANGE_CHECK_OFF"
fi

# check for quiet_NaN support in OS
# At compile time, but this may not work if quiet_NaN exists and returns
# an incorrect value
AC_MSG_CHECKING([for std::numeric_limits<>::quiet_NaN()])
AC_COMPILE_IFELSE(
  [AC_LANG_PROGRAM(
    [#include <limits>
     extern void f(double);],
    [f(std::numeric_limits<double>::quiet_NaN())])],
  [quiet_nan=yes],
  [quiet_nan=no])
AC_MSG_RESULT($quiet_nan)
# At run-time, but this has the disadvantage that yat cannot be built  
# for cross-compilation
AC_MSG_CHECKING([if std::numeric_limits<>::has_quiet_NaN is true])
AC_RUN_IFELSE(
  [AC_LANG_PROGRAM(
    [#include <limits>],
    [return !std::numeric_limits<double>::has_quiet_NaN])],
  [quiet_nan=yes],
  [quiet_nan=no])
AC_MSG_RESULT($quiet_nan)

# yat specific settings
YAT_LIB="libyat.la"
YAT_LIB_LOCATION="yat"
AC_SUBST(YAT_LIB)
AC_SUBST(YAT_LIB_LOCATION)

AC_CONFIG_FILES([Makefile
     doc/Makefile
     test/Makefile
     test/data/Makefile
     yat/Makefile
     yat/classifier/Makefile
     yat/random/Makefile
     yat/regression/Makefile
     yat/statistics/Makefile
     yat/utility/Makefile])

# Only warning about missing programs (needed for docs generation)
# when in debug mode
if (test "$enable_debug" == "yes"); then
if (test "$HAVE_DOXYGEN" != "true") ; then
  AC_MSG_WARN([
  Doxygen was not found. Yat will compile and work without doxygen.
  However, in order to enable generation of documentation, please
  install doxygen available at http://www.doxygen.org/
  ])
fi
if (test "$HAVE_LATEX" != "true") ; then
  AC_MSG_WARN([
  latex was not found. Yat will compile and work without latex.
  However, supporting documentation on statistics used in yat
  cannot be generated without latex.
  ])
fi
if (test "$HAVE_DVIPDFM" != "true") ; then
  AC_MSG_WARN([
  dvipdfm was not found. Yat will compile and work without dvipdfm.
  However, pdf document on statistics used in yat cannot be
  generated without dvipdfm.
  ])
fi
if (test "$HAVE_LATEX2HTML" != "true") ; then
  AC_MSG_WARN([
  latex2html was not found. Yat will compile and work without
  latex. However, html document on statistics used in yat cannot
  be generated without latex.
  ])
fi
fi

# Print failure status information about selected items, and exit if
# fatal errors were encountered. No output will be created if
# configure is halted prematurely.

# used to trigger exit before creation of output
all_reqs_ok="true"

# No support for quiet NAN is fatal -- sub-sequent compilation, or execution
# of created binary, will fail.
if test "${quiet_nan}" = "no" ; then
  all_reqs_ok="false"
  AC_MSG_WARN([
  Support for quiet NAN required.
  Yat will not work on this system!])
fi

# Non-existing BLAS is fatal -- sub-sequent compilation will fail.
if test "${cblas_found}" = "no" -a "${atlas_found}" = "no" -a "${gslcblas_found}" = "no"; then
  all_reqs_ok="false"
  AC_MSG_WARN([
  cBLAS not found. The C implementation of Basic Linear Algebra
  Subprograms (cBLAS) library cannot be found. Please make sure
  cBLAS is installed.])
fi
if test "${atlas_found}" = "partial"; then
  all_reqs_ok="false"
  AC_MSG_WARN([
  Partial ATLAS BLAS library found. Please repair your installation.])
fi

# Non-existing GSL is fatal -- sub-sequent compilation will fail.
if test "${gsl_found}" = "no" ; then
  all_reqs_ok="false"
  if test "${gsl_version_check}" = "no" ; then
  AC_MSG_WARN([
  GSL found but not the required version. Please install
  GSL version ${gsl_version} or later])
  else
  AC_MSG_WARN([
  GSL not found. The GNU Scientific Library (GSL) library cannot be
  found. Please make sure GSL is installed.])
  fi
fi

if (test "$all_reqs_ok" = "false") ; then
  AC_MSG_FAILURE([
  Some pre-requisites were not fulfilled, aborting configure.
  Please consult the 'README' file for more information about what
  is needed to compile yat and refer to above warning messages.
  Needed files were NOT created.])
fi

# Create output.
AC_OUTPUT

# Some more messages.
AC_MSG_NOTICE([])
AC_MSG_NOTICE([ Ready to compile the yat library])
AC_MSG_NOTICE([ The following flags and libraries will be used:])
AC_MSG_NOTICE([ +++++++++++++++++++++++++++++++++++++++++++++++])
AC_MSG_NOTICE([  CPPFLAGS=\"$CPPFLAGS\"])
AC_MSG_NOTICE([  CXXFLAGS=\"$CXXFLAGS\"])
AC_MSG_NOTICE([  LIBS=\"$LIBS\"])
AC_MSG_NOTICE([  LDFLAGS=\"$LDFLAGS\"])
AC_MSG_NOTICE([ +++++++++++++++++++++++++++++++++++++++++++++++])
AC_MSG_NOTICE([])
if test "${gslcblas_found}" = "yes"; then
AC_MSG_NOTICE([ GSL BLAS found. This is a reference implementation only.])
AC_MSG_NOTICE([ Consider using hardware optimized BLAS.])
AC_MSG_NOTICE([ ATLAS (http://math-atlas.sourceforge.net/) provides an])
AC_MSG_NOTICE([ optimized BLAS library. It is supported by yat!])
AC_MSG_NOTICE([])
fi
AC_MSG_NOTICE([ Now type 'make ; make check'.])