Changeset 3591

Timestamp:

Jan 20, 2017, 3:19:49 AM (5 years ago)

Author:

Peter

Message:

fixes #877

Generalize YAT_CXX_RVALUE into YAT_CXX_TRY_CXX11 and use that to
implement new macro YAT_CXX_ATOMIC. Use this macro in configure.ac and
use std::atomic<> conditoionally in RNG singleton.

Location:

trunk

Files:

• configure.ac (modified) (2 diffs)
• m4/yat_cxx11.m4 (modified) (3 diffs)
• yat/random/random.cc (modified) (2 diffs)
• yat/random/random.h (modified) (3 diffs)
• yat/utility/config_public.h.in (modified) (1 diff)

trunk/configure.ac

@@ -95 +95 @@
 # if CXX11 is wanted look for rvalue support
 yat_have_rvalue=no
+yat_have_atomic=no
 AS_VAR_IF([with_cxx11], [no], [], [
   YAT_CXX_RVALUE([yat_have_rvalue=yes
                   AC_DEFINE([YAT_HAVE_RVALUE], [1],
                             [Define if compiler support rvalues])])
+  YAT_CXX_ATOMIC([yat_have_atomic=yes
+                  AC_DEFINE([YAT_HAVE_ATOMIC], [1],
+                            [Define if compiler support std::atomic])])
 ])
 
@@ -655 +659 @@
   With Bam Support:     $with_htslib
   With Rvalue Support:  $yat_have_rvalue
+  With atomic Support:  $yat_have_atomic
 
 Options used to compile and link:

trunk/m4/yat_cxx11.m4

@@ -7 +7 @@
 # SYNOPSIS
 #
+#   YAT_CXX_ATOMIC([ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 #   YAT_CXX_RVALUE([ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 #
@@ -37 +38 @@
 #
 
+# YAT_CXX_ATOMIC([action-if-found], [action-if-not-found])
+#
+# Test whether $CXX supports std::atomic. If not, try turning on
+# support with a number of different switches. If a successful switch
+# is found invoke shell action-if-found; else issue
+# action-if-not-found.
+AC_DEFUN([YAT_CXX_ATOMIC],
+[
+YAT_CXX_TRY_CXX11([atomic],
+  [@%:@include <atomic>],
+  [std::atomic<bool> ready(false);],
+  [$1], [$2])
+])
+
+
+# YAT_CXX_RVALUE([action-if-found], [action-if-not-found])
+#
+# Test whether $CXX supports rvalue. If not, try turning on support
+# with a number of different switches. If a successful switch is found
+# invoke shell action-if-found; else issue action-if-not-found.
 AC_DEFUN([YAT_CXX_RVALUE],
-[AC_MSG_CHECKING([for $CXX option to enable rvalue])
-AC_CACHE_VAL([yat_cv_cxx_rvalue],
-  [yat_cv_cxx_rvalue=no
-   yat_cxx_rvalue_save_CXX=$CXX
+[
+YAT_CXX_TRY_CXX11([rvalue], [ dnl header
+  @%:@include <utility>
+
+  class MyClass
+  {
+  public:
+    MyClass(void);
+    MyClass(const MyClass&); // copy constructor
+    MyClass(MyClass&&); // move constructor
+    MyClass& operator=(const MyClass&); // copy assignment
+    MyClass& operator=(MyClass&&); // move assignment
+  };
+  ],[ dnl body
+  MyClass mc;
+  MyClass mc2 = std::move(mc);
+  ], [# action
+  $1
+  ], [ # action if not found
+  $2
+  ])
+]) # YAT_CXX_RVALUE
+
+# YAT_CXX_TRY_CXX11([feature], [header], [body], [action-if-found],
+#                   [action-if-not-found])
+#
+AC_DEFUN([YAT_CXX_TRY_CXX11],
+[AS_VAR_PUSHDEF([my_CACHE], [yat_cv_cxx_$1])dnl
+AC_CACHE_CHECK([for $CXX option to enable $1],
+  [my_CACHE],
+  [my_CACHE=no
+   AS_VAR_PUSHDEF([my_save_CXX], [yat_cxx_$1_save_CXX])dnl
+   my_save_CXX="$CXX"
 # From autoconf 'c.m4' we have
 # GCC -std=c++11 -std=c++0x
@@ -52 +102 @@
 # but first we try with empty string, hoping compiler is modern.
    for yat_arg in '' -std=c++11 -std=c++0x -qlanglvl=stdcxx11 -AA +std=c++11 "-h std=c++11" ; do
-     CXX="$yat_cxx_rvalue_save_CXX $yat_arg"
-     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([YAT_CXX_RVALUE_HEADER],
-                                        [YAT_CXX_RVALUE_BODY])],
-                       [yat_cv_cxx_rvalue="$yat_arg"],
+     CXX="$my_save_CXX $yat_arg"
+     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
+                       [my_CACHE="$yat_arg"],
                        [])
-     AS_IF([test x"$yat_cv_cxx_rvalue" != x"no"], [break])
+     AS_VAR_IF([my_CACHE], [no], [], [break])
    done
-   CXX="$yat_cxx_rvalue_save_CXX"
+   # restore CXX
+   CXX="$my_save_CXX"
+
+   AS_CASE([x"$my_CACHE"],
+           [x], [my_CACHE="none needed"],
+           [x"no"], [my_CACHE=unsupported])
+
+   AS_VAR_POPDEF([my_save_CXX])
   ])
 
-AS_CASE([x"$yat_cv_cxx_rvalue"],
-        [x], [AC_MSG_RESULT([none needed])],
-        [x"no"], [AC_MSG_RESULT([unsupported])],
-        [CXX="$CXX $yat_cv_cxx_rvalue"
-         AC_MSG_RESULT([$yat_cv_cxx_rvalue])])
-AS_VAR_IF([yat_cv_cxx_rvalue], [no], [$2], [$1])
+AS_CASE([$my_CACHE],
+        ["none needed"], [$4],
+        [unsupported], [$5],
+        [CXX="$CXX $my_CACHE"
+         $4])
+AS_VAR_POPDEF([my_CACHE])
 ])
-
-
-AC_DEFUN([YAT_CXX_RVALUE_HEADER],
-[
-@%:@include <utility>
-
-class MyClass
-{
-public:
-  MyClass(void);
-  MyClass(const MyClass&); // copy constructor
-  MyClass(MyClass&&); // move constructor
-  MyClass& operator=(const MyClass&); // copy assignment
-  MyClass& operator=(MyClass&&); // move assignment
-};
-])
-
-
-AC_DEFUN([YAT_CXX_RVALUE_BODY],
-[
-  MyClass mc;
-  MyClass mc2 = std::move(mc);
-])

trunk/yat/random/random.cc

@@ -30 +30 @@
 
 #include <cassert>
+#include <cstddef>
 #include <cstring>
 #include <fstream>
@@ -38 +39 @@
 namespace random {
 
+#ifdef YAT_HAVE_ATOMIC
+  std::atomic<RNG*> RNG::instance_ { nullptr };
+#else
   RNG* RNG::instance_=NULL;
+#endif
   boost::mutex RNG::init_mutex_;
 

trunk/yat/random/random.h

@@ -24 +24 @@
 */
 
+#include "yat/utility/config_public.h"
+
 #include "yat/statistics/Histogram.h"
 #include "yat/utility/deprecate.h"
@@ -39 +41 @@
 
 #include <algorithm>
+#ifdef YAT_HAVE_ATOMIC
+#include <atomic>
+#endif
 #include <string>
 #include <vector>
@@ -193 +198 @@
     void rng_alloc(void) const;
 
+#ifdef YAT_HAVE_ATOMIC
+    static std::atomic<RNG*> instance_;
+#else
     static RNG* instance_;
+#endif
     // holds one gsl_rng per thread. Access through rng(void) so a
     // gsl_rng is allocated if necessary.

trunk/yat/utility/config_public.h.in

@@ -58 +58 @@
 /// Don't turn on cxx11 features if user explicitely turned off cxx11.
 #ifndef YAT_WITHOUT_CXX11
-/// Define if compiler support rvalues */
+/// Define if compiler supports rvalues */
 #undef YAT_HAVE_RVALUE
+/// Define if compiler supports atomic */
+#undef YAT_HAVE_ATOMIC
 #endif