source: trunk/m4/yat_lt_link_ifelse.m4 @ 2451

## $Id: yat_lt_link_ifelse.m4 2451 2011-03-28 23:16:14Z peter $
#
# SYNOPSIS
#
#   YAT_LT_LINK_IFELSE(program, [action-if-true], [action-if-not-true])
#
# DESCRIPTION
#
# COPYLEFT
#
#   Copyright (C) 2010, 2011 Peter Johansson
#
#   This file is part of the yat library, http://dev.thep.lu.se/yat
#
#   The yat library is free software; you can redistribute it and/or
#   modify it under the terms of the GNU General Public License as
#   published by the Free Software Foundation; either version 3 of the
#   License, or (at your option) any later version.
#
#   The yat library is distributed in the hope that it will be useful,
#   but WITHOUT ANY WARRANTY; without even the implied warranty of
#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
#   General Public License for more details.
#
#   You should have received a copy of the GNU General Public License
#   along with yat. If not, see <http://www.gnu.org/licenses/>.
#

# Based on _KPSE_USE_LIBTOOL by 
# Peter Breitenlohner <peb@mppmu.mpg.de> shared here
# http://www.mail-archive.com/autoconf@gnu.org/msg19948.html

#
# serial 3 
#

# YAT_LT_LINK_IFELSE(PROG, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
# -------------------------------------------------------------
# Same as AC_LINK_IFELSE but linking via libtool
AC_DEFUN([YAT_LT_LINK_IFELSE],
[
  YAT_USE_LIBTOOL_PUSH
  AC_LINK_IFELSE($@)
  YAT_USE_LIBTOOL_POP
]) # YAT_LT_LINK_IFELSE

# YAT_USE_LIBTOOL_PUSH
# --------------------
# Assign `$ac_link' and `$ac_compile' to use libtool. Variables are
# saved so they can be restored with YAT_USE_LIBTOOL_POP
AC_DEFUN([YAT_USE_LIBTOOL_PUSH],
[
m4_defn([LT_INIT])
m4_ifdef([_YAT_USE_LIBTOOL], [],
  [LT_OUTPUT
   yat_use_libtool_ac_compile=$ac_compile;
   ac_compile="./libtool --mode=compile --tag=_YAT_USE_LIBTOOL_TAG $ac_link";
   yat_use_libtool_ac_link=$ac_link;
   ac_link="./libtool --mode=link --tag=_YAT_USE_LIBTOOL_TAG $ac_link";
  ]) dnl
m4_pushdef([_YAT_USE_LIBTOOL], [yes])
]) # YAT_USE_LIBTOOL_PUSH

# YAT_USE_LIBTOOL_POP
# --------------------

# Restore values of `$ac_link' and `$ac_compile' to what they were
# prior YAT_USE_LIBTOOL_PUSH
AC_DEFUN([YAT_USE_LIBTOOL_POP],
[
m4_popdef([_YAT_USE_LIBTOOL])
m4_ifndef([_YAT_USE_LIBTOOL], dnl
  [ac_compile=$yat_use_libtool_ac_compile;
   ac_link=$yat_use_libtool_ac_link;
  ])
]) # YAT_USE_LIBTOOL_POP


# _YAT_USE_LIBTOOL_TAG
# --------------------
# internal macro to select tag depending on active library
m4_define([_YAT_USE_LIBTOOL_TAG],
[AC_LANG_CASE([C], [CC], dnl
              [C++], [CXX], dnl
              [Fortran 77], [F77], dnl
              [Fortran], [FC]) dnl
])