source: trunk/configure.ac @ 944

## Process this file with autoconf to produce a configure script.
##
## $Id: configure.ac 944 2007-10-07 21:10:51Z peter $

# Copyright (C) 2003 Daniel Dalevi, Jari Häkkinen
# Copyright (C) 2004 Jari Häkkinen
# Copyright (C) 2005, 2006, 2007 Jari Häkkinen, Peter Johansson
#
# This file is part of the yat library, http://trac.thep.lu.se/trac/yat
#
# The yat library is free software; you can redistribute it
# and/or modify it under the terms of the GNU General Public License as
# published by the Free Software Foundation; either version 2 of the
# License, or (at your option) any later version.
#
# The yat library is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
# 02111-1307, USA.
#
# If you grabbed the source from the subversion repository you should,
# at top-level, execute:
#     ./bootstrap

AC_PREREQ(2.57)
AC_INIT([[yat]],[0.4pre],[jari@thep.lu.se])
AC_CONFIG_SRCDIR([yat/utility/matrix.h])
AC_CONFIG_AUX_DIR([autotools])
AC_PREFIX_DEFAULT([/usr/local])

AM_CONFIG_HEADER([config.h])
AM_INIT_AUTOMAKE()

# Checks for programs.
AC_PROG_CXX
AC_PROG_INSTALL
AC_CHECK_PROG([DOXYGEN], [doxygen], [yes], [no])
AC_CHECK_PROG([DVIPDFM], [dvipdfm], [yes], [no])
AC_CHECK_PROG([LATEX], [latex], [yes], [no])
AC_CHECK_PROG([LATEX2HTML], [latex2html], [yes], [no])

# Checks for libraries.
AC_CHECK_LIB(m,main)
AC_SEARCH_LIBS(ATL_ctrsv,atlas,,
  AC_SEARCH_LIBS(cblas_sdsdot,gslcblas))
AC_CHECK_LIB(gsl,main)

AM_PATH_GSL(1.6,,[AC_MSG_ERROR(could not find required version of GSL)])

# Set default programming language
AC_LANG(C++)

# Checks for header files.
AC_CHECK_HEADERS([unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_HEADER_STDBOOL
AC_C_CONST
AC_C_INLINE
AC_TYPE_SIZE_T

# Checks for library functions.
AC_PROG_LIBTOOL
AC_FUNC_ERROR_AT_LINE
AC_HEADER_STDC
AC_CHECK_FUNCS([pow sqrt])

CXXFLAGS="-Wall -pedantic"
CPPFLAGS="-DHAVE_INLINE=1"
AC_ARG_ENABLE(debug,
  [AS_HELP_STRING([--enable-debug],[turn on debug options and code])])
if test "${enable_debug}" = "yes" ; then
  CXXFLAGS="$CXXFLAGS -g -O"
  CPPFLAGS="$CPPFLAGS -DYAT_DEBUG=1"
else
  CXXFLAGS="$CXXFLAGS -O3"
  CPPFLAGS="$CPPFLAGS -DNDEBUG -DGSL_RANGE_CHECK_OFF"
fi

# check for quiet_NaN support in OS
# At compile time, but this may not work if quiet_NaN exists and returns
# an incorrect value
AC_MSG_CHECKING([for std::numeric_limits<>::quiet_NaN()])
AC_COMPILE_IFELSE(
  [AC_LANG_PROGRAM(
    [#include <limits>
     extern void f(double);],
    [f(std::numeric_limits<double>::quiet_NaN())])],
  [quiet_nan=yes],
  [quiet_nan=no])
AC_MSG_RESULT($quiet_nan)
if test "${quiet_nan}" = "no" ; then
  AC_MSG_FAILURE([
    Support for quiet NAN required.
    Yat will not work on this system!])
fi
# At run-time, but this has the disadvantage that yat cannot be built  
# for cross-compilation
AC_MSG_CHECKING([if std::numeric_limits<>::has_quiet_NaN is true])
AC_RUN_IFELSE(
  [AC_LANG_PROGRAM(
    [#include <limits>],
    [return !std::numeric_limits<double>::has_quiet_NaN])],
  [quiet_nan=yes],
  [quiet_nan=no])
AC_MSG_RESULT($quiet_nan)
if test "${quiet_nan}" = "no" ; then
  AC_MSG_FAILURE([
    Support for quiet NAN required.
    Yat will not work on this system!])
fi

# yat specific settings
YAT_LIB="libyat.la"
YAT_LIB_LOCATION="yat"
AC_SUBST(YAT_LIB)
AC_SUBST(YAT_LIB_LOCATION)

# Only warning about missing programs (needed for docs generation)
# when in debug mode
if (test "$enable_debug" == "yes"); then
   if (test "$DOXYGEN" != "yes") ; then
      AC_MSG_WARN([Doxygen was not found. Yat will compile and work
      without doxygen.  However, in order to enable generation of
      documentation, please install doxygen available at
      http://www.doxygen.org/])
   fi        
   if (test "$LATEX" != "yes") ; then
      AC_MSG_WARN([latex was not found. Yat will compile and work
      without latex. However, supporting documentation on statistics
      used in yat cannot be generated without latex.])
   fi        
   if (test "$DVIPFDM" != "yes") ; then
      AC_MSG_WARN([dvipdfm was not found. Yat will compile and work
      without dvipdfm. However, pdf document on statistics used in yat
      cannot be generated without dvipdfm.])
   fi        
   if (test "$LATEX2HTML" != "yes") ; then
      AC_MSG_WARN([latex2html was not found. Yat will compile and work
      without Latex. However, html document on statistics used in yat
      cannot be generated without latex.])
   fi        
fi

AC_CONFIG_FILES([Makefile
     doc/Makefile
     test/Makefile
     test/data/Makefile
     yat/Makefile
     yat/classifier/Makefile
     yat/random/Makefile
     yat/regression/Makefile
     yat/statistics/Makefile
     yat/utility/Makefile])

AC_OUTPUT

# Some more messages.
AC_MSG_NOTICE([])
AC_MSG_NOTICE([ Ready to compile the yat library])
AC_MSG_NOTICE([ The following flags and libraries will be used:])
AC_MSG_NOTICE([ +++++++++++++++++++++++++++++++++++++++++++++++])
AC_MSG_NOTICE([  CPPFLAGS=\"$CPPFLAGS\"])
AC_MSG_NOTICE([  CXXFLAGS=\"$CXXFLAGS\"])
AC_MSG_NOTICE([  LIBS=\"$LIBS\"])
AC_MSG_NOTICE([ +++++++++++++++++++++++++++++++++++++++++++++++])
AC_MSG_NOTICE([])
AC_MSG_NOTICE([ Now type 'make ; make check'.])