source: trunk/m4/yat_check_libbam.m4 @ 3306

## $Id: yat_check_libbam.m4 3306 2014-08-21 04:37:21Z peter $
#
# serial 5 (yat 0.12.1)
#
#
#   Copyright (C) 2012, 2013, 2014 Peter Johansson
#
#   This file is part of the yat library, http://dev.thep.lu.se/yat
#
#   The yat library is free software; you can redistribute it and/or
#   modify it under the terms of the GNU General Public License as
#   published by the Free Software Foundation; either version 3 of the
#   License, or (at your option) any later version.
#
#   The yat library is distributed in the hope that it will be useful,
#   but WITHOUT ANY WARRANTY; without even the implied warranty of
#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
#   General Public License for more details.
#
#   You should have received a copy of the GNU General Public License
#   along with yat. If not, see <http://www.gnu.org/licenses/>.

# YAT_CHECK_HEADER_BAM([action-if-found], [action-if-not-found])
# ==============================================================
#
AC_DEFUN([YAT_CHECK_HEADER_BAM],
[
yat_bam_header=no
# check how to #include <bam.h>
m4_foreach_w([myheader], [bam.h bam/bam.h samtools/bam.h],
             [_YAT_CHECK_HEADER_BAM(myheader)
])
AS_IF([test x$yat_bam_header = xyes], [$1], [$2])
]) # YAT_CHECK_HEADER_BAM


# _YAT_CHECK_HEADER_BAM
# =====================
# Private macro used in YAT_CHECK_HEADER_BAM
AC_DEFUN([_YAT_CHECK_HEADER_BAM],
[
AS_IF([test x$yat_bam_header = xno], [dnl
  AC_CHECK_HEADER([$1], [
    AC_DEFINE_UNQUOTED(AS_TR_CPP([YAT_HAVE_$1]), [1],
                       [Define to 1 if you have <$1> header file])
    yat_bam_header=yes;
  ])
])
]) # _YAT_CHECK_HEADER_BAM


# YAT_CHECK_LIBBAM([action-if-found], [action-if-not-found])
# ==========================================================
#
AC_DEFUN([YAT_CHECK_LIBBAM],
[
BAM_LIBS=no
AC_MSG_CHECKING([for library containing bam_header_destroy])
for libs in "" "-lbam" "-lbam -lpthread"; do
  AS_IF([test x"$BAM_LIBS" = x"no"], [
    YAT_LINK_BAM_IFELSE([$libs], [BAM_LIBS=$libs])
  ])
done
AS_IF([test x"$BAM_LIBS" = x""], [
  AC_MSG_RESULT([none required])
],[
  AC_MSG_RESULT([$BAM_LIBS])
])
AS_IF([test x"$BAM_LIBS" = xno], [$2], [$1])
]) # YAT_CHECK_LIBBAM



# YAT_LINK_BAM_IFELSE([lib], [action-if-found], [action-if-not-found])
# ====================================================================
# Add lib to LIBS and try to link some code using libbam
AC_DEFUN([YAT_LINK_BAM_IFELSE],
[
save_LIBS=$LIBS
LIBS="$1 $LIBS"
AC_LINK_IFELSE([AC_LANG_PROGRAM([_YAT_BAM_INCLUDES],
                                [
                                 bam_header_t* hdr = bam_header_init();
                                 bam_header_destroy(hdr);
                                ])],
               [$2], [$3])
LIBS=$save_LIBS
]) # YAT_LINK_BAM_IFELSE

# YAT_BAM_NT16_REV_TABLE
# ====================================================================
# Check if global variable bam_nt16_rev_table is available in
# -lbam. If found call AC_DEFINE(HAVE_BAM_NT16_REV_TABLE).
AC_DEFUN([YAT_BAM_NT16_REV_TABLE],
[
AC_MSG_CHECKING([for bam_nt16_rev_table])
AC_LINK_IFELSE([AC_LANG_PROGRAM([_YAT_BAM_INCLUDES],
                  [char c = bam_nt16_rev_table@<:@7@:>@;])
               ],[
                 AC_MSG_RESULT([yes])
                 AC_DEFINE([HAVE_BAM_NT16_REV_TABLE], [1],
                           [Define to 1 if libbam contains bam_nt16_rev_table])
               ],[
                 AC_MSG_RESULT([no])
               ])
]) # YAT_BAM_NT16_REV_TABLE


# YAT_FUNC_BAM_CALEND(SAM_FILE)
# ===================
# Check if there is a bam_calend that works
AC_DEFUN([YAT_FUNC_BAM_CALEND],
[
  AC_CACHE_CHECK([for working bam_calend],
    [yat_cv_func_bam_calend],
    [AC_RUN_IFELSE(
       [AC_LANG_PROGRAM(
          [_YAT_BAM_INCLUDES],
          [
          samfile_t* samfile = samopen("$1", "r", NULL);
          if (!samfile)
            return 1;
          bam1_t* read = bam_init1();
          while (samread(samfile, read) >= -1) {
            bool have_match = false;
            if (read->core.n_cigar < 1)
              continue;
            uint32_t end = bam_calend(&read->core, bam1_cigar(read));
            // replace BAM_CMATCH with BAM_CEQUAL in cigar
            for (size_t k=0; k<read->core.n_cigar; ++k) {
              uint32_t& element = bam1_cigar(read)@<:@k@:>@;
              uint32_t op = element & BAM_CIGAR_MASK;
              if (op == BAM_CMATCH) {
                have_match = true;
                uint32_t oplen = element >> BAM_CIGAR_SHIFT;
                element = oplen<<BAM_CIGAR_SHIFT|BAM_CEQUAL;
              }
            }
            // if no match element found, next read please
            if (!have_match)
              continue;
            // bam_calend works on BAM_CEQUAL
            if (bam_calend(&read->core, bam1_cigar(read)) == end)
              return 0;
            // bam_calend is not working as expected
            return 2;
          }
          // end of data, fail
          return 3;
          ])
       ],
       [yat_cv_func_bam_calend=yes],
       [yat_cv_func_bam_calend=no],
       [yat_cv_func_bam_calend="guessing no"])
    ])
  AS_IF([test x"$yat_cv_func_bam_calend" = x"yes"],[
    AC_DEFINE([HAVE_BAM_CALEND], [1], [Define to 1 if bam_calend is working])
  ])
])


# _YAT_BAM_INCLUDES
# =================
# Private macro that expand PP magic we see in 'yat/omic/bam_config.h'
AC_DEFUN([_YAT_BAM_INCLUDES],
[AC_REQUIRE([YAT_CHECK_HEADER_BAM])
@%:@if YAT_HAVE_BAM_H
@%:@ include <bam.h>
@%:@ include <sam.h>
@%:@elif YAT_HAVE_BAM_BAM_H
@%:@ include <bam/bam.h>
@%:@ include <bam/sam.h>
@%:@elif YAT_HAVE_SAMTOOLS_BAM_H
@%:@ include <samtools/bam.h>
@%:@ include <samtools/sam.h>
@%:@endif
]) # _YAT_BAM_HEADER