source: trunk/m4/yat_string.m4 @ 4102

## $Id: yat_string.m4 4102 2021-09-22 07:50:18Z peter $
#
# Copyright (C) 2021 Peter Johansson
#
# This file is part of the yat library, https://dev.thep.lu.se/yat
#
# The yat library is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License as
# published by the Free Software Foundation; either version 3 of the
# License, or (at your option) any later version.
#
# The yat library is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with yat. If not, see <https://www.gnu.org/licenses/>.
#

#
# serial 1 (yat 0.20)
#


# YAT_FUNC_STRING_CONTAINS([action-if-found], [action-if-not-found]
# =================================================================
# Test if CXX supports std::string::contains. If not successful issue
# action-if-not-found. If successful issue action-if-found, or if
# empty issue AC_DEFINE([YAT_HAVE_FUNC_STRING_CONTAINS])
AC_DEFUN([YAT_FUNC_STRING_CONTAINS],
[
  YAT_FUNC_STRING([contains], [$1], [$2])
])


# YAT_FUNC_STRING_ENDS_WITH([action-if-found], [action-if-not-found]
# =================================================================
# Test if CXX supports std::string::ends_with. If not successful issue
# action-if-not-found. If successful issue action-if-found, or if
# empty issue AC_DEFINE([YAT_HAVE_FUNC_STRING_ENDS_WITH])
AC_DEFUN([YAT_FUNC_STRING_ENDS_WITH],
[
  YAT_FUNC_STRING([ends_with], [$1], [$2])
])


# YAT_FUNC_STRING_STARTS_WITH([action-if-found], [action-if-not-found]
# =================================================================
# Test if CXX supports std::string::starts_with. If not successful
# issue action-if-not-found. If successful issue action-if-found, or
# if empty issue AC_DEFINE([YAT_HAVE_FUNC_STRING_STARTS_WITH])
AC_DEFUN([YAT_FUNC_STRING_STARTS_WITH],
[
  YAT_FUNC_STRING([starts_with], [$1], [$2])
])


# YAT_FUNC_STRING(funcion, [action-if-found], [action-if-not-found])
# =================================================================
# Test if CXX supports std::string::func-name. The test includes a
# test for std::string::<function>(std::string),
# std::string::<function>(char), and std::string::<function>(const
# char*) If not successful issue action-if-not-found. If successful
# issue action-if-found, or if empty issue
# AC_DEFINE([YAT_HAVE_FUNC_STRING_<function>])
AC_DEFUN([YAT_FUNC_STRING],
[
  YAT_CHECK_FUNC([string::$1], [
    @%:@include <string>
    ], [
      std::string str("Hello world!");
      str.$1("world");
      str.$1('H');
      str.$1(str);
    ], [m4_default([$2],
                   [AC_DEFINE(AS_TR_CPP([YAT_HAVE_FUNC_STRING_$1]), [1],
                              [Define if you have function std::string::$1])
                   ])
    ], [$3]
  )
])