Changeset 3303

Timestamp:

Aug 21, 2014, 5:55:50 AM (9 years ago)

Author:

Peter

Message:

New macro YAT_FUNC_BAM_CALEND, which checks if function bam_calend is
buggy. If the function works as expected, HAVE_BAM_CALEND is
AC_DEFINEd so bam_calend is used. Closes #810.

Location:

branches/0.12-stable

Files:

• configure.ac (modified) (1 diff)
• m4/yat_check_libbam.m4 (modified) (3 diffs)

branches/0.12-stable/configure.ac

@@ -383 +383 @@
   # check if global variable bam_nt16_rev_table is available
   YAT_BAM_NT16_REV_TABLE
+  # check if function bam_calend works. Result of this test can be
+  # overridden by setting variable 'yat_cv_func_bam_calend'
+  YAT_FUNC_BAM_CALEND([$srcdir/test/data/foo.sam])
   AC_PATH_PROG([SAMTOOLS], [samtools], [false])
   AC_ARG_VAR([SAMTOOLS], [Tools for alignment in the SAM format])

branches/0.12-stable/m4/yat_check_libbam.m4

@@ -1 +1 @@
 ## $Id$
 #
-# serial 4 (yat 0.11)
+# serial 5 (yat 0.12.1)
 #
 #
-#   Copyright (C) 2012, 2013 Peter Johansson
+#   Copyright (C) 2012, 2013, 2014 Peter Johansson
 #
 #   This file is part of the yat library, http://dev.thep.lu.se/yat
@@ -107 +107 @@
 
 
+# YAT_FUNC_BAM_CALEND(SAM_FILE)
+# ===================
+# Check if there is a bam_calend that works
+AC_DEFUN([YAT_FUNC_BAM_CALEND],
+[
+  AC_CACHE_CHECK([for working bam_calend],
+    [yat_cv_func_bam_calend],
+    [AC_RUN_IFELSE(
+       [AC_LANG_PROGRAM(
+          [_YAT_BAM_INCLUDES],
+          [
+          samfile_t* samfile = samopen("$1", "r", NULL);
+          if (!samfile)
+            return 1;
+          bam1_t* read = bam_init1();
+          while (samread(samfile, read) >= -1) {
+            bool have_match = false;
+            if (read->core.n_cigar < 1)
+              continue;
+            uint32_t end = bam_calend(&read->core, bam1_cigar(read));
+            // replace BAM_CMATCH with BAM_CEQUAL in cigar
+            for (size_t k=0; k<read->core.n_cigar; ++k) {
+              uint32_t& element = bam1_cigar(read)@<:@k@:>@;
+              uint32_t op = element & BAM_CIGAR_MASK;
+              if (op == BAM_CMATCH) {
+                have_match = true;
+                uint32_t oplen = element >> BAM_CIGAR_SHIFT;
+                element = oplen<<BAM_CIGAR_SHIFT|BAM_CEQUAL;
+              }
+            }
+            // if no match element found, next read please
+            if (!have_match)
+              continue;
+            // bam_calend works on BAM_CEQUAL
+            if (bam_calend(&read->core, bam1_cigar(read)) == end)
+              return 0;
+            // bam_calend is not working as expected
+            return 2;
+          }
+          // end of data, fail
+          return 3;
+          ])
+       ],
+       [yat_cv_func_bam_calend=yes],
+       [yat_cv_func_bam_calend=no],
+       [yat_cv_func_bam_calend="guessing no"])
+    ])
+  AS_IF([test x"$yat_cv_func_bam_calend" = x"yes"],[
+    AC_DEFINE([HAVE_BAM_CALEND], [1], [Define to 1 if bam_calend is working])
+  ])
+])
+
+
 # _YAT_BAM_INCLUDES
 # =================
@@ -114 +167 @@
 @%:@if YAT_HAVE_BAM_H
 @%:@ include <bam.h>
+@%:@ include <sam.h>
 @%:@elif YAT_HAVE_BAM_BAM_H
 @%:@ include <bam/bam.h>
+@%:@ include <bam/sam.h>
 @%:@elif YAT_HAVE_SAMTOOLS_BAM_H
 @%:@ include <samtools/bam.h>
+@%:@ include <samtools/sam.h>
 @%:@endif
 ]) # _YAT_BAM_HEADER