source: trunk/m4/yat_check_libbam.m4 @ 2986

## $Id: yat_check_libbam.m4 2986 2013-02-18 08:07:44Z peter $
#
# serial 2 (yat 0.10.2)
#
#
#   Copyright (C) 2012, 2013 Peter Johansson
#
#   This file is part of the yat library, http://dev.thep.lu.se/yat
#
#   The yat library is free software; you can redistribute it and/or
#   modify it under the terms of the GNU General Public License as
#   published by the Free Software Foundation; either version 3 of the
#   License, or (at your option) any later version.
#
#   The yat library is distributed in the hope that it will be useful,
#   but WITHOUT ANY WARRANTY; without even the implied warranty of
#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
#   General Public License for more details.
#
#   You should have received a copy of the GNU General Public License
#   along with yat. If not, see <http://www.gnu.org/licenses/>.

# YAT_CHECK_HEADER_BAM([action-if-found], [action-if-not-found])
# ==============================================================
#
AC_DEFUN([YAT_CHECK_HEADER_BAM],
[
yat_bam_header=no
# check how to #include <bam.h>
AC_CHECK_HEADERS([bam/bam.h bam.h samtools/bam.h bam.h],
                 [yat_bam_header=yes; break])
AS_IF([test x$yat_bam_header = xyes], [$1], [$2])
]) # YAT_CHECK_HEADER_BAM


# YAT_CHECK_LIBBAM([action-if-found], [action-if-not-found])
# ==========================================================
#
AC_DEFUN([YAT_CHECK_LIBBAM],
[
AC_REQUIRE([YAT_CHECK_HEADER_BAM])
BAM_LIBS=no
AC_MSG_CHECKING([for library containing bam_header_destroy])
for libs in "" "-lbam" "-lbam -lpthread"; do
  AS_IF([test x"$BAM_LIBS" = x"no"], [
    YAT_LINK_BAM_IFELSE([$libs], [BAM_LIBS=$libs])
  ])
done
AS_IF([test x"$BAM_LIBS" = x""], [
  AC_MSG_RESULT([none required])
],[
  AC_MSG_RESULT([$BAM_LIBS])
])
AS_IF([test x"$BAM_LIBS" = xno], [$2], [$1])
]) # YAT_CHECK_LIBBAM



# YAT_LINK_BAM_IFELSE([lib], [action-if-found], [action-if-not-found])
# ====================================================================
# Add lib to LIBS and try to link some code using libbam
AC_DEFUN([YAT_LINK_BAM_IFELSE],
[
save_LIBS=$LIBS
LIBS="$1 $LIBS"
AC_LINK_IFELSE([AC_LANG_PROGRAM([@%:@if HAVE_BAM_H
                                 @%:@ include <bam.h>
                                 @%:@elif HAVE_BAM_BAM_H
                                 @%:@ include <bam/bam.h>
                                 @%:@elif HAVE_SAMTOOLS_BAM_H
                                 @%:@ include <samtools/bam.h>
                                 @%:@endif
                                ],[
                                 bam_header_t* hdr = bam_header_init();
                                 bam_header_destroy(hdr);
                                ])],
               [$2], [$3])
LIBS=$save_LIBS
]) # YAT_LINK_BAM_IFELSE

# YAT_BAM_NT16_REV_TABLE
# ====================================================================
# Check if global variable bam_nt16_rev_table is available in
# -lbam. If found call AC_DEFINE(HAVE_BAM_NT16_REV_TABLE).
AC_DEFUN([YAT_BAM_NT16_REV_TABLE],
[
AC_MSG_CHECKING([for bam_nt16_rev_table])
AC_LINK_IFELSE([AC_LANG_PROGRAM(
                 [@%:@if HAVE_BAM_H
                  @%:@ include <bam.h>
                  @%:@elif HAVE_BAM_BAM_H
                  @%:@ include <bam/bam.h>
                  @%:@elif HAVE_SAMTOOLS_BAM_H
                  @%:@ include <samtools/bam.h>
                  @%:@endif
                 ],[
                  char c = bam_nt16_rev_table@<:@7@:>@;
                 ])
               ],[
                 AC_MSG_RESULT([yes])
                 AC_DEFINE([HAVE_BAM_NT16_REV_TABLE], [1],
                           [Define to 1 if libbam contains bam_nt16_rev_table])
               ],[
                 AC_MSG_RESULT([no])
               ])
]) # YAT_BAM_NT16_REV_TABLE