source: trunk/m4/yat_thread.m4

## $Id: yat_thread.m4 3960 2020-08-01 04:17:31Z peter $
#
# Copyright (C) 2020 Peter Johansson
#
# This file is part of the yat library, http://dev.thep.lu.se/yat
#
# The yat library is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License as
# published by the Free Software Foundation; either version 3 of the
# License, or (at your option) any later version.
#
# The yat library is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with yat. If not, see <http://www.gnu.org/licenses/>.
#

#
# serial 1 (yat 0.18)
#


# YAT_THREAD
# ====================
AC_DEFUN([YAT_THREAD],
[
YAT_THREAD_COMPILE_IFELSE_([
  yat_thread_save_CPPFLAGS="$CPPFLAGS"

  YAT_CHECK_LIBS([for linker flag needed for thread],
                 [yat_cv_thread_libs], [pthread],
                 [YAT_THREAD_PROGRAM_],
                 [CPPFLAGS="$yat_thread_save_CPPFLAGS"
                  $1],
                 [CPPFLAGS="$yat_thread_save_CPPFLAGS"
                  $2])
], [
  $2
])
]) #YAT_THREAD


# Internal macro looking for compiler flags needed for thread support
AC_DEFUN([YAT_THREAD_COMPILE_IFELSE_],
[
AS_VAR_PUSHDEF([my_CACHE], [yat_cv_thread_cppflags])dnl
AC_CACHE_CHECK([for compiler flag needed for thread], [my_CACHE],
  [yat_thread_compile_result=unsupported
   yat_thread_compile_CPPFLAGS="$CPPFLAGS"
   for yat_opt in '' '-pthread' '-pthreads' '-mthreads'; do
     AS_VAR_IF([yat_thread_compile_result], [unsupported], [
       CPPFLAGS="$yat_thread_compile_CPPFLAGS $yat_opt"
       AC_COMPILE_IFELSE([YAT_THREAD_PROGRAM_],
                         [yat_thread_compile_result="$yat_opt"])
     ])
   done

   # restore flags
   CPPFLAGS="$yat_thread_compile_CPPFLAGS"

   # translate test result to someting suitable to display
   AS_CASE([x"$yat_thread_compile_result"],
           [x""], [my_CACHE=none],
           [my_CACHE="$yat_thread_compile_result"])
  ])

AS_CASE([$my_CACHE],
        ["none"], [$1],
        [unsupported], [$2],
        [YAT_THREAD_CPPFLAGS="$my_CACHE"
         $1])
AS_VAR_POPDEF([my_CACHE])
])


# private macro defining the code used in tests for std::thread
AC_DEFUN([YAT_THREAD_PROGRAM_],
[
AC_LANG_PROGRAM([[
  @%:@include <thread>
  void foo(void) {}
]], [[
  std::thread t(foo);
  t.join();
]])
])
}