source: trunk/configure.ac @ 1444

Last change on this file since 1444 was 1444, checked in by Peter, 13 years ago

just for clarity

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 11.8 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 1444 2008-08-27 20:40:30Z peter $
4
5# Copyright (C) 2003 Daniel Dalevi, Jari Häkkinen
6# Copyright (C) 2004 Jari Häkkinen
7# Copyright (C) 2005, 2006 Jari Häkkinen, Peter Johansson
8# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson, Markus Ringnér
9#
10# This file is part of the yat library, http://dev.thep.lu.se/yat
11#
12# The yat library is free software; you can redistribute it
13# and/or modify it under the terms of the GNU General Public License as
14# published by the Free Software Foundation; either version 2 of the
15# License, or (at your option) any later version.
16#
17# The yat library is distributed in the hope that it will be useful,
18# but WITHOUT ANY WARRANTY; without even the implied warranty of
19# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
20# General Public License for more details.
21#
22# You should have received a copy of the GNU General Public License
23# along with this program; if not, write to the Free Software
24# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
25# 02111-1307, USA.
26#
27# If you grabbed the source from the subversion repository you should,
28# at top-level, execute:
29#     ./bootstrap
30# To push subsequent changes of this file into the build scripts you
31# must issue:
32#     autoreconf
33
34m4_include([./build_support/version.m4])
35AC_INIT([yat],[YAT_VERSION],[jari@thep.lu.se])
36AC_PREREQ(2.60)
37AC_CONFIG_SRCDIR([yat/utility/Matrix.h])
38AC_CONFIG_AUX_DIR([autotools])
39dnl arg below should be the same as in Makefile.am
40AC_CONFIG_MACRO_DIR([build_support])
41AC_PREFIX_DEFAULT([/usr/local])
42
43AC_SUBST([YAT_LT_VERSION], [LT_VERSION])
44AC_SUBST([YAT_MAJOR_VERSION], [MAJOR_VERSION])
45AC_SUBST([YAT_MINOR_VERSION], [MINOR_VERSION])
46AC_SUBST([YAT_PATCH_VERSION], [PATCH_VERSION])
47AC_SUBST([YAT_DEV_BUILD], [DEV_BUILD])
48
49AC_CONFIG_HEADER([config.h])
50AM_INIT_AUTOMAKE()
51
52# Set default programming language
53AC_LANG(C++)
54
55# Let user overide default CXXFLAGS
56if test "${CXXFLAGS+set}" != set; then
57  CXXFLAGS=""  # Setting CXXFLAGS here to prevent expansion in AC_PROG_CXX
58fi
59# Checks for programs.
60AC_PROG_CXX
61AC_PROG_INSTALL
62AC_PROG_SED
63
64AC_MSG_NOTICE(dnl
65[checking whether tools for generating documentation are available])
66
67have_dox_tools="yes"
68AC_PATH_PROG([DOXYGEN], [doxygen], [no])
69if test "$DOXYGEN" = "no"; then
70   AC_MSG_WARN([unable to find doxygen application])
71   have_dox_tools=no
72else
73   doxygen_min_version=1.5
74   AC_MSG_CHECKING([if doxygen is at least $doxygen_min_version])
75   doxygen_version=`$DOXYGEN --version`
76   AX_COMPARE_VERSION([$doxygen_version], [ge], [$doxygen_min_version], ,
77                      [have_dox_tools=no])
78   AC_MSG_RESULT([$doxygen_version])
79fi
80AC_CHECK_PROG([have_epstopdf], [epstopdf], [yes], [no])
81if test "$have_epstopdf" != "yes"; then
82   AC_MSG_WARN([unable to find epstopdf application])
83   have_dox_tools=no
84fi
85AC_CHECK_PROG([have_latex], [latex], [yes], [no])
86if test "$have_latex" != "yes"; then
87   AC_MSG_WARN([unable to find latex application])
88fi
89AC_CHECK_PROG([have_makeindex], [makeindex], [yes], [no])
90if test "$have_makeindex" != "yes"; then
91   AC_MSG_WARN([unable to find makeindex application])
92   have_dox_tools=no
93fi
94AC_CHECK_PROG([have_pdflatex], [pdflatex], [yes], [no])
95if test "$have_pdflatex" != "yes"; then
96   AC_MSG_WARN([unable to find pdflatex application])
97   have_dox_tools=no
98fi
99
100AM_CONDITIONAL(HAVE_DOXYGEN, test "$have_dox_tools" = "yes")
101AC_CONFIG_FILES([test/documentation_test.sh],
102                [chmod +x test/documentation_test.sh])
103
104# Save user-defined environment settings for later restoration
105APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
106APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
107APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
108
109# Checks for libraries.
110AC_MSG_NOTICE([checking for libraries])
111AC_CHECK_LIB(m,main)
112# searching for cblas. Priority 1) find a cblas library, 2) find ATLAS
113# generated cblas, and 3) fall back to GSL cblas implementation. If
114# partial ATLAS is detected the configure script fails.
115cblas_found="no"  # cblas_found may get values yes or no
116# atlas_found may get values yes, no, or partial. In some cases
117# partial atlas may be installed
118atlas_found="no"
119gslcblas_found="no" # gslcblas_found may get values yes or no
120AC_SEARCH_LIBS(cblas_sdsdot,cblas,cblas_found="yes",
121  AC_SEARCH_LIBS(ATL_sdsdot,atlas,
122    AC_SEARCH_LIBS(cblas_sdsdot,cblas,atlas_found="yes",
123                   atlas_found="partial",-m64),
124      AC_SEARCH_LIBS(cblas_dswap,gslcblas,gslcblas_found="yes"),-m64),)
125# CBLAS used in test of GSL
126gsl_cblas_lib=-lgslcblas
127if test ${cblas_found} = "yes"; then
128  gsl_cblas_lib=-lcblas
129fi
130if test ${atlas_found} = "yes"; then
131  CXXFLAGS="$CXXFLAGS -m64" LDFLAGS="$LDFLAGS -m64"
132  gsl_cblas_lib=-latlas
133fi
134export GSL_CBLAS_LIB=${gsl_cblas_lib}
135
136# GNU Scientific Library, GSL http://www.gnu.org/software/gsl/, checks
137# Including AX_PATH_GSL macro from gsl.m4 distributed by GSL
138gsl_found="no"
139gsl_version="1.8"
140AC_SUBST(gsl_version)
141AX_PATH_GSL(${gsl_version},gsl_found="yes",gsl_version_check="no")
142if test "$gsl_found" = "yes"; then
143   LIBS="-lgsl $LIBS"
144   # grep words starting with '-L' in other words LDFLAGS
145   for i in $GSL_LIBS; do
146     if test ${i:0:2} = "-L"; then
147       LDFLAGS="$LDFLAGS $i"
148     fi
149   done
150fi
151
152# Boost http://www.boost.org
153boost_version=1.33
154AC_SUBST(boost_version)
155AX_BOOST_BASE("$boost_version")
156boost_version_check=$succeeded;
157CPPFLAGS="$BOOST_CPPFLAGS $CPPFLAGS"
158
159
160# Checks for header files.
161AC_CHECK_HEADERS([unistd.h])
162
163# Checks for typedefs, structures, and compiler characteristics.
164AC_HEADER_STDBOOL
165AC_C_CONST
166AC_C_INLINE
167AC_TYPE_SIZE_T
168
169# Checks for library functions.
170AC_PROG_LIBTOOL
171AC_FUNC_ERROR_AT_LINE
172AC_HEADER_STDC
173AC_CHECK_FUNCS([pow sqrt])
174
175CXXFLAGS="$CXXFLAGS -Wall -pedantic"
176CPPFLAGS="$CPPFLAGS -DHAVE_INLINE=1"
177AC_ARG_ENABLE(debug,
178  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])])
179if test "${enable_debug}" = "yes" ; then
180  CXXFLAGS="$CXXFLAGS -g -O"
181  CPPFLAGS="$CPPFLAGS -DYAT_DEBUG=1"
182else
183  CXXFLAGS="$CXXFLAGS -O3"
184  CPPFLAGS="$CPPFLAGS -DNDEBUG -DGSL_RANGE_CHECK_OFF"
185fi
186
187# check for quiet_NaN support in OS
188# Check at run-time, but if we are cross-compiling fall back on a
189# compilation test
190AC_MSG_CHECKING([if std::numeric_limits<>::has_quiet_NaN is true])
191AC_RUN_IFELSE(
192  [AC_LANG_PROGRAM(
193    [@%:@include <limits>],
194    [return !std::numeric_limits<double>::has_quiet_NaN])],
195  [quiet_nan=yes
196   AC_MSG_RESULT($quiet_nan)],
197  [quiet_nan=no
198   AC_MSG_RESULT($quiet_nan)],
199  # if we are cross-compiling fall back on compilation test
200  [AC_MSG_RESULT(cross-compiling)
201   AC_MSG_CHECKING([for std::numeric_limits<>::quiet_NaN()])
202    AC_COMPILE_IFELSE(
203     [AC_LANG_PROGRAM(
204        [@%:@include <limits>
205         extern void f(double);],
206        [f(std::numeric_limits<double>::quiet_NaN())])],
207     [quiet_nan=yes],
208     [quiet_nan=no])
209   AC_MSG_RESULT($quiet_nan)])
210# Check for infinity support for doubles in OS
211# Check at run-time, but if we are cross-compiling fall back on a
212# compilation test
213AC_MSG_CHECKING([if std::numeric_limits<>::has_infinity is true])
214AC_RUN_IFELSE(
215  [AC_LANG_PROGRAM(
216    [@%:@include <limits>],
217    [return !std::numeric_limits<double>::has_infinity])],
218  [has_infinity=yes
219   AC_MSG_RESULT($has_infinity)],
220  [has_infinity=no
221   AC_MSG_RESULT($has_infinity)],
222  # if we are cross-compiling fall back on compilation test
223  [AC_MSG_RESULT(cross-compiling)
224   AC_MSG_CHECKING([for std::numeric_limits<>::infinity()])
225    AC_COMPILE_IFELSE(
226     [AC_LANG_PROGRAM(
227        [@%:@include <limits>
228         extern void f(double);],
229        [f(std::numeric_limits<double>::infinity())])],
230     [has_infinity=yes],
231     [has_infinity=no])
232   AC_MSG_RESULT($has_infinity)])
233
234
235# yat specific settings
236YAT_LIBNAME="yat"
237YAT_LIB_LOCATION="yat"
238AC_SUBST(YAT_LIBNAME)
239AC_SUBST(YAT_LIB)
240AC_SUBST(YAT_LIB_LOCATION)
241
242#doxygen stuff
243DX_HTML_OUTPUT=html
244DX_LATEX_OUTPUT=latex
245AC_SUBST(DX_HTML_OUTPUT)
246AC_SUBST(DX_LATEX_OUTPUT)
247
248
249AC_CONFIG_FILES([Makefile
250     build_support/yat.pc
251     doc/Makefile
252     doc/doxygen.config
253     doc/first_page.doxygen
254     test/Makefile
255     test/environment.h
256     test/data/Makefile
257     yat/Makefile
258     yat/classifier/Makefile
259     yat/normalization/Makefile
260     yat/random/Makefile
261     yat/regression/Makefile
262     yat/statistics/Makefile
263     yat/utility/version.h
264     yat/utility/Makefile])
265
266AC_CONFIG_FILES([build_support/yat-config],
267                [chmod +x build_support/yat-config])
268
269# warning about missing doxygen
270if (test "$have_dox_tools" != "yes") ; then
271  AC_MSG_WARN([
272  Some pre-requisites for generating documentation were not
273  fulfilled. The build will not create any documentation.
274  Please consult the 'README' file for more information about
275  what is needed to generate documentation and refer to above
276  warning messages.
277  ])
278fi
279
280# Print failure status information about selected items, and exit if
281# fatal errors were encountered. No output will be created if
282# configure is halted prematurely.
283
284# used to trigger exit before creation of output
285all_reqs_ok="true"
286
287# No support for quiet NAN is fatal -- sub-sequent compilation, or execution
288# of created binary, will fail.
289if test "${quiet_nan}" = "no" ; then
290  all_reqs_ok="false"
291  AC_MSG_WARN([
292  Support for quiet NAN required.
293  Yat will not work on this system!])
294fi
295
296# No support for infinity is fatal -- sub-sequent compilation, or execution
297# of created binary, will fail.
298if test "${has_infinity}" = "no" ; then
299  all_reqs_ok="false"
300  AC_MSG_WARN([
301  Support for infinity required.
302  Yat will not work on this system!])
303fi
304
305
306# Non-existing BLAS is fatal -- sub-sequent compilation will fail.
307if test "${cblas_found}" = "no" -a "${atlas_found}" = "no" -a "${gslcblas_found}" = "no"; then
308  all_reqs_ok="false"
309  AC_MSG_WARN([
310  cBLAS not found. The C implementation of Basic Linear Algebra
311  Subprograms (cBLAS) library cannot be found. Please make sure
312  cBLAS is installed.])
313fi
314if test "${atlas_found}" = "partial"; then
315  all_reqs_ok="false"
316  AC_MSG_WARN([
317  Partial ATLAS BLAS library found. Please repair your installation.])
318fi
319
320# Non-existing GSL is fatal -- sub-sequent compilation will fail.
321if test "${gsl_found}" = "no" ; then
322  all_reqs_ok="false"
323  if test "${gsl_version_check}" = "no" ; then
324  AC_MSG_WARN([
325  GSL found but not the required version. Please install
326  GSL version ${gsl_version} or later])
327  else
328  AC_MSG_WARN([
329  GSL not found. The GNU Scientific Library (GSL) library cannot be
330  found. Please make sure GSL is installed.])
331  fi
332fi
333
334# Too old Boost is fatal -- sub-sequent compilation will fail.
335if test "${boost_version_check}" != "yes" ; then
336  all_reqs_ok="false"
337  AC_MSG_WARN([
338  Boost found but not the required version. Please install
339  Boost version ${boost_version} or later])
340fi
341
342if (test "$all_reqs_ok" = "false") ; then
343  AC_MSG_FAILURE([
344  Some pre-requisites were not fulfilled, aborting configure.
345  Please consult the 'README' file for more information about what
346  is needed to compile yat and refer to above warning messages.
347  Needed files were NOT created.])
348fi
349
350# Reset flags
351APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
352APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
353APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
354
355# Create output.
356AC_OUTPUT
357
358# Some more messages.
359AC_MSG_NOTICE([])
360AC_MSG_NOTICE([ Ready to compile the yat library])
361AC_MSG_NOTICE([ The following flags and libraries will be used:])
362AC_MSG_NOTICE([ +++++++++++++++++++++++++++++++++++++++++++++++])
363AC_MSG_NOTICE([  CPPFLAGS=\"$CPPFLAGS\"])
364AC_MSG_NOTICE([  EXTRA_CPPFLAGS=\"$EXTRA_CPPFLAGS\"])
365AC_MSG_NOTICE([  CXXFLAGS=\"$CXXFLAGS\"])
366AC_MSG_NOTICE([  EXTRA_CXXFLAGS=\"$EXTRA_CXXFLAGS\"])
367AC_MSG_NOTICE([  LDFLAGS=\"$LDFLAGS\"])
368AC_MSG_NOTICE([  EXTRA_LDFLAGS=\"$EXTRA_LDFLAGS\"])
369AC_MSG_NOTICE([  LIBS=\"$LIBS\"])
370AC_MSG_NOTICE([ +++++++++++++++++++++++++++++++++++++++++++++++])
371AC_MSG_NOTICE([])
372if test "${gslcblas_found}" = "yes"; then
373AC_MSG_NOTICE([ GSL BLAS found. This is a reference implementation only.])
374AC_MSG_NOTICE([ Consider using hardware optimized BLAS.])
375AC_MSG_NOTICE([ ATLAS (http://math-atlas.sourceforge.net/) provides an])
376AC_MSG_NOTICE([ optimized BLAS library. It is supported by yat!])
377AC_MSG_NOTICE([])
378fi
379AC_MSG_NOTICE([ Now type 'make ; make check'.])
Note: See TracBrowser for help on using the repository browser.