source: trunk/m4/yat_msg_error.m4

## $Id: yat_msg_error.m4 2865 2012-11-11 00:58:24Z peter $

#
# serial 3 (yat 0.10)
#

#
#   Copyright (C) 2011, 2012 Peter Johansson
#
#   This file is part of the yat library, http://dev.thep.lu.se/yat
#
#   The yat library is free software; you can redistribute it and/or
#   modify it under the terms of the GNU General Public License as
#   published by the Free Software Foundation; either version 3 of the
#   License, or (at your option) any later version.
#
#   The yat library is distributed in the hope that it will be useful,
#   but WITHOUT ANY WARRANTY; without even the implied warranty of
#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
#   General Public License for more details.
#
#   You should have received a copy of the GNU General Public License
#   along with yat. If not, see <http://www.gnu.org/licenses/>.
#

# YAT_MSG_ERROR(ERROR)
#
# Just like AC_MSG_ERROR this macro prints an error message, ERROR, to
# standard error and exits. But rather than doing that immediately
# this macro lets configure continue and prints the error message and
# exits just before the end.
#
AC_DEFUN([YAT_MSG_ERROR],
[
  AC_REQUIRE([YAT_MSG_ERROR_PREPARE])
  AS_ECHO(["$1"]) >> yat_msg_error.txt
  AS_ECHO(["$as_me:$LINENO: error: $1"]) >& AS_MESSAGE_LOG_FD
]) # YAT_MSG_ERROR

# YAT_MSG_ERROR_PREPARE([MESSAGE])
#
# The error messages generated by YAT_MSG_ERROR is preceeded by a
# message: 'some requirements were not fulfilled, see below'. This
# default message can can be changed to MESSAGE by calling
# YAT_MSG_ERROR_PREPARE prior the first YAT_MSG_ERROR.
AC_DEFUN([YAT_MSG_ERROR_PREPARE],
[
rm -f yat_msg_error.txt
AC_CONFIG_COMMANDS_PRE([
   AS_IF([test -f yat_msg_error.txt], [
     msg="m4_default([$1], [some requirements were not fulfilled, see below])"
     AS_ECHO(["$as_me: error: $msg"]) >&2
     cat yat_msg_error.txt >&2
     AS_EXIT([1])
   ])
  ])
]) # _YAT_MSG_ERROR