source: trunk/configure.ac @ 3072

Last change on this file since 3072 was 3072, checked in by Peter, 8 years ago

prefer aborting directly when error is detected rather than in the end. refs #737

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 16.8 KB
Line 
1## Process this file with autoconf to produce a configure script.
2##
3## $Id: configure.ac 3072 2013-08-28 08:31:33Z peter $
4
5# Copyright (C) 2003 Daniel Dalevi, Jari Häkkinen
6# Copyright (C) 2004 Jari Häkkinen
7# Copyright (C) 2005, 2006 Jari Häkkinen, Peter Johansson
8# Copyright (C) 2007, 2008 Jari Häkkinen, Peter Johansson, Markus Ringnér
9# Copyright (C) 2009 Jari Häkkinen, Peter Johansson
10# Copyright (C) 2010, 2011 Peter Johansson
11# Copyright (C) 2012 Jari Häkkinen, Peter Johansson
12# Copyright (C) 2013 Peter Johansson
13#
14# This file is part of the yat library, http://dev.thep.lu.se/yat
15#
16# The yat library is free software; you can redistribute it
17# and/or modify it under the terms of the GNU General Public License as
18# published by the Free Software Foundation; either version 3 of the
19# License, or (at your option) any later version.
20#
21# The yat library is distributed in the hope that it will be useful,
22# but WITHOUT ANY WARRANTY; without even the implied warranty of
23# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
24# General Public License for more details.
25#
26# You should have received a copy of the GNU General Public License
27# along with yat. If not, see <http://www.gnu.org/licenses/>.
28#
29# If you grabbed the source from the subversion repository you should,
30# at top-level, execute:
31#     ./bootstrap
32# To push subsequent changes of this file into the build scripts you
33# must issue:
34#     autoreconf
35
36
37m4_include([m4/version.m4])
38AC_INIT([yat],[my_VERSION],[libyat-users@lists.sourceforge.net],,
39        [http://dev.thep.lu.se/yat])
40MY_VERSION
41AC_PREREQ(2.63)
42AC_CONFIG_SRCDIR([yat/utility/Matrix.h])
43AC_CONFIG_AUX_DIR([autotools])
44dnl arg below should be the same as in Makefile.am
45AC_CONFIG_MACRO_DIR([m4])
46AC_PREFIX_DEFAULT([/usr/local])
47
48# Set default htmldir to ${docdir}/html
49AS_IF([test $htmldir = '${docdir}'], [htmldir='${docdir}/html'])
50
51dnl FIXME remove when we assume autoconf 2.64
52m4_ifndef([AC_PACKAGE_URL],
53          [AC_DEFINE([PACKAGE_URL], ["http://dev.thep.lu.se/yat"],
54                     [Define to home page for this package])
55           AC_SUBST([PACKAGE_URL], ["http://dev.thep.lu.se/yat"])])
56
57AC_SUBST([YAT_LT_VERSION], [YAT_LT_VERSION_INFO])
58AC_DEFINE([YAT_VERSION], ["my_VERSION"], [version])
59
60AC_CONFIG_HEADERS([config.h])
61AM_INIT_AUTOMAKE([1.11 std-options color-tests parallel-tests
62                  silent-rules subdir-objects])
63
64# Set default programming language
65AC_LANG(C++)
66
67# propagate selected configure variables to DISTCHECK_CONFIGURE_FLAGS
68for var in CPPFLAGS CXX CXXFLAGS CXXCPP LDFLAGS LIBS; do
69  eval isset=\${$var+set}
70  if test "$isset" = 'set' ; then
71    eval val=$`echo $var`
72    DISTCHECK_CONFIGURE_FLAGS="${DISTCHECK_CONFIGURE_FLAGS}'${var}=${val}' "
73  fi
74done
75AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
76
77# record if CXXFLAGS was set by user for further use below
78AS_IF([test "${CXXFLAGS+set}" = set], [
79  CXXFLAGS_set_by_user=yes
80],[
81  CXXFLAGS_set_by_user=no
82  # set CXXFLAGS to avoid expansion in AC_PROG_CXX
83  CXXFLAGS=
84])
85
86# Checks for programs.
87dnl FIXME remove m4_ifdef when we assume Automake 1.12
88m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
89AC_PROG_CXX
90AC_PROG_SED
91AC_PROG_LIBTOOL
92
93# find the compiler vendor: gnu, intel, etc
94AX_COMPILER_VENDOR
95
96have_doxygen=no
97AC_PATH_PROG([DOXYGEN], [doxygen], [no])
98if test "$DOXYGEN" = "no"; then
99   AC_MSG_WARN([unable to find doxygen application])
100else
101   doxygen_min_version=1.5
102   AC_MSG_CHECKING([if doxygen is at least $doxygen_min_version])
103   doxygen_version=`$DOXYGEN --version`
104   AX_COMPARE_VERSION([$doxygen_version], [ge], [$doxygen_min_version],
105                      [have_doxygen=yes], [have_doxygen=old])
106   AC_MSG_RESULT([$doxygen_version])
107fi
108
109AC_SUBST(have_doxygen)
110AM_CONDITIONAL([DX_ENABLE_HTML], [test x$have_doxygen = xyes])
111
112# check for quiet_NaN support in OS
113# Check at run-time, but if we are cross-compiling fall back on a
114# compilation test
115AC_MSG_CHECKING([if std::numeric_limits<>::has_quiet_NaN is true])
116AC_RUN_IFELSE(
117  [AC_LANG_PROGRAM(
118    [@%:@include <limits>],
119    [return !std::numeric_limits<double>::has_quiet_NaN])],
120  [quiet_nan=yes
121   AC_MSG_RESULT($quiet_nan)],
122  [quiet_nan=no
123   AC_MSG_RESULT($quiet_nan)],
124  # if we are cross-compiling fall back on compilation test
125  [AC_MSG_RESULT(cross-compiling)
126   AC_MSG_CHECKING([for std::numeric_limits<>::quiet_NaN()])
127    AC_COMPILE_IFELSE(
128     [AC_LANG_PROGRAM(
129        [@%:@include <limits>
130         extern void f(double);],
131        [f(std::numeric_limits<double>::quiet_NaN())])],
132     [quiet_nan=yes],
133     [quiet_nan=no])
134   AC_MSG_RESULT($quiet_nan)])
135# No support for quiet NAN is fatal -- sub-sequent compilation, or execution
136# of created binary, will fail.
137AS_IF([test x"$quiet_nan" = x"no"], [
138  AC_MSG_FAILURE([dnl
139Support for quiet NAN required. yat will not work on this system!])
140])
141
142# Check for infinity support for doubles in OS
143# Check at run-time, but if we are cross-compiling fall back on a
144# compilation test
145AC_MSG_CHECKING([if std::numeric_limits<>::has_infinity is true])
146AC_RUN_IFELSE(
147  [AC_LANG_PROGRAM(
148    [@%:@include <limits>],
149    [return !std::numeric_limits<double>::has_infinity])],
150  [has_infinity=yes
151   AC_MSG_RESULT($has_infinity)],
152  [has_infinity=no
153   AC_MSG_RESULT($has_infinity)],
154  # if we are cross-compiling fall back on compilation test
155  [AC_MSG_RESULT(cross-compiling)
156   AC_MSG_CHECKING([for std::numeric_limits<>::infinity()])
157    AC_COMPILE_IFELSE(
158     [AC_LANG_PROGRAM(
159        [@%:@include <limits>
160         extern void f(double);],
161        [f(std::numeric_limits<double>::infinity())])],
162     [has_infinity=yes],
163     [has_infinity=no])
164   AC_MSG_RESULT($has_infinity)])
165# No support for infinity is fatal -- sub-sequent compilation, or execution
166# of created binary, will fail.
167AS_IF([test x"${has_infinity}" = x"no"], [
168  AC_MSG_FAILURE([dnl
169Support for infinity required. yat will not work on this system!])
170])
171
172
173AC_MSG_CHECKING([g++ deprecation attribute])
174AC_COMPILE_IFELSE(
175   [AC_LANG_PROGRAM([[void f() __attribute__ ((deprecated));]],)],
176   [AC_DEFINE([YAT_HAVE_GCC_DEPRECATED], [1],
177              [Define if compiler supports deprecated attribute, as in g++ 4.0])
178    AC_MSG_RESULT([yes])],
179   [AC_MSG_RESULT([no])] )
180
181AC_MSG_CHECKING([if std::multiset::iterator is mutable])
182AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@%:@include <set>
183                                     @%:@include <vector>]],
184                                   [[std::set<std::vector<double> > s;
185                                     std::vector<double> v;
186                                     s.insert(v);
187                                     s.begin()->reserve(100);
188                                   ]])],
189                  [AC_DEFINE([MULTISET_ITERATOR_IS_MUTABLE], [1],
190                             [Define if std::multiset::iterator is mutable])
191                   AC_MSG_RESULT([yes])
192                  ],
193                  [AC_MSG_RESULT([no])] )
194
195# Save user-defined environment settings for later restoration
196APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
197APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
198APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
199APR_SAVE_THE_ENVIRONMENT(LIBS)
200
201AS_CASE([$host_os], [darwin*], [
202  YAT_LD_ADD_FLAG([LDFLAGS], [-Wl,-flat_namespace])
203])
204
205# Checks for libraries.
206AC_MSG_NOTICE([checking for libraries])
207AC_CHECK_LIBM
208LIBS="$LIBM $LIBS"
209
210# find library implementing BLAS C API, or use gslcblas
211YAT_LIB_CBLAS([YAT_CBLAS_LIB=$CBLAS_LIB], [YAT_CBLAS_LIB=-lgslcblas])
212LIBS="$YAT_CBLAS_LIB $LIBS"
213
214# GNU Scientific Library, GSL http://www.gnu.org/software/gsl/, checks
215# Including AX_PATH_GSL macro from gsl.m4 distributed by GSL
216gsl_version="1.8"
217AC_SUBST(gsl_version)
218YAT_CHECK_GSL([$gsl_version],[LIBS="-lgsl $LIBS"],[AC_MSG_FAILURE([dnl
219GSL $gsl_version (or newer) not found. The GNU Scientific Library
220(GSL) library cannot be found. Please make sure GSL is installed.])
221])
222
223# Boost http://www.boost.org
224boost_version=1.35
225AC_SUBST(boost_version)
226AX_BOOST_BASE(["$boost_version"], [], [AC_MSG_FAILURE([dnl
227Boost ${boost_version} (or newer) not found. Please install boost, or provide
228CPPFLAGS=-I/path/to/boost])
229])
230# skip boost link tests if boost is not wanted (--without-boost)
231AS_IF([test x"$want_boost" = x"yes"],[
232  AX_BOOST_THREAD
233  AX_BOOST_SYSTEM
234  YAT_CPP_ADD_FLAG([CPPFLAGS], [$BOOST_CPPFLAGS])
235  YAT_LD_ADD_FLAG([LDFLAGS], [$BOOST_LDFLAGS])
236  # boost tests above only test compilation, so let's try link in the libs
237  LIBS="$LIBS $BOOST_THREAD_LIB $BOOST_SYSTEM_LIB"
238  AC_MSG_CHECKING([for thread_specific_ptr])
239  AC_LINK_IFELSE([AC_LANG_PROGRAM([@%:@include <boost/thread/tss.hpp>],
240                                  [boost::thread_specific_ptr<int> x;
241                                   x.reset(new int(1));])],
242                 [AC_MSG_RESULT([yes])],
243                 [AC_MSG_RESULT([no])
244                  AC_MSG_FAILURE([Boost thread library not found.])
245                 ])
246])
247
248# see tickets #648 #687
249AC_MSG_CHECKING([whether constructor in boost concept is supported])
250AC_COMPILE_IFELSE([
251  AC_LANG_PROGRAM(
252    [
253     @%:@include <boost/concept_check.hpp>
254     template <typename T>
255     class MyConcept
256     {
257     public:
258       MyConcept(void) {}
259       BOOST_CONCEPT_USAGE(MyConcept){}
260     };
261    ],[
262     MyConcept<double> x;
263     x = x;
264    ])
265  ],
266  [AC_MSG_RESULT([yes])
267   AC_DEFINE([YAT_HAVE_BOOST_CONCEPT_WITH_CONSTRUCTOR],[1],
268             [define if compiler supports boost concept with constructor])
269  ],
270  [AC_MSG_RESULT([no])]
271)
272
273# Workaround problem that boost 1.41 does not work with certain versions of GCC
274# see ticket #762
275AC_MSG_CHECKING([if boost::mutex workaround is needed])
276AC_COMPILE_IFELSE(
277  [AC_LANG_PROGRAM([@%:@include <boost/thread.hpp>],
278                   [boost::mutex mutex;]
279   )],
280  [AC_MSG_RESULT([no])
281   AC_DEFINE([YAT_HAVE_WORKING_BOOST_EXCEPTION_PTR], [1],
282             [Define to 1 if boost::exception_ptr works])
283  ],
284  [AC_MSG_RESULT([yes])])
285
286# samtools API from http://samtools.sourceforge.net
287AC_ARG_WITH([samtools],
288            [AS_HELP_STRING([--without-samtools],
289                            [disable samtools support])],
290            [],
291            [with_samtools=yes])
292
293AS_IF([test x"$with_samtools" != x"no"], [
294  AC_CHECK_HEADER([zlib.h], [],
295    [AC_MSG_FAILURE([header file 'zlib.h' was not found])])
296  AC_SEARCH_LIBS([inflateEnd], [z], [],
297    [AC_MSG_FAILURE([library 'libz' was not found])])
298  YAT_CHECK_HEADER_BAM([],[AC_MSG_FAILURE([header file 'bam.h' was not found])])
299  # try link against libbam
300  YAT_CHECK_LIBBAM([LIBS="$BAM_LIBS $LIBS"
301                    AC_DEFINE([HAVE_LIBBAM], [1],
302                              [Define to 1 if libbam is available])],
303    [AC_MSG_FAILURE([library 'libbam' was not found])])
304  # check if global variable bam_nt16_rev_table is available
305  YAT_BAM_NT16_REV_TABLE
306  AC_PATH_PROG([SAMTOOLS], [samtools], [false])
307  AC_ARG_VAR([SAMTOOLS], [Tools for alignment in the SAM format])
308], [
309  SAMTOOLS=false
310])
311AM_CONDITIONAL([HAVE_LIBBAM], [test x"$with_samtools" = x"yes"])
312have_libbam=$with_samtools
313AC_SUBST([have_libbam])
314AM_CONDITIONAL([HAVE_SAMTOOLS], [test x"$SAMTOOLS" != x"false"])
315AC_SUBST([SAMTOOLS])
316AS_IF([test x"$SAMTOOLS" = x"false"], [], [
317  AC_DEFINE([HAVE_SAMTOOLS], [1], [Define if samtools executable is available])
318])
319
320#support for large files
321AC_SYS_LARGEFILE
322if test "$enable_largefile" = "no"; then
323  AC_DEFINE([YAT_LFS_DISABLED], 1,
324            [defined to 1 if large file support is disabled])
325fi
326
327AC_DEFINE([HAVE_INLINE], [1], [Define if inline is available on system])
328# default is same as --disable-debug
329AC_ARG_ENABLE([debug],
330  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])],
331        [], [enable_debug=no])
332
333# If neither --enable-assert nor --disable-assert, set enable_assert
334# to same as enable_debug
335AC_ARG_ENABLE([assert],
336              [AS_HELP_STRING([--enable-assert], [turn on assertions])],
337              [], [enable_assert=$enable_debug])
338
339# we use prefix INTERNAL_ for variables that are solely needed for
340# building yat, i.e., they are not needed for a user of yat and are
341# not propagated to yat-config or yat.m4.
342AS_IF([test "${enable_debug}" = "yes"], [
343  AC_DEFINE([YAT_DEBUG], [1], [Define to activate yat assertioons])
344  YAT_CXX_ADD_FLAG([INTERNAL_CXXFLAGS], [-Wall -pedantic -g -O])
345], [
346  # avoid defining GSL_RANGE_CHECK_OFF if GSL_RANGE_CHECK is already defined
347  AC_CHECK_DECL([GSL_RANGE_CHECK],[],
348                [AC_DEFINE([GSL_RANGE_CHECK_OFF], [1],
349                           [Define to turn off GSL range checks])])
350  # If CXXFLAGS not set by user, set it to default value
351  AS_IF([test x$CXXFLAGS_set_by_user != xyes], [
352    YAT_CXX_ADD_FLAG([INTERNAL_CXXFLAGS],[-O3])
353  ])
354])
355
356AS_IF([test x"$enable_assert" = x"no"], [
357  AC_DEFINE([NDEBUG], [1], [Define to turn off assertions])
358])
359
360# turn off compiler warning #654 from intel compiler
361AS_IF([test x"$ax_cv_cxx_compiler_vendor" = x"intel"], [
362  YAT_CXX_ADD_FLAG([CXXFLAGS], ['-diag-disable 654'])
363])
364
365# Turns warnings to errors in compilation tests. Only put tests that
366# should be warning sensitive below this point. Can't find any
367# mechanism to revert AC_LANG_WERROR
368AC_LANG_WERROR
369
370# GCC 4.0.1 on OSX complains about -pthread (issue #713)
371AS_IF([AS_ECHO(["$CPPFLAGS"]) | $GREP '\-pthread' > /dev/null],
372  [AX_CHECK_PREPROC_FLAG([-pthread], [],
373     [CPPFLAGS=`AS_ECHO(["$CPPFLAGS"]) | $SED 's%-pthread%%'`],
374     [$INTERNAL_CPPFLAGS])
375])
376
377AS_IF([test x$enable_debug = xyes], [
378  # some versions of boost uses long long - turn off compiler warnings
379  # with -Wno-long-long
380  yat_save_CXXFLAGS=$CXXFLAGS
381  AC_MSG_CHECKING([whether boost uses long long])
382  CXXFLAGS="$INTERNAL_CXXFLAGS $CXXFLAGS"
383  AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
384    [
385      @%:@include <boost/iterator/transform_iterator.hpp>
386      @%:@include <boost/thread.hpp>
387      @%:@include <cmath>
388      @%:@include <functional>
389      @%:@include <vector>
390    ],[
391      using namespace boost;
392      typedef std::pointer_to_unary_function<double, double> F;
393      std::vector<double> vec;
394      transform_iterator<F, std::vector<double>::iterator>
395        i(vec.begin(), std::ptr_fun(fabs));
396      int x = boost::thread::hardware_concurrency();
397      ++x;
398    ])],
399  [AC_MSG_RESULT([no])],
400  [AC_MSG_RESULT([yes])
401   YAT_CXX_ADD_FLAG([INTERNAL_CXXFLAGS], [-Wno-long-long])
402  ])
403  # restore CXXFLAGS
404  CXXFLAGS=$yat_save_CXXFLAGS
405])
406
407#doxygen stuff
408DX_HTML_OUTPUT=html
409AC_SUBST(DX_HTML_OUTPUT)
410
411AC_CONFIG_FILES([build_support/gen_yat_pc.sh],
412                [chmod +x build_support/gen_yat_pc.sh])
413AC_CONFIG_FILES([build_support/gen_announce.sh],
414                [chmod +x-w build_support/gen_announce.sh])
415AC_CONFIG_FILES([Makefile
416     doc/doxygen.config
417     doc/first_page.doxygen
418                 test/defs.sh
419])
420
421AC_CONFIG_HEADERS([yat/utility/config_public.h])
422# for the test suite
423yat_abs_top_srcdir=`cd $srcdir && pwd`
424AC_DEFINE_UNQUOTED([YAT_ABS_TOP_SRCDIR], ["$yat_abs_top_srcdir"],
425                   [Define to absolute path to top yat src dir])
426
427# Reset flags
428APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, YAT_)
429APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, YAT_)
430APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, YAT_)
431APR_RESTORE_THE_ENVIRONMENT(LIBS, YAT_)
432
433# YAT_LIBS minus cblas and math libraries
434YAT_PRIMARY_LIBS=
435for lib in $YAT_LIBS; do
436  AS_CASE([$lib], [$YAT_CBLAS_LIB], [],
437          [$LIBM], [],
438          [YAT_PRIMARY_LIBS="$YAT_PRIMARY_LIBS $lib"])
439done
440# workaround for ticket #736
441for lib in $BAM_LIBS; do
442  APR_REMOVEFROM([YAT_PRIMARY_LIBS], [$lib])
443done
444AC_SUBST(BAM_LIBS)
445AC_SUBST(YAT_PRIMARY_LIBS)
446AC_SUBST(YAT_LIBS)
447AC_SUBST(YAT_CBLAS_LIB)
448
449# set and AC_SUBST variables that are interpreted by Automake
450AM_CPPFLAGS="$INTERNAL_CPPFLAGS $YAT_CPPFLAGS"
451AM_CXXFLAGS="$INTERNAL_CXXFLAGS $YAT_CXXFLAGS"
452AM_LDFLAGS="$INTERNAL_LDFLAGS $YAT_LDFLAGS"
453
454AC_SUBST(AM_CPPFLAGS)
455AC_SUBST(AM_CXXFLAGS)
456AC_SUBST(AM_LDFLAGS)
457AC_SUBST([enable_shared])
458AC_SUBST([enable_static])
459
460YAT_SVN_RELEASE([am/maintainer.am])
461
462# make shell tests work in VPATH builds
463AC_CONFIG_LINKS([test/init.sh:test/init.sh])
464
465# set some variable for final message
466AS_CASE([$have_doxygen],
467        [yes], [doxygen_message=yes],
468        [no], [doxygen_message="no (doxygen not found)"],
469        [old], [doxygen_message="no (\`$DOXYGEN' too old)"],
470        [AC_MSG_WARN([unexpected value \$have_doxygen: '$have_doxygen'])
471         AS_BOX([Report this to ]AC_PACKAGE_BUGREPORT)
472        ])
473
474yat_gslcblas_message=
475AS_IF([test "x$YAT_CBLAS_LIB" = "x-lgslcblas"], [
476yat_gslcblas_message='
477  GSL CBLAS found. This is a reference implementation only.
478  Consider using hardware optimized BLAS.
479  ATLAS (http://math-atlas.sourceforge.net/) provides an
480  optimized BLAS library. It is supported by yat!
481'
482])
483
484# Create output.
485AC_OUTPUT
486
487
488# Some more messages.
489AC_MSG_RESULT([
490yat is configured as follows:
491
492  Build Shared Library: $enable_shared
493  Build Static Library: $enable_static
494  Build Documentation:  $doxygen_message
495  With Bam Support:     $with_samtools
496
497Options used to compile and link:
498  VERSION     = $VERSION
499  CXX         = $CXX
500  CPPFLAGS    = $CPPFLAGS
501  YAT_CPPFLAGS= $AM_CPPFLAGS
502  CXXFLAGS    = $CXXFLAGS
503  YAT_CXXFLAGS= $AM_CXXFLAGS
504  LD          = $LD
505  LDFLAGS     = $LDFLAGS
506  YAT_LDFLAGS = $AM_LDFLAGS
507  LIBS        = $LIBS
508  YAT_LIBS    = $YAT_LIBS
509${yat_gslcblas_message}dnl
510----------------------------------------------------------------
511Now type `make'. dnl
512])
Note: See TracBrowser for help on using the repository browser.