source: trunk/m4/yat_check_func.m4 @ 4102

## $Id: yat_check_func.m4 4102 2021-09-22 07:50:18Z peter $
#
# Copyright (C) 2021 Peter Johansson
#
# This file is part of the yat library, https://dev.thep.lu.se/yat
#
# The yat library is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License as
# published by the Free Software Foundation; either version 3 of the
# License, or (at your option) any later version.
#
# The yat library is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with yat. If not, see <https://www.gnu.org/licenses/>.
#

#
# serial 1 (yat 0.20)
#

# YAT_CHECK_FUNC(function, [prologue], [body], [action-if-found],
#                [action-if-not-found])
# ==========================================================
# Wrapper around AC_CACHE_CHECK and AC_COMPILE_IFELSE. Try to compile
# program with prologue 'prologue' and body 'body'. If successful, run
# shell commands action-if-found, otherwise
# action-if-not-found. Result is cached in variable
# $yat_cv_func_<function>
AC_DEFUN([YAT_CHECK_FUNC],
[
  AS_VAR_PUSHDEF([yat_CACHE], [AS_TR_SH([yat_cv_func_$1])])dnl
  AC_CACHE_CHECK([if $CXX supports $1], [yat_CACHE], [
    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
                      [yat_CACHE=yes],
                      [yat_CACHE=no])
  ])
  AS_VAR_IF([yat_CACHE], [yes], [$4], [$5])
  AS_VAR_POPDEF([yat_CACHE])dnl
])